The STDRATE Procedure

This example illustrates indirect standardization and uses the standardized mortality ratio to compare the death rate from skin cancer between people who live in the state of Florida and people who live in the United States as a whole.

The Florida_C43 data set contains the stratum-specific mortality information for skin cancer in year 2000 for the state of Florida (Florida Department of Health 2000, 2013). The variable Age is a grouping variable that forms the strata in the standardization, and the variables Event and PYear identify the number of events and total person-years, respectively. The COMMA9. format is specified in the DATA step to input numerical values that contain commas in PYear.

data Florida_C43;
   input Age $1-5 Event PYear:comma9.;
   datalines;
00-04    0    953,785
05-14    0  1,997,935
15-24    4  1,885,014
25-34   14  1,957,573
35-44   43  2,356,649
45-54   72  2,088,000
55-64   70  1,548,371
65-74  126  1,447,432
75-84  136  1,087,524
85+     73    335,944
;

The US_C43 data set contains the corresponding stratum-specific mortality information for the United States in year 2000 (Miniño et al. 2002; US Bureau of the Census 2011). The variable Age is the grouping variable, and the variables Event and PYear identify the number of events and the total person-years, respectively.

data US_C43;
   input Age $1-5 Event:comma5. PYear:comma10.;
   datalines;
00-04      0  19,175,798
05-14      1  41,077,577
15-24     41  39,183,891
25-34    186  39,892,024
35-44    626  45,148,527
45-54  1,199  37,677,952
55-64  1,303  24,274,684
65-74  1,637  18,390,986
75-84  1,624  12,361,180
85+      803   4,239,587
;

The following statements invoke the STDRATE procedure and request indirect standardization to compare death rates between the state of Florida and the United States:

ods graphics on;
proc stdrate data=Florida_C43 refdata=US_C43
             method=indirect
             stat=rate(mult=100000)
             plots=all
             ;
   population event=Event total=PYear;
   reference  event=Event total=PYear;
   strata Age / stats smr;
run;

The DATA= and REFDATA= options name the study data set and reference data set, respectively. The METHOD=INDIRECT option requests indirect standardization. The STAT=RATE option specifies the rate as the frequency measure for standardization, and the MULT=100000 suboption (which is the default) displays the rates per 100,000 person-years in the table output and graphics output. The PLOTS=ALL option requests all appropriate plots with indirect standardization.

The POPULATION statement specifies the options that are related to the study population, and the EVENT= and TOTAL= options specify variables for the number of events and person-years in the study population, respectively.

The REFERENCE statement specifies the options related to the reference population, and the EVENT= and TOTAL= options specify variables for the number of events and person-years in the reference population, respectively.

The STRATA statement lists the variable Age that forms the strata. The STATS option requests a strata information table that contains stratum-specific statistics such as rates, and the SMR option requests a table of stratum-specific SMR estimates.

The "Standardization Information" table in Figure 107.1 displays the standardization information.

The STATS option in the STRATA statement requests that the "Indirectly Standardized Strata Statistics" table in Figure 107.2 display the strata information and expected number of events at each stratum. The MULT=100000 suboption in the STAT=RATE option requests that crude rates per person-years be displayed. The Expected Events column displays the expected number of events when the stratum-specific rates in the reference data set are applied to the corresponding person-years in the study data set.

With ODS Graphics enabled, the PLOTS=ALL option displays all appropriate plots. With indirect standardization and a rate statistic, these plots include the strata distribution plot, the strata rate plot, and the strata SMR plot. By default, strata levels are displayed on the vertical axis for these plots.

The strata distribution plot displays proportions for stratum-specific person-years in the study and reference populations, as shown in Figure 107.3.

Figure 107.3: Strata Distribution Plot

The strata distribution plot displays the proportions in the "Indirectly Standardized Strata Statistics" table in Figure 107.2. In the plot, the proportions of the study population are identified by the blue lines, and the proportions of the reference population are identified by the red lines. The plot shows that the study population has higher proportions in older age groups and lower proportions in younger age groups than the reference population.

The strata rate plot displays stratum-specific rate estimates in the study and reference populations, as shown in Figure 107.4. This plot displays the rate estimates in the "Indirectly Standardized Strata Statistics" table in Figure 107.2. In addition, the plot displays the confidence limits for the rate estimates in the study population and the overall crude rates for the two populations.

Figure 107.4: Strata Rate Plot

The SMR option in the STRATA statement requests that the "Strata SMR Estimates" table in Figure 107.5 display the strata SMR at each stratum. The MULT=100000 suboption in the STAT=RATE option requests that the reference rates per person-years be displayed.

The "Strata SMR Estimates" table shows that although SMR is less than 1 only at three age strata (55–64, 65–74, and 75–84), these three strata contain about of the total events.

The strata SMR plot displays stratum-specific SMR estimates with confidence limits, as shown in Figure 107.6. The plot displays the SMR estimates in the "Strata SMR Estimates" table in Figure 107.5.

Figure 107.6: Strata SMR Plot

The METHOD=INDIRECT option requests that the "Standardized Morbidity/Mortality Ratio" table in Figure 107.7 be displayed. The table displays the SMR, its confidence limits, and the test for the null hypothesis . The default ALPHA=0.05 option requests that confidence limits be constructed.

The normal confidence limits contain the null hypothesis value , and the hypothesis of is not rejected at the level from the normal test.

The "Indirectly Standardized Rate Estimates" table in Figure 107.8 displays the indirectly standardized rate and related statistics.

The indirectly standardized rate estimate is the product of the SMR and the crude rate estimate for the reference population. The table shows that although the crude rate in the state of Florida (3.4359) is higher than the crude rate in the U.S. (2.6366), the resulting standardized rate (2.6829) is close to the crude rate in the U.S.