REPORT Procedure
- Syntax
- Overview
- Concepts
- Using
- Results
- Examples Selecting Variables for a ReportOrdering the Rows in a ReportUsing Aliases to Obtain Multiple Statistics for the Same VariableConsolidating Multiple Observations into One Row of a ReportCreating a Column for Each Value of a VariableDisplaying Multiple Statistics for One VariableStoring and Reusing a Report DefinitionCondensing a Report into Multiple PanelsWriting a Customized Summary on Each PageCalculating PercentagesHow PROC REPORT Handles Missing ValuesCreating and Processing an Output Data SetStoring Computed Variables as Part of a Data SetUsing a Format to Create GroupsSpecifying Style Elements for ODS Output in the PROC REPORT StatementSpecifying Style Elements for ODS Output in Multiple StatementsUsing Multilabel FormatsUsing the WIDTH= and CELLWIDTH= Style Attributes with PROC REPORT
Example 3: Using Aliases to Obtain Multiple Statistics for the Same Variable
| Features: |
COLUMN statement: with aliases COMPUTE statement arguments: AFTER
|
| Other features: |
automatic macro variables: SYSDATE |
| Data set: | GROCERY |
| Formats: | $MGRFMT |
Details
The customized summary
at the end of this report displays the minimum and maximum values
of Sales over all departments for stores in the southeast sector.
To determine these values, PROC REPORT needs the MIN and MAX statistic
for Sales in every row of the report. However, to keep the report
simple, the display of these statistics is suppressed.
Program
libname proclib
'SAS-library';
options fmtsearch=(proclib);
proc report data=grocery nowd headline headskip;
column manager department sales
sales=salesmin
sales=salesmax;
define manager / order
order=formatted
format=$mgrfmt.
'Manager';
define department / order
order=internal
format=$deptfmt.
'Department';
define sales / analysis sum format=dollar7.2 'Sales';
define salesmin / analysis min noprint; define salesmax / analysis max noprint;
compute after;
line ' ';
line @7 53*'-';
line @7 '| Departmental sales ranged from'
salesmin dollar7.2 +1 'to' +1 salesmax dollar7.2
'. |';
line @7 53*'-';
endcomp;
where sector='se';
title 'Sales for the Southeast Sector'; title2 "for &sysdate"; run;
Program Description
Specify the format search library.The SAS system option FMTSEARCH= adds the SAS library
PROCLIB to the search path that is used to locate formats.
Specify the report options. The
NOWD option runs PROC REPORT without the REPORT window and sends its
output to the open output destinations. HEADLINE underlines all column
headings and the spaces between them at the top of each page of the
report. HEADSKIP writes a blank line beneath the underlining that
HEADLINE writes.
Specify the report columns. The
report contains columns for Manager and Department. It also contains
three columns for Sales. The column specifications SALES=SALESMIN
and SALES=SALESMAX create aliases for Sales. These aliases enable
you to use a separate definition of Sales for each of the three columns.
Define the sort order variables. The values of all variables with the ORDER option
in the DEFINE statement determine the order of the rows in the report.
In this report, PROC REPORT arranges the rows first by the value of
Manager (because it is the first variable in the COLUMN statement)
and then by the values of Department. The ORDER= option specifies
the sort order for a variable. This report arranges the values of
Manager by their formatted values and arranges the values of Department
by their internal values (np1, np2, p1, and p2). FORMAT= specifies
the formats to use in the report. Text in quotation marks specifies
column headings.
define manager / order
order=formatted
format=$mgrfmt.
'Manager';
define department / order
order=internal
format=$deptfmt.
'Department';Define the analysis variable. The
value of an analysis variable in any row of a report is the value
of the statistic that is associated with it (in this case Sum), calculated
for all observations that are represented by that row. In a detail
report each row represents only one observation. Therefore, the Sum
statistic is the same as the value of Sales for that observation in
the input data set.
Define additional analysis variables for use in the summary. These DEFINE statements use aliases from the COLUMN
statement to create separate columns for the MIN and MAX statistics
for the analysis variable Sales. NOPRINT suppresses the printing of
these statistics. Although PROC REPORT does not print these values
in columns, it has access to them so that it can print them in the
summary.
Print a horizontal line at the end of the report. This COMPUTE statement begins a compute block that
executes at the end of the report. The first LINE statement writes
a blank line. The second LINE statement writes 53 hyphens (-), beginning
in column 7. Note that the pointer control (@) has no effect on ODS
destinations other than traditional SAS monospace output.
Produce a customized summary. The
first line of this LINE statement writes the text in quotation marks,
beginning in column 7. The second line writes the value of Salesmin
with the DOLLAR7.2 format, beginning in the next column. The cursor
then moves one column to the right (+1), where PROC REPORT writes
the text in quotation marks. Again, the cursor moves one column to
the right, and PROC REPORT writes the value of Salesmax with the DOLLAR7.2
format. (Note that the program must reference the variables by their
aliases.) The third line writes the text in quotation marks, beginning
in the next column. Note that the pointer control (@) is designed
for the Listing destination (traditional SAS output). It has no effect
on ODS destinations other than traditional SAS monospace output.
The ENDCOMP statement ends the compute block.
line @7 '| Departmental sales ranged from'
salesmin dollar7.2 +1 'to' +1 salesmax dollar7.2
'. |';
line @7 53*'-';
endcomp;Select the observations to process. The WHERE statement selects for the report only
the observations for stores in the southeast sector.
