The SURVEYLOGISTIC Procedure

A market research firm conducts a survey among undergraduate students at a certain university to evaluate three new Web designs for a commercial Web site targeting undergraduate students at the university.

The sample design is a stratified sample where the strata are students’ classes. Within each class, 300 students are randomly selected by using simple random sampling without replacement. The total number of students in each class in the fall semester of 2001 is shown in the following table:

This total enrollment information is saved in the SAS data set Enrollment by using the following SAS statements:

proc format;
   value Class 
      1='Freshman' 2='Sophomore' 
      3='Junior'   4='Senior';
run;
 
data Enrollment;
   format Class Class.;
   input Class _TOTAL_;
   datalines;
1 3734 
2 3565 
3 3903 
4 4196
;

In the data set Enrollment, the variable _TOTAL_ contains the enrollment figures for all classes. They are also the population size for each stratum in this example.

Each student selected in the sample evaluates one randomly selected Web design by using the following scale:

The survey results are collected and shown in the following table, with the three different Web designs coded as A, B, and C.

The survey results are stored in a SAS data set WebSurvey by using the following SAS statements:

proc format;
   value Design 1='A' 2='B' 3='C';
   value Rating 
      1='dislike very much'
      2='dislike'
      3='neutral'
      4='like'
      5='like very much';
run;
    
data WebSurvey;
   format Class Class. Design Design. Rating Rating.;
   do Class=1 to 4; 
      do Design=1 to 3; 
         do Rating=1 to 5;
            input Count @@; 
            output; 
         end;
      end;
   end;
   datalines;  
10 34 35 16 15   8 21 23 26 22   5 10 24 30 21
 1 14 25 23 37  11 14 20 34 21  16 19 30 23 12
19 12 26 18 25  11 14 24 33 18  10 18 32 23 17 
 8 15 35 30 12  15 22 34  9 20   2 34 30 18 16 
;

data WebSurvey; 
   set WebSurvey;    
   if Class=1 then Weight=3734/300; 
   if Class=2 then Weight=3565/300; 
   if Class=3 then Weight=3903/300; 
   if Class=4 then Weight=4196/300; 
run;

The data set WebSurvey contains the variables Class, Design, Rating, Count, and Weight. The variable class is the stratum variable, with four strata: freshman, sophomore, junior, and senior. The variable Design specifies the three new Web designs: A, B, and C. The variable Rating contains students’ evaluations of the new Web designs. The variable counts gives the frequency with which each Web design received each rating within each stratum. The variable weight contains the sampling weights, which are the reciprocals of selection probabilities in this example.

Output 111.1.1 shows the first 20 observations of the data set.

The following SAS statements perform the logistic regression:

proc surveylogistic data=WebSurvey total=Enrollment;
   stratum Class;
   freq Count;
   class Design;
   model Rating (order=internal) = design;
   weight Weight;
run;

The PROC SURVEYLOGISTIC statement invokes the procedure. The TOTAL= option specifies the data set Enrollment, which contains the population totals in the strata. The population totals are used to calculate the finite population correction factor in the variance estimates. The response variable Rating is in the ordinal scale. A cumulative logit model is used to investigate the responses to the Web designs. In the MODEL statement, rating is the response variable, and Design is the effect in the regression model. The ORDER=INTERNAL option is used for the response variable Rating to sort the ordinal response levels of Rating by its internal (numerical) values rather than by the formatted values (for example, 'like very much'). Because the sample design involves stratified simple random sampling, the STRATA statement is used to specify the stratification variable Class. The WEIGHT statement specifies the variable Weight for sampling weights.

The sample and analysis summary is shown in Output 111.1.2. There are five response levels for the Rating, with 'dislike very much' as the lowest ordered value. The regression model is modeling lower cumulative probabilities by using logit as the link function. Because the TOTAL= option is used, the finite population correction is included in the variance estimation. The sampling weight is also used in the analysis.

In Output 111.1.3, the score chi-square for testing the proportional odds assumption is 98.1957, which is highly significant. This indicates that the cumulative logit model might not adequately fit the data.

An alternative model is to use the generalized logit model with the LINK=GLOGIT option, as shown in the following SAS statements:

proc surveylogistic data=WebSurvey total=Enrollment;
   stratum Class;
   freq Count;
   class Design;
   model Rating (ref='neutral') = Design /link=glogit;
   weight Weight;
run;

The REF='neutral' option is used for the response variable Rating to indicate that all other response levels are referenced to the level 'neutral.' The option LINK=GLOGIT option requests that the procedure fit a generalized logit model.

The summary of the analysis is shown in Output 111.1.4, which indicates that the generalized logit model is used in the analysis.

Output 111.1.5 shows the parameterization for the main effect Design.

The parameter and odds ratio estimates are shown in Output 111.1.6. For each odds ratio estimate, the 95% confidence intervals shown in the table contain the value 1.0. Therefore, no conclusion about which Web design is preferred can be made based on this survey.