The TPSPLINE Procedure

This example illustrates how you can use the D=  option to decrease the computation time needed by the TPSPLINE procedure. Although the D=  option can be helpful in decreasing computation time for large data sets, it might produce unexpected results when used with small data sets.

The following statements generate the data set large:

data large;
   do x=-5 to 5 by 0.02;
      y=5*sin(3*x)+1*rannor(57391);
      output;
   end;
run;

The data set large contains 501 observations with one independent variable x and one dependent variable y. The following statements invoke PROC TPSPLINE to produce a thin-plate smoothing spline estimate and the associated 99% confidence interval. The output statistics are saved in the data set fit1.

proc tpspline data=large;
   model y  =(x) /lognlambda=(-5 to -1 by 0.2) alpha=0.01;
   output out=fit1 pred lclm uclm;
run;

The results from this MODEL statement are displayed in Output 116.4.1.

The following statements specify an identical model, but with the additional specification of the D=  option. The estimates are obtained by treating nearby points as replicates.

proc tpspline data=large;
   model y  =(x) /lognlambda=(-5 to -1 by 0.2) d=0.05 alpha=0.01;
   output out=fit2 pred lclm uclm;
run;

The output is displayed in Output 116.4.2.

The difference between the two estimates is minimal. However, the CPU time for the second MODEL statement is only about of the CPU time used in the first model fit.

The following statements produce a plot for comparison of the two estimates:

data fit2;
   set fit2;
   P1_y     = P_y;
   LCLM1_y  = LCLM_y;
   UCLM1_y  = UCLM_y;
   drop P_y LCLM_y UCLM_y;
run;

proc sort data=fit1;
   by x y;
run;

proc sort data=fit2;
   by x y;
run;

data comp;
   merge fit1 fit2;
      by x y;
   label p1_y   ="Yhat1" p_y="Yhat0"
         lclm_y ="Lower CL"
         uclm_y ="Upper CL";
run;

proc sgplot data=comp;
   title "Comparison of Two Estimates";
   title2 "with and without the D= Option";

   yaxis label="Predicted y Values";
   xaxis label="x";

   band x=x lower=lclm_y upper=uclm_y /name="range"
                      legendlabel="99% CI of Predicted y without D=";
   series x=x y=P_y/ name="P_y" legendlabel="Predicted y without D="
                      lineattrs=graphfit(thickness=1px pattern=shortdash);
   series x=x y=P1_y/ name="P1_y" legendlabel="Predicted y with D="
                      lineattrs=graphfit(thickness=1px color=red);
   discretelegend "range" "P_y" "P1_y";
run;

The estimates from fit1 and fit2 are displayed in Output 116.4.3 with the 99% confidence interval from the fit1 output data set.

Output 116.4.3: Comparison of Two PROC TPSPLINE Fits with and without the D= Option