The ROBUSTREG Procedure

This example models the selling price of a house as a function of several covariates. One of these covariates is a classification variable that indicates whether a house is located on a corner lot (called a corner house in this example). Because corner houses are relatively rare, the inclusion of this classification effect in the model introduces a low-dimensional structure (that is, the majority of the observations are located in a lower-dimensional hyperplane that is defined as containing non-corner houses) into the design matrix. As discussed in the section Robust Distance, the presence of this low-dimensional structure causes difficulties in the traditional computation of robust distances. This example illustrates how you can use the projected robust distance to address those difficulties and to obtain meaningful leverage diagnostics. It also shows how you can use the RDPLOT= and DDPLOT= options to illustrate the outlier-leverage relationship.

The following house price data set contains 66 home resale records on seven variables from February 15 to April 30, 1993 (Data and Story Library 2005). The records are randomly selected from a database that is maintained by the Albuquerque Board of Realtors.

 
data house;
   input price sqft age feats ne cor tax @@;
   label price = "Selling price"
         sqft  = "Square feet of living space"
         age   = "Age of home in year" 
         feats = "Number out of 11 features (dishwasher, refrigerator,
                  microwave, disposer, washer, intercom, skylight(s),
                  compactor, dryer, handicap fit, cable TV access)" 
         ne    = "Located in northeast sector of city (1) or not (0)" 
         cor   = "Corner location (1) or not (0)" 
         tax   = "Annual taxes";  
   sum = sqft+age+feats+ne+cor+tax;
   id  = _N_;
   datalines;
2050 2650 13 7 1 0 1639
2150 2664  6 5 1 0 1193
2150 2921  3 6 1 0 1635
1999 2580  4 4 1 0 1732

   ... more lines ...   

 870 1273  4 4 0 0  638
 869 1165  7 4 0 0  694
 766 1200  7 4 0 1  634
 739  970  4 4 0 1  541
;

To illustrate the dependence detection ability of the generalized MCD algorithm, an extra variable called sum is created such that all the observations satisfy sum = sqft + age + feats + ne + cor + tax. Adding the variable sum does not change the rank of the original design matrix; sum is expected to be ignored in the model and also in the diagnostics. The following statements apply the MM method and the generalized MCD algorithm to the house price data:

ods graphics on;
proc robustreg data=house method=MM plots=all;
   model price = sqft age feats ne cor tax sum /
         leverage(opc mcdinfo) diagnostics;
run;

As shown in Output 98.5.1 and Output 98.5.2, PROC ROBUSTREG finds the design dependence equation and forces the parameter estimate of variable sum to be 0.

Moreover, PROC ROBUSTREG also identifies a robust dependence equation on cor in Output 98.5.3, which holds for 77.27% of the observations but not for the entire data set.

Another way to represent the low-dimensional structure is to specify the coefficients of the MCD-dropped components on the data (see Output 98.5.4), which form a basis of the complementary space to the relevant low-dimensional hyperplane.

By the definitions of projected robust distance and leverage point, an observation is called an off-plane leverage point if at least one of the robust or design dependence equations does not apply to the observation. In this example, the observations in which cor = 1 are all off-plane leverage points. Output 98.5.5 lists the leverage points and outliers along with the relevant distance measurements and standardized residuals.

From Output 98.5.6 and Output 98.5.7, you can see that there is no apparent corner-related difference for the houses in terms of standardized robust residual and projected MD versus projected RD, although all the corner houses are defined as off-plane leverage points.

Output 98.5.6: Projected RD Plot

Output 98.5.7: Projected DD Plot

Output 98.5.8 shows more details of the robust diagnostics. The number of dimensions indicates that six regressors are used in the MCD analysis. Because sum is excluded in model fitting, it is ignored in the MCD analysis. The number of robust dropped components equals 1 because cor = 1. The number of off-plane points implies the 15 corner-house observations. The reweighted value of H is the number of observations that are finally used to estimate the MCD covariance.

You might speculate that the projected MD and projected RD are equal to the regular MD and RD on the same data set without the variable cor. In fact, this is not true. (See Output 98.5.9 and Output 98.5.10 for the RD plot and DD plot of the data set without cor.) When cor is included in the MODEL statement, it is omitted from the distance calculation, but it is still used for the initial orthonormalization step and the h-subset searching. In this example, inclusion of cor causes all the other covariates to be centered separately for corner houses and non-corner houses. However, without cor, the centering process does not distinguish corner houses from non-corner houses, and therefore the MCD algorithm can still be influenced by cor through the correlation between cor and other covariates. The following statements drop the variable cor and produce the RD plot and DD plot for the reduced model, which are shown in Output 98.5.9 and Output 98.5.10, respectively:

proc robustreg data=house method=MM plots=all;
   model price = sqft age feats ne tax/leverage(mcdinfo) diagnostics;
run;
ods graphics off;

Output 98.5.9: RD Plot for the Reduced Model

Output 98.5.10: DD Plot for the Reduced Model

Compared with Output 98.5.8, Output 98.5.11 shows the changes of the MCD information by removing cor from the model. You can see that the corner houses are no longer identified as off-plane points and that the reweighted value of H is increased from 47 to 52. The breakdown value is intact because it depends only on the specified value of H and the total number of observations.