The %ChoicEff Macro

%ChoicEff( MODEL=model-specification, NSETS=n <, optional arguments>)

You can specify either of the following to display the option names and simple examples of the macro syntax:

%choiceff(help)
%choiceff(?)

This macro specifies options nonotes throughout most of its execution. If you want to see all the notes, submit the following statement before running the macro:

%let mktopts = notes;

To see the macro version, submit the following statement before running the macro:

%let mktopts = version;

This example creates a design for a generic choice model that contains three 3-level factors. First, you use the %MktEx macro to create a set of candidate alternatives, where X1, X2, and X3 are the factors. The following statements create and display the candidate set:

%mktex(3 ** 3, n=3**3, seed=238)

The %MktEx macro, by default, saves the candidate alternatives in a data set named Design. The following statements use the PRINT procedure to print the candidate alternatives:

proc print data=design noobs;
run;

Figure 1 displays the candidate alternatives.

Next, you use the %ChoicEff macro to find an efficient design for the unbranded, purely generic choice model with the assumption that as follows:

%choiceff(data=design, model=class(x1-x3 / standorth), nsets=9, flags=3,
          seed=289, maxiter=60, options=relative, beta=zero)

The DATA= argument indicates that the design matrix is contained in the data set Design. The MODEL= argument specifies the MODEL statement in PROC TRANSREG for coding the design. CLASS(x1-x3 / STANDORTH) indicates that there are three main effects, and the STANDORTH option specifies a standardized orthogonal coding. The NSETS= argument specifies that there are nine choice sets. OPTIONS=RELATIVE requests that the relative D-efficiency be displayed. The FLAGS= argument specifies that there are three alternatives in a purely generic design. BETA=ZERO specifies that all model parameters are 0. The SEED= argument specifies the random number seed. The MAXITER= argument requests that 60 designs be created.

The output from the %ChoicEff macro, as shown in Figure 2, includes a list of the model parameters’ names, values, and labels; a series of iteration histories (not shown); a brief report on the most efficient design found; and a table that shows the model parameters’ names, variances, degrees of freedom, and standard errors.

                                 Final Results

                           Design                 52
                           Choice Sets             9
                           Alternatives            3
                           Parameters              6
                           Maximum Parameters     18
                           D-Efficiency       9.0000
                           Relative D-Eff   100.0000
                           D-Error            0.1111
                           1 / Choice Sets    0.1111

By default, the %ChoicEff macro saves the best design in a data set named Best and the covariance matrix of the best design in a data set named BestCov. The following statements use PROC PRINT to display the best design and its covariance matrix:

proc print data=best;
   var x1-x3;
   id set;
   by set;
run;

proc print data=bestcov label;
   id __label;
   label __label = '00'x;
   var x:;
run;

The output is shown in Figure 3 and Figure 4.

This design is optimal because it has 100% relative D-efficiency. Because a generic (main-effects-only) design is requested in which , and the standardized orthogonal contrast coding is used, it is possible to get a relative D-efficiency on a 0-to-100 scale. This is not necessarily true for all models. Relative D-efficiency is computed as the raw D-efficiency divided by the number of choice sets, multiplied by 100. An optimal generic design such as this one exhibits all the following properties:

Note: In practice, the values of the covariances are often not precisely 0 because the values are computed by using inexact floating-point arithmetic. This is why some values are displayed as –0.00000 in the output.

This example uses the %MktEx, %MktRoll, and %MktDups macros to create a candidate set of choice sets. The %ChoicEff macro is then used to search for an efficient design by using the candidate-set-swapping algorithm. The %ChoicEff macro can sometimes find a 100% D-efficient generic choice design by using this candidate set of choice sets approach. However, the optimal design is much harder to find when the macro is searching through a large candidate set of choice sets instead of searching through a small candidate set of alternatives. This is one reason why the candidate set of alternatives approach is usually preferred to creating a candidate set of choice sets.

The following three statements create a candidate set of choice sets:

%mktex(3 ** 9, n=2187, seed=368)

%mktroll(design=Design, key=3 3, out=Rolled)

%mktdups(generic, data=Rolled, factors=x1-x3, nalts=3, out=NoDups)

The %MktEx macro creates a design that has nine factors, three for each of the three alternatives. The %MktRoll macro turns a linear arrangement of a choice design into a true choice design by using the rules that are specified in the Key data set. In this example, the Key data set is automatically created to arrange one row with nine factors into three alternatives with three attributes. The %MktDups macro removes duplicate cadidate choice sets from the data set Rolled and saves the resulting candidate choice sets in the data set NoDups.

Figure 5 shows the first three candidate choice sets that are contained the the data set NoDups.

The following invocation of the %ChoicEff macro attempts to construct an efficient design from the candidate choice sets:

%choiceff(data=NoDups, model=class(x1-x3 / standorth), nsets=9, nalts=3,
          maxiter=20, seed=205, options=relative, beta=zero)

The DATA= argument specifies that the candidate choice sets are contained in the data set NoDups. The MODEL= argument specifies the MODEL statement in PROC TRANSREG. The NSETS= argument requests a design that contains nine choice sets. NALTS=3 specifies that there are three alternatives. The MAXITER= argument requests that 20 designs be created. The SEED argument specifies the seed for the pseudorandom number generator, which ensures reproducibility. OPTIONS=RELATIVE requests that the relative D-efficiency for the final design be displayed. BETA=ZERO specifies that all the model parameters be set equal to 0.

By default, the %ChoicEff macro saves the best design in a data set named Best, which you can display by using the PRINT procedure, as follows:

proc print data=Best;
  var set _alt_ x1-x3;
run;

The output is shown in Figure 6.

Suppose you are designing a choice experiment in which there are six 4-level quantitative attributes. As the factor level value increases, the desirability of the feature increases. When one alternative contains levels that are all less than or equal to the levels for another alternative, the first alternative is dominated by the second. When one alternative is dominated by another, the choice task becomes easier for respondents. Eliminating dominated alternatives forces the respondents to consider all the attributes and all the alternatives in making a choice. This example shows how to use the %ChoicEff macro to generate a design that avoids dominated alternatives by imposing restrictions on the design. You impose restrictions on a design by writing a restrictions macro that uses the SAS/IML matrix language and that specifies the restrictions in terms of a set of predefined IML matrices and scalars (see the documentation for the REVARS= argument for more details).

First you generate a candidate set of alternatives by using the %MktEx macro:

%mktex(4 ** 6, n=32, seed=104)

By default, the %MktEx macro saves the randomized experimental design in a data set named Randomized. This is your candidate set of alternatives.

Next, you write a macro that counts the number of dominated alternatives. You write this macro in the SAS/IML matrix language. The IML scalar Bad is increased by 1 every time a dominated alternative is found. The scalar Bad is automatically initialized to 0. In this example, the restrictions macro is evaluating each choice set at the same time that the %ChoicEff macro is constructing it. The current choice set that is being considered is stored in the matrix . When every element in the ith row of is greater than or equal to its corresponding element in the kth row of , the ith row dominates the kth row and Bad is increased by 1. Similarly, when every element in the kth row of is greater than or equal to its corresponding element in the ith row of , the kth row dominates the ith row and Bad is increased by 1.

%macro res;
   do i = 1 to nalts;
      do k = i + 1 to nalts;
         if all(x[i,] >= x[k,]) then bad = bad + 1;
         if all(x[k,] >= x[i,]) then bad = bad + 1;
      end;
   end;
%mend;

Finally, you invoke the %ChoicEff macro and provide the name of your restrictions macro in the RESTRICTIONS= argument. You must also provide the names of the variables that the design contains by using the RESVARS= argument. The %ChoicEff macro uses the %Res macro to evaluate the badness of each choice set when it considers swapping alternatives into the design.

%choiceff(data=randomized, model=class(x1-x6 / sta), nsets=8, flags=4,
          seed=104, options=relative, restrictions=res, resvars=x1-x6,
          maxiter=20, beta=zero)

Figure 7 shows that this construction method creates a design that is 91% efficient relative to the optimal design that has no restrictions. You can often find a slightly more efficient design by increasing the number of designs that are specified in the MAXITER= argument, but the gain in efficiency is subject to diminishing returns.

                                 Final Results

                           Design                 15
                           Choice Sets             8
                           Alternatives            4
                           Parameters             18
                           Maximum Parameters     24
                           D-Efficiency       7.2649
                           Relative D-Eff    90.8108
                           D-Error            0.1376
                           1 / Choice Sets    0.1250

The following statements assign names and levels for the attributes and display the design:

proc format;
   value x1f 1='Bad'   2='Good'    3='Better'   4='Best';
   value x2f 1='Small' 2='Average' 3='Bigger'   4='Large';
   value x3f 1='Ugly'  2='OK'      3='Average'  4='Nice ';
   value x4f 1='Slow'  2='Fast'    3='Faster'   4='Fastest';
   value x5f 1='Rough' 2='Normal'  3='Smoother' 4='Smoothest';
   value x6f 1='$9.99' 2='$8.99'   3='$7.99'    4='$6.99';
run;
proc print data=best label;
   label x1 = 'Quality'
         x2 = 'Size'
         x3 = 'Appearance'
         x4 = 'Speed'
         x5 = 'Smoothness'
         x6 = 'Price';
   format x1 x1f. x2 x2f. x3 x3f. x4 x4f. x5 x5f. x6 x6f.;
   by set;
   id set;
   var x:;
run;

The attribute levels are assigned so that in terms of the original values (1, 2, 3, 4), larger values are always better than smaller values. In particular, notice that the largest price is assigned to the smallest level (1 becomes $9.99) and the smallest price is assigned to the largest level (4 becomes $6.99).

Figure 8 shows the final design.

This example shows how to use the %ChoicEff macro to evaluate an existing design. The design might have been created by a previous invocation of the %ChoicEff macro, by the %MktEx macro, or by other means. The following DATA step reads a data set that contains a generic choice design with three 3-level factors. There are three choice sets, indexed by the variable Set. The three factors are Size, Color, and Price.

data Design;
   input Set Size Color Price ;
   datalines;
1 1 1 1
1 2 3 2
1 3 2 3
2 1 3 3
2 2 2 1
2 3 1 2
3 1 2 2
3 2 1 3
3 3 3 1
;

The following invocation of the %ChoicEff macro evaluates the design:

%choiceff(data=Design, init=Design(keep=Set), intiter=0,
          model=class(Size Color Price / sta), nsets=3,
          nalts=3, options=relative, beta=zero)

When you evaluate a design, you provide the name of the data set that contains the design in the DATA= argument. INIT=DESIGN(KEEP=SET) instructs the %ChoicEff macro to select all the choice sets in the data set Design that are indexed by the variable Set and use them as the initial design. INTITER=0 instructs the macro to evaluate the efficiency of the initial design. The MODEL= argument specifies the MODEL statement in PROC TRANSREG. The NSETS= argument specifies that the design contains three choice sets. The NALTS= argument specifies that each choice set has three alternatives. OPTIONS=RELATIVE requests that the design’s relative D-efficiency be displayed. BETA=ZERO specifies that the values of the true parameters are equal to 0.

Figure 9 displays the %ChoicEff macro’s output.

                 Design   Iteration  D-Efficiency       D-Error
                 ----------------------------------------------
                      1       0           3.00000 *     0.33333

                                 Final Results

                           Design                  1
                           Choice Sets             3
                           Alternatives            3
                           Parameters              6
                           Maximum Parameters      6
                           D-Efficiency       3.0000
                           Relative D-Eff   100.0000
                           D-Error            0.3333
                           1 / Choice Sets    0.3333

This design is optimal. The relative D-efficiency is 100%, and all the variances of the parameter estimates are equal to 1 over the number of choice sets.