# The GEE Procedure

### Example 43.5 Alternating Logistic Regression for Ordinal Multinomial Data

This example illustrates how you use the GEE procedure and alternating logistic regression (ALR) to analyze ordinal multinomial data. A clinical trial was conducted to evaluate the effectiveness of the drug auranofin for treating arthritis (Lipsitz, Kim, and Zhao 1994). Patients were assigned to one of two groups: one group was treated with auranofin, and the other group received a placebo. The treatment that a patient received is recorded in the variable `Treatment` (coded here as 1 = auranofin and 0 = placebo).

The response was self-assessment of arthritis recorded at one-, three-, and five-month follow-up visits. The responses are recorded in the `Rating` variable and are coded as 1 = very poor, 2 = poor, 3 = fair, 4 = good, and 5 = very good. This coding of `Rating` is finer than the coding in Lipsitz, Kim, and Zhao (1994), where only three levels were used. The visit numbers are recorded in the classification variable `Visit`, whose value is 1, 3, or 5. An initial self-assessment that uses the same coding as `Rating` is recorded in the variable `Baseline`. The variable `Age` records the participants’ ages (in years) at the baseline visit and is treated as a continuous variable. One participant missed all visits and is not considered. There are an additional 15 missed visits from eight participants who dropped out, and there are four participants who missed a single visit. A weighted GEE is not used because the GEE procedure in SAS/STAT 14.1 does not support the weighted GEE method for the multinomial distribution.

The following DATA step creates the data set `Arthritis`:

```data Arthritis;
input ID Rating Sex Age Treatment Baseline Visit;
datalines;
1 4 2 54 2 2 1
1 5 2 54 2 2 3
1 5 2 54 2 2 5
2 4 1 41 1 3 1
2 4 1 41 1 3 3
2 4 1 41 1 3 5

... more lines ...

301 2 2 64 1 2 5
302 2 2 55 1 2 1
302 3 2 55 1 2 3
302 3 2 55 1 2 5
;

```

The following SAS statements use PROC GEE to fit a model that has a fully exchangeable working correlation structure:

```proc gee data=Arthritis;
class Sex ID Treatment Baseline Visit;
model Rating= Visit Treatment Baseline / dist=multinomial;
repeated subject=ID / within=Visit logor=exch;
run;
```

You specify LOGOR=EXCH in the REPEATED statement to select the ALR method that has a fully exchangeable model for the log odds ratio. The results of the ALR model fitting are displayed in Output 43.5.1.

Output 43.5.1: Parameter Estimates for Arthritis Data Using ALR

The GEE Procedure

Parameter Estimates for Response Model
with Empirical Standard Error Estimates
Parameter   Estimate Standard
Error
95% Confidence Limits Z Pr > |Z|
Intercept1   -6.7502 0.4267 -7.5865 -5.9138 -15.82 <.0001
Intercept2   -4.6310 0.3968 -5.4087 -3.8533 -11.67 <.0001
Intercept3   -2.6735 0.3749 -3.4083 -1.9387 -7.13 <.0001
Intercept4   -0.3838 0.3710 -1.1109 0.3433 -1.03 0.3008
Visit 1 0.3740 0.1148 0.1489 0.5991 3.26 0.0011
Visit 3 0.3641 0.1116 0.1455 0.5828 3.26 0.0011
Visit 5 0.0000 0.0000 0.0000 0.0000 . .
Treatment 1 0.5552 0.1673 0.2273 0.8830 3.32 0.0009
Treatment 2 0.0000 0.0000 0.0000 0.0000 . .
Baseline 1 3.9457 0.5352 2.8969 4.9946 7.37 <.0001
Baseline 2 3.3052 0.4268 2.4686 4.1418 7.74 <.0001
Baseline 3 2.7483 0.3790 2.0054 3.4911 7.25 <.0001
Baseline 4 1.4013 0.4132 0.5914 2.2113 3.39 0.0007
Baseline 5 0.0000 0.0000 0.0000 0.0000 . .
Alpha1   1.6447 0.1693 1.3130 1.9764 9.72 <.0001

The parameter `Alpha1`, which is used to estimate the log odds ratio, is included in Output 43.5.1.

To fit the ALR model, each response is coded as a vector of binary variables and the log odds ratio models the association between pairs of responses. For more information about the log odds ratio and the ALR method for ordinal multinomial data, see the section ALR for Ordinal Multinomial Data. The ALR model fit criteria are shown in Output 43.5.2.

Output 43.5.2: ALR Model Fit Criteria

GEE Fit Criteria
QIC 2241.9540
QICu 2259.8575

For comparison, the following SAS statements use PROC GEE to fit the same marginal model by using an independent working correlation structure:

```proc gee data=Arthritis;
class Sex ID Treatment Baseline Visit;
model Rating= Visit Treatment Baseline / dist=multinomial;
repeated subject=ID / within=Visit;
run;
```

When the data have multinomial responses, the independent working correlation structure is the only structure supported for ordinary GEEs. In Output 43.5.1 and Output 43.5.3, you can see slight differences in the parameter estimates between the model that you fit by using ALR and the model that you fit by using an independent working correlation structure.

Output 43.5.3: Parameter Estimates for Arthritis Data Using Independent Working Correlation

The GEE Procedure

Parameter Estimates for Response Model
with Empirical Standard Error Estimates
Parameter   Estimate Standard
Error
95% Confidence Limits Z Pr > |Z|
Intercept1   -6.7528 0.4227 -7.5812 -5.9244 -15.98 <.0001
Intercept2   -4.6719 0.3953 -5.4466 -3.8972 -11.82 <.0001
Intercept3   -2.7138 0.3730 -3.4449 -1.9828 -7.28 <.0001
Intercept4   -0.4129 0.3689 -1.1360 0.3102 -1.12 0.2631
Visit 1 0.3852 0.1160 0.1578 0.6125 3.32 0.0009
Visit 3 0.3725 0.1118 0.1534 0.5916 3.33 0.0009
Visit 5 0.0000 0.0000 0.0000 0.0000 . .
Treatment 1 0.5643 0.1679 0.2352 0.8933 3.36 0.0008
Treatment 2 0.0000 0.0000 0.0000 0.0000 . .
Baseline 1 3.9533 0.5351 2.9046 5.0020 7.39 <.0001
Baseline 2 3.3264 0.4250 2.4934 4.1593 7.83 <.0001
Baseline 3 2.7672 0.3769 2.0285 3.5059 7.34 <.0001
Baseline 4 1.4252 0.4112 0.6192 2.2312 3.47 0.0005
Baseline 5 0.0000 0.0000 0.0000 0.0000 . .

The QIC for the ALR model shown in Output 43.5.2 is 2241.95, whereas the QIC for the independent working correlation model shown in Output 43.5.4 is 2269.82, indicating a slightly better fit for the ALR model.

Output 43.5.4: Model Fit Criteria

GEE Fit Criteria
QIC 2269.8166
QICu 2259.7693