The REG Procedure

Example 83.6 Chemical Reaction Response

This example shows how you can use lack-of-fit tests with the REG procedure. See the section Testing for Lack of Fit for details about lack-of-fit tests.

In a study of the percentage of raw material that responds in a reaction, researchers identified the following five factors:

  • the feed rate of the chemicals (FeedRate), ranging from 10 to 15 liters per minute

  • the percentage of the catalyst (Catalyst), ranging from 1% to 2%

  • the agitation rate of the reactor (AgitRate), ranging from 100 to 120 revolutions per minute

  • the temperature (Temperature), ranging from 140 to 180 degrees Celsius

  • the concentration (Concentration), ranging from 3% to 6%

The following data set contains the results of an experiment designed to estimate main effects for all factors:

data reaction;
   input FeedRate Catalyst AgitRate Temperature
         Concentration ReactionPercentage;
   datalines;
10.0   1.0  100   140  6.0   37.5
10.0   1.0  120   180  3.0   28.5
10.0   2.0  100   180  3.0   40.4
10.0   2.0  120   140  6.0   48.2
15.0   1.0  100   180  6.0   50.7
15.0   1.0  120   140  3.0   28.9
15.0   2.0  100   140  3.0   43.5
15.0   2.0  120   180  6.0   64.5
12.5   1.5  110   160  4.5   39.0
12.5   1.5  110   160  4.5   40.3
12.5   1.5  110   160  4.5   38.7
12.5   1.5  110   160  4.5   39.7
;

The first eight runs of this experiment enable orthogonal estimation of the main effects for all factors. The last four comprise four replicates of the centerpoint.

The following statements fit a linear model. Because this experiment includes replications, you can test for lack of fit by using the LACKFIT option in the MODEL statement.

proc reg data=reaction;
   model  ReactionPercentage=FeedRate Catalyst AgitRate
                             Temperature Concentration / lackfit;
run;

Output 83.6.1 shows that the lack of fit for the linear model is significant, indicating that a more complex model is required. Models that include interactions should be investigated. In this case, this will require additional experimentation to obtain appropriate data for estimating the effects.

Output 83.6.1: Analysis of Variance

The REG Procedure
Model: MODEL1
Dependent Variable: ReactionPercentage

Analysis of Variance
Source DF Sum of
Squares
Mean
Square
F Value Pr > F
Model 5 990.27000 198.05400 33.29 0.0003
Error 6 35.69917 5.94986    
Lack of Fit 3 34.15167 11.38389 22.07 0.0151
Pure Error 3 1.54750 0.51583    
Corrected Total 11 1025.96917      

Root MSE 2.43923 R-Square 0.9652
Dependent Mean 41.65833 Adj R-Sq 0.9362
Coeff Var 5.85533