The VARMAX Procedure

Consider the following four-dimensional system of US economic variables. Quarterly data for the years 1954 to 1987 are used (Lütkepohl 1993, Table E.3.).

title 'Analysis of US Economic Variables';
data us_money;
   date=intnx( 'qtr', '01jan54'd, _n_-1 );
   format date yyq. ;
   input y1 y2 y3 y4 @@;
   y1=log(y1);
   y2=log(y2);
   label y1='log(real money stock M1)'
         y2='log(GNP in bil. of 1982 dollars)'
         y3='Discount rate on 91-day T-bills'
         y4='Yield on 20-year Treasury bonds';
datalines;
450.9 1406.8  0.010800000 0.026133333
453.0 1401.2 0.0081333333 0.025233333
459.1 1418.0 0.0087000000 0.024900000

   ... more lines ...   

The following statements plot the series:

proc sgplot data=us_money;
   series x=date y=y1 / lineattrs=(pattern=solid);
   series x=date y=y2 / lineattrs=(pattern=dash);
   yaxis label="Series";
run;

Output 42.1.1 shows the plot of the variables and .

Output 42.1.1: Plot of Data

The following statements plot the variables and :

proc sgplot data=us_money;
   series x=date y=y3 / lineattrs=(pattern=solid);
   series x=date y=y4 / lineattrs=(pattern=dash);
   yaxis label="Series";
run;

Output 42.1.2 shows the plot of the variables and .

Output 42.1.2: Plot of Data

The following statements perform the Dickey-Fuller test for stationarity, the Johansen cointegrated test integrated order 2, and the exogeneity test. The VECM(2) is fit to the data.

proc varmax data=us_money;
   id date interval=qtr;
   model y1-y4 / p=2 lagmax=6 dftest
                 print=(iarr(3) estimates diagnose)
                 cointtest=(johansen=(iorder=2));
   cointeg rank=1 normalize=y1 exogeneity;
run;

From the outputs shown in Output 42.1.5, you can see that the series has unit roots and is cointegrated in rank 1 with integrated order 1. The fitted VECM(2) is given as

The prefixed to a variable name implies differencing.

Output 42.1.3 through Output 42.1.16 show the details. Output 42.1.3 shows the descriptive statistics.

Output 42.1.4 shows the output for Dickey-Fuller tests for the nonstationarity of each series. The null hypothesis is that there exists a unit root. All series have a unit root.

The Johansen cointegration rank test shows whether the series is integrated order either 1 or 2 as shown in Output 42.1.5. The last two columns in Output 42.1.5 explain the cointegration rank test with integrated order 1. The results indicate that there is a cointegrated relationship with cointegration rank 1 with respect to the 0.05 significance level because the test statistic for the null hypothesis H0: is 55.9633 and its corresponding p-value is 0.0072, less than 0.05 (indicating that H0: should be rejected), and the test statistic for the null hypothesis H0: is 20.6542 and its corresponding p-value is 0.3775, greater than 0.05 (indicating that H0: cannot be rejected). Now, look at the row associated with . All p-values of the tests for the null hypothesis that the series are integrated order 2 are zeros, less than 0.05 significance level (indicating that the null hypothesis should be rejected).

Output 42.1.6 shows the estimates of the long-run parameter, , and the adjustment coefficient, .

Output 42.1.7 shows the estimates and .

Output 42.1.8 shows that the VECM(2) is fit to the data. The RANK=1 option in the COINTEG statement produces the estimates of the long-run parameter, , and the adjustment coefficient, .

Output 42.1.9 shows the parameter estimates in terms of the constant, the lag 1 coefficients () that are contained in the estimates, and the coefficients that are associated with the lag 1 first differences ().

Output 42.1.10 through Output 42.1.12 show the parameter estimates and their significance.

Output 42.1.13 shows the innovation covariance matrix estimates, the log-likelihood, the various information criteria results, and the tests for white noise residuals. According to the Portmanteau test results, the residuals have significant correlations at lag 2 and 3, indicating that a VECM(3) model might be a better fit than the VECM(2) model.

Output 42.1.14 describes how well each univariate equation fits the data. The residuals for and differ from normality. Except for the residuals for , there are no AR effects on other residuals. Except for the residuals for , there are no ARCH effects on other residuals.

The PRINT=(IARR) option provides the VAR(2) representation in Output 42.1.15.

Output 42.1.16 shows whether each variable is the weak exogeneity of other variables. The variable is not the weak exogeneity of other variables, , , and ; the variable is not the weak exogeneity of other variables, , , and ; the variable and are the weak exogeneity of other variables.