The PHREG Procedure

Example 66.11 Analysis of Clustered Data

When experimental units are naturally or artificially clustered, failure times of experimental units within a cluster are correlated. Two approaches can be taken to adjust for the intracluster correlation. In the marginal Cox model approach, Lee, Wei, and Amato (1992) estimate the regression parameters in the Cox model by the maximum partial likelihood estimates under an independent working assumption and use a robust sandwich covariance matrix estimate to account for the intracluster dependence. Lin (1994) illustrates this methodology by using a subset of data from the Diabetic Retinopathy Study (DRS). An alternative approach to account for the within-cluster correlation is to use a shared frailty model where cluster effects are incorporated into the model as independent and identically distributed random variables.

The following DATA step creates the data set Blind that represents 197 diabetic patients who have a high risk of experiencing blindness in both eyes as defined by DRS criteria. One eye of each patient is treated with laser photocoagulation. The hypothesis of interest is whether the laser treatment delays the occurrence of blindness. Since juvenile and adult diabetes have very different courses, it is also desirable to examine how the age of onset of diabetes might affect the time of blindness. Since there are no biological differences between the left eye and the right eye, it is natural to assume a common baseline hazard function for the failure times of the left and right eyes.

Each patient is a cluster that contributes two observations to the input data set, one for each eye. The following variables are in the input data set Blind:

• ID, patient’s identification

• Time, time to blindness

• Status, blindness indicator (0:censored and 1:blind)

• Treat, treatment received (Laser or Others)

• Type, type of diabetes (Juvenile: onset at age 20 or Adult: onset at age 20)

proc format;
   value type 0='Juvenile' 1='Adult';
   value Rx  1='Laser' 0='Others';
   run;
   
data Blind;
   input ID Time Status dty trt @@;
   Type= put(dty, type.);
   Treat= put(trt, Rx.);
   datalines;
   5 46.23 0 1 1    5 46.23 0 1 0   14 42.50 0 0 1   14 31.30 1 0 0
  16 42.27 0 0 1   16 42.27 0 0 0   25 20.60 0 0 1   25 20.60 0 0 0

   ... more lines ...   

1705  8.00 0 0 1 1705  8.00 0 0 0 1717 51.60 0 1 1 1717 42.33 1 1 0
1727 49.97 0 1 1 1727  2.90 1 1 0 1746 45.90 0 0 1 1746  1.43 1 0 0
1749 41.93 0 1 1 1749 41.93 0 1 0
;

As a preliminary analysis, PROC FREQ is used to summarize the number of eyes that developed blindness.

proc freq data=Blind;
   table Treat*Status;
   run;

By the end of the study, 54 eyes treated with laser photocoagulation and 101 eyes treated by other means have developed blindness (Output 66.11.1).

The following statements use PROC PHREG to carry out the analysis of Lee, Wei, and Amato (1992). The explanatory variables in this Cox model are Treat, Type, and the Treat Type interaction. The COVS(AGGREGATE) option is specified to compute the robust sandwich covariance matrix estimate. The ID statement identifies the variable that represents the clusters. The HAZARDRATIO statement requests hazard ratios for the treatments be displayed.

proc phreg data=Blind covs(aggregate);
   class Treat Type;
   model Time*Status(0)=Treat|Type;
   id ID;
   hazardratio 'Marginal Model Analysis' Treat;
   run;

Results of the marginal model analysis are displayed in Output 66.11.2. The robust standard error estimates are smaller than the model-based counterparts, since the ratio of the robust standard error estimate relative to the model-based estimate is less than 1 for each parameter. Laser photocoagulation appears to be effective (=0.0217) in delaying the occurrence of blindness, although there is also a significant interaction effect between treatment and type of diabetes (=0.0053).

Hazard ratio estimates of the laser treatment relative to nonlaser treatment are displayed in Output 66.11.3. For both types of diabetes, the 95% confidence interval for the hazard ratio lies below 1. This indicates that laser-photocoagulation treatment is more effective in delaying blindless regardless of the type of diabetes. However, the effect is more prominent for adult-onset diabetes than for juvenile-onset diabetes since the hazard ratio estimates for the former are less than those of the latter.

Next, you analyze the same data by using a shared frailty model. The following statements use PROC PHREG to fit a shared frailty model to the Blind data set. The RANDOM statement identifies the variable ID as the variable that represents the clusters. You must declare the cluster variable as a classification variable in the CLASS statement.

proc phreg data=Blind;
   class ID Treat Type;
   model Time*Status(0)=Treat|Type;
   random ID;
   hazardratio 'Frailty Model Analysis' Treat;
   run;

Selected results of this analysis are displayed in Output 66.11.4 to Output 66.11.6.

The "Random Class Level Information" table in Output 66.11.4 displays the 197 ID values of the patients. You can suppress the display of this table by using the NOCLPRINT option in the RANDOM statement.

The "Covariance Parameter Estimates" table in Output 66.11.5 displays the estimate and asymptotic estimated standard error of the common variance parameter of the normal random effects.

Output 66.11.6 displays the Wald tests for both the fixed effects and the random effects. The random effects are statistically significant (=0.0042). Results of testing the fixed effects are very similar to those based on the robust variance estimates. Laser photocoagulation appears to be effective (=0.0252) in delaying the occurrence of blindness, although there is also a significant treatment by diabetes type interaction effect (=0.0071).

Estimates of hazard ratios of the laser treatment relative to nonlaser treatment are displayed in Output 66.11.7. These estimates closely resemble those computed in analysis based on the marginal Cox model in Output 66.11.3, which leads to the same conclusion that laser photocoagulation is effective in delaying blindess for both types of diabetes, and more effective for the adult-onset diabetes than for juvenile-onset diabetes.