The VARMAX Procedure

INITIAL Statement

  • INITIAL equation, …, equation;

The INITIAL statement sets up the initial parameter values for nonlinear optimization when the maximum likelihood method is applied to the estimation of VARMAX, VECM, VARMAX-GARCH, or VEC-ARMAX-GARCH models. Only one INITIAL statement is allowed. If you specify more than one equation, separate them with commas. The equations are specified in the same manner as the restrictions in the RESTRICT statement. For information about how to define equations by using matrix expressions, operators, and functions, see the section RESTRICT Statement.

To use the INITIAL statement, you need to know the form of the model. If you do not specify the GARCH statement, the COINTEG statement, or the ECM=, P=, Q=, or XLAG= option in the MODEL statement, then the INITIAL statement is not applicable. If you specify the ECM=(NORMALIZE=), METHOD=LS, or PRIOR= option in the MODEL statement, or if you specify the EXOGENEITY, H=, J=, or NORMALIZE= option in the COINTEG statement, the INITIAL statement is ignored. Nonlinear restrictions on parameters are not supported.

The initial parameter values are the solution of the specified linear equations. If you do not specify initial values for all parameters, the default initial value for any parameter that is not specified in the INITIAL statement is 0, except for the following:

  • The diagonal elements of the COV parameter matrix are set to ones if the COV parameter matrix is to be estimated.

  • The diagonal elements of the GCHC parameter matrix are set to ones if the GCHC parameter matrix is to be estimated and the SUBFORM=EGARCH option is not specified.

  • The diagonal elements of the PACH parameter matrix are set to ones if the SUBFORM=PGARCH option is specified.

The following is an example of the INITIAL statement for a bivariate (k=2) zero-mean VARMA(1,1) model, which is estimated by the maximum likelihood method by default because a moving average (MA) term is present:

proc varmax data=one;
   model y1 y2 / noint p=1 q=1;
   initial AR = 0, MA = 0,
           COV={1 0.5, 0.5 4};
run;

Like the RESTRICT statement, the preceding INITIAL statement can be abbreviated as follows:

initial AR = MA = 0,
        COV={1 0.5, 0.5 4};

or

initial AR, MA, COV={1 0.5, 0.5 4};

Furthermore, you can omit AR and MA in the INITIAL statement as follows, because by default the AR and MA matrices are set to zeros if they are not specified in the INITIAL statement:

initial COV={1 0.5, 0.5 4};

If you use the INITIAL statement for a vector error correction model (VECM), you must specify initial values for both the ALPHA and BETA matrices and make sure they are both full rank; otherwise, the INITIAL statement is ignored.

In the following example, the INITIAL statement is ignored because initial values for ALPHA and BETA are not specified:

proc varmax data=one;
   model y1 y2 / noint p=1;
   cointeg rank=1;
   initial cov=I(2)*4;
run;

In the following example, the INITIAL statement is ignored because initial values for ALPHA are not specified:

proc varmax data=one;
   model y1 y2 / noint p=1;
   cointeg rank=1;
   initial beta=1;
run;

In the following example, the INITIAL statement is ignored because the initial BETA matrix is not full rank:

proc varmax data=one;
   model y1 y2 y3 / noint p=1;
   cointeg rank=2;
   initial alpha={1 0, 0 1, 0 0},
           beta ={1 2, 2 4, 3 6};
run;

In the following example, the INITIAL statement works fine because the specified initial ALPHA and BETA matrices are both full rank:

proc varmax data=one;
   model y1 y2 y3 / noint p=1;
   cointeg rank=2;
   initial alpha={1 0, 0 1, 0 0},
           beta ={1 2, 2 4, 3 5};
run;