The OPTGRAPH Procedure

This example looks at the use of precedents in court cases. Consider the judge’s problem of identifying precedent court cases that are most relevant and important to the current case. This application of network analysis was published in Fowler and Joen 2008. Because of norms inherited from 19th century English law, judges are encouraged to follow precedent in order to take advantage of “accumulated experience of many judges responding to the arguments and evidence of many lawyers” (Landes and Posner 1976). In network analysis, one way to define the importance of a previous case is to look at the network of citations used in related cases. That is, if a particular case A cited case B to help support its argument, then a link exists from A to B in the citation network.

Given such a citation network, you can then use a metric known as authority score to rank the importance of these cases. This metric is explained in more detail in the section Hub and Authority Scoring. Figure 1.6 shows a small representative subset of the citation network for landmark abortion decisions from the example in Fowler and Joen 2008.

Figure 1.6: Citation Network for Some U.S. Supreme Court Cases

The data set Cases stores a mapping between case name and the case identifier:

data Cases;
   length case_id 8 case_name $80;
   input case_id 1-5 case_name $ 7-80;
   datalines;
12061 Jacobson v. Massachusetts, 197 U.S. 11 (1905)
25347 Roe vs. Wade, 410 U.S. 113 (1973)
27633 Akron vs. Akron Cntr for Repro-Health, 462 U.S. 416 (1983)
28354 Thornburgh vs. American College, 476 U.S. 747 (1986)
29003 Webster vs. Repro-Health Services, 492 U.S. 490 (1989)
29153 Cruzan v. Director, MO Dept of Health, 497 U.S. 261 (1990)
29155 Georgia v. South Carolina, 497 U.S. 376 (1990)
29156 Hodgson v. Minnesota, 497 U.S. 417 (1990)
29459 Planned Parenthood of SE PA vs. Casey, 505 U.S. 833 (1992)
29663 Madsen v. Women's Health Ctr., 512 U.S. 753 (1994)
29933 Wash. v. Glucksberg, 521 U.S. 702 (1997)
;

The data set LinkSetInCourt provides the citation network between case identifiers:

data LinkSetInCourt;
   input from_case to_case @@;
   datalines;
27633 25347  28354 25347  28354 27633  29003 25347  29003 27633
29003 28354  29459 25347  29459 27633  29459 28354  29459 29003
25347 12061  28354 12061  29459 12061  29933 25347  29933 29459
29933 12061  29933 29153  29663 25347  29663 28354  29153 12061
29153 28354  29153 29003  29153 25347  29459 29153  29156 27633  
29156 28354  29156 29003  29156 25347  29459 29156
;

You can calculate the authority scores of each case by using the CENTRALITY statement with the AUTH= option, as follows:

proc optgraph
   direction      = directed
   data_links     = LinkSetInCourt
   out_nodes      = NodeSetOut;
   data_links_var
      from        = from_case
      to          = to_case;
   centrality
      auth        = unweight;
run;

The output data set NodeSetOut contains the authority score for each case (node). Then, the following DATA step combines the case names with the case identifiers and sorts on the score:

data NodeSetOut(drop=rc case_id);
   if _n_=1 then do;
       declare hash h(dataset:'cases');
       h.definekey('case_id');
       h.definedata('case_name');
       h.definedone();
   end;
   set NodeSetOut;
   length case_id 8 case_name $80;
   rc=h.find(key:node);
run;

proc sort data=NodeSetOut;
   by descending centr_auth_unwt;
run;

As expected, Roe vs. Wade (1973) has the highest authority ranking since it is most often cited by other cases.

In such a small example, it is somewhat easy to see which cases have the most influence by looking at the directed graph of citations. As discussed in Fowler and Joen 2008, the real advantage of such an analysis can be seen when examining all the citations for all 30,288 cases available in their data.