The PHREG Procedure

Caution about Using Survival Data with Left Truncation

The product-limit estimator is used in a number of instances in the PHREG procedure, such as to transform the time values in the ZPH option in the PROC PHREG statement. The product-limit estimator is also used to construct the weights in the inverse probability of censoring weighting (IPCW) techniques, which are adapted to fit the proportional subdistribution model of Fine and Gray (1999) for competing-risks data and to assess the predictive accuracy of a model (Schemper and Henderson 2000). Although the product-limit estimator is the gold standard for estimating the survivor function of right-censored data, it might not be meaningful for right-censored data with left-truncation, as illustrated by Example 4.3 in Klein and Moeschberger (2003). In their example, 94 men and 365 women passed through the Channing House Retirement Center between January 1964 and July 1975. The outcome is the time to death, using the natural metric of age (in months).

The following statements create the data set Channing, which contains the following variables:

  • Gender: female or male

  • Age_entry: age at entry, in months

  • Age_exit: age at exit (death or last follow-up), in months

  • Death: death indicator, with the value 1 for death and 0 for censoring

data Channing;
   input Gender$ Age_entry Age_exit Death @@;
   datalines;
Female  1042 1172  1  Female   921 1040  1  Female   885 1003  1
Female   901 1018  1  Female   808  932  1  Female   915 1004  1
Female   901 1023  1  Female   852  908  1  Female   828  868  1
Female   968  990  1  Female   936 1033  1  Female   977 1056  1
Female   929  999  1  Female   936 1064  1  Female  1016 1122  1
Female   910 1020  1  Female  1140 1200  1  Female  1015 1056  1
Female   850  940  1  Female   895  996  1  Female   854  969  1

   ... more lines ...   

  Male   751  777  1    Male   906  966  1    Male   835  907  1
  Male   946 1031  1    Male   759  781  1    Male   909  914  0
  Male   962  998  1    Male   984 1022  1    Male   891  932  1
  Male   835  898  1    Male  1039 1060  1    Male  1010 1044  1
;

The following statements use the PHREG procedure to save the product-limit estimate of the survivor function for each gender in the data set Outs. For each gender, the number of subjects at risk and the number of deaths at each death time are captured in the data set Atrisk. By merging these two data sets, Outs and Atrisk, you can conveniently display side by side the number of subjects at risk, the number of deaths, and the product-limit survival estimate at each death time.

ods graphics on;
proc phreg data=Channing plots(overlay=row)=survival atrisk;
   model Age_exit*Death(0)= /entrytime=Age_entry;
   strata Gender;
   baseline out=Outs survival=Probability / method=pl;
   ods output RiskSetInfo=Atrisk;
run;
data Outs;
   set Outs;
   if Gender="Female" then StratumNumber=1;
   else                    StratumNumber=2;
run;
data Outs;
   merge atrisk outs;
   by StratumNumber Age_exit;
run;
proc print data=Outs;
   id Gender;
   var Age_exit Atrisk Event Probability;
run;

Figure 85.18 displays two product-limit survival curves, one for women and one for men. The survival probabilities are tabulated in Figure 85.19 for women and in Figure 85.20 for men. Although the survival curve for women does not appear unusual, the survival curve for men looks odd, because the curve drops to 0 at 781 months even though the majority of men survive beyond 781 months. At 781 months, the risk set consists of a single time to death, rendering the product-limit estimate as 0 at 781 months and thereafter. The product-limit curve for men for these data is meaningless. Klein and Moeschberger (2003) suggest using only those observations in which the value of Age_exit exceeds 781 months.

Figure 85.18: Product-Limit Estimates for Women and Men

Product-Limit Estimates for Women and Men


Figure 85.19: Product-Limit Survival Probabilities for Women

Gender Age_exit Atrisk Event Probability
Female 0 . . 1.00000
Female 804 21 1 0.95238
Female 822 36 1 0.92593
Female 830 46 1 0.90580
Female 840 58 1 0.89018
Female 845 66 1 0.87669
Female 861 89 1 0.86684
  . . . .
  . . . .
  . . . .
Female 1152 8 1 0.11493
Female 1172 7 1 0.09852
Female 1192 4 1 0.07389
Female 1200 3 2 0.02463



Figure 85.20: Product-Limit Survival Probabilities for Men

Gender Age_exit Atrisk Event Probability
Male 0 . . 1.0
Male 777 2 1 0.5
Male 781 1 1 0.0
Male 869 24 1 0.0
Male 872 25 1 0.0
Male 876 25 1 0.0
Male 893 33 1 0.0
  . . . .
  . . . .
  . . . .
Male 1085 10 1 0.0
Male 1094 8 2 0.0
Male 1128 3 1 0.0
Male 1139 2 1 0.0



PROC PHREG currently makes no attempt to circumvent the problem of the invalid product-limit estimator for left-truncated data.