The ICPHREG Procedure

This example demonstrates how you can fit a proportional hazards model on an interval-censored data set. By default, PROC ICPHREG uses a piecewise constant baseline hazard to fit the model.

The AIDS data (Larder, Darby, and Richman 1989) consist of observations from 31 patients who were followed up for the development of drug resistance to zidovudine. The following DATA step creates the SAS data set HIV:

data hiv;
   input Left Right Stage Dose CdLow CdHigh;
   if (Left=0) then Left=.;
   if (Right>=26) then Right=.;
   datalines;
0 16 0 0 0 1
15 26 0 0 0 1
12 26 0 0 0 1
17 26 0 0 0 1
13 26 0 0 0 1
0 24 0 0 1 0
6 26 0 1 1 0
0 15 0 1 1 0
14 26 0 1 1 0
12 26 0 1 1 0
13 26 0 1 0 1
12 26 0 1 1 0
12 26 0 1 1 0
0 18 0 1 0 1
0 14 0 1 0 1
0 17 0 1 1 0
0 15 0 1 1 0
3 26 1 0 0 1
4 26 1 0 0 1
1 11 1 0 0 1
13 19 1 0 0 1
0 6 1 0 0 1
0 11 1 1 0 0
6 26 1 1 0 0
0 6 1 1 0 0
2 12 1 1 0 0
1 17 1 1 1 0
0 14 1 1 0 0
0 25 1 1 0 1
2 11 1 1 0 0
0 14 1 1 0 0
;

The data set HIV contains the variables Left and Right, which are the starting time and ending time, both in months since the start of study; the variable Stage, which indicates the stage of disease (early (0) or late (1)); the variable Dose, a binary variable that indicates whether the dose is low (0) or high (1); the variable CdLow, which indicates whether the CD4 lymphocyte count is less than 100; and the variable CdHigh, which indicates that a count greater than or equal to 400 is recorded.

The following statements use PROC ICPHREG to fit a proportional hazards model to these data:

proc icphreg data=hiv;
   class Stage Dose / desc;
   model (Left, Right) = Stage Dose;
run;

The CLASS statement specifies that the variables Stage and Dose are classification variables. The DESC option sets the lower formatted value as the reference level for each CLASS variable. The MODEL statement specifies that the observed intervals are formed by Left and Right.

By default, the preceding statements produce information about the input data and the fitted model, as shown in Figure 63.1.

Figure 63.1 shows 13 left-censored observations, 13 right-censored observations, and 5 interval-censored observations.

Figure 63.2 displays the "Class Level Information" table, which identifies the levels of the classification variables that are used in the model.

By default, PROC ICPHREG uses a baseline hazard that is partitioned into five disjoint intervals to fit a proportional hazards model. Figure 63.3 displays details about this partition.

PROC ICPHREG determines the break points so that each time interval contains approximately an equal number of imputed middle points and boundary values in the input data set after excluding the right-censored observations. For more information about this method, see the section Choosing Break Points. You can supply your own partition by using the INTERVALS= option in the MODEL statement.

The "Fit Statistics" table, shown in Figure 63.4, contains several statistics that summarize how well the model fits the data. These statistics are helpful in judging the adequacy of a model and in comparing it with other models under consideration.

The table of parameter estimates is displayed in Figure 63.5. The columns display the parameter name, the degrees of freedom that are associated with the parameter, the estimated parameter value, the standard error of the parameter estimate, the confidence limits, the Wald chi-square statistic, and the associated p-value for testing the significance of the parameter. If a parameter has been fixed during the optimization process, or if a column of the Hessian matrix that corresponds to that parameter is found to linearly depend on columns that correspond to proceeding model parameters, PROC ICPHREG assigns zero degrees of freedom to that parameter and displays a value of zero for its standard error.

Two types of parameters are present in Figure 63.5: the hazard parameters (Haz1, Haz2, ..., Haz5) and the regression coefficients for the covariates. PROC ICPHREG does not display the chi-square statistic and associated p-value for the hazard parameters.

Two of the hazard parameters are constrained at 0, a sign of overparameterization that results from too many hazard parameters in the model. For more information about how the constraints are constructed, see the section NOPOLISH. You can use fewer break points to fit the model by using the NINTERVAL= option or the INTERVALS= option. For example, the following statements request a model that has exactly two hazard parameters by specifying one break point at 10:

proc icphreg data=hiv ithistory;
   class Stage Dose / desc;
   model (Left, Right) = Stage Dose / basehaz=pch(intervals=(10));
run;

The table of parameter estimates is displayed in Figure 63.6. None of the hazard parameters are constrained.

The ITHISTORY option outputs the iteration history of the fitting algorithm, which is shown in Figure 63.7. This option also produces the gradient and Hessian of the likelihood function at the last evaluation. In Figure 63.7, all values of the gradient are close to zero.

One reason for fitting a proportional hazards model is to evaluate the hazard ratios between various disease groups. You can request customized hazard ratios by using the HAZARDRATIO statement, as follows:

proc icphreg data=hiv;
   class Stage / desc;
   model (Left, Right) = Stage / basehaz=pch(intervals=(10));
   hazardratio Stage;
run;

Figure 63.8 shows the estimated hazard ratio between the values 1 and 0 of the Stage variable and the corresponding confidence limits.

The estimate of 5.624 indicates that patients who have Stage 1 disease tend to have a much higher risk of developing AIDS than those who have Stage 0. However, the confidence limits are wide because of the small sample size.