The HTSNP Procedure (Experimental)

Before using PROC HTSNP, you might need to run PROC HAPLOTYPE (see Chapter 7: The HAPLOTYPE Procedure, for more details) if you have data with unknown phase in order to estimate the haplotype frequencies. This example demonstrates how output from PROC HAPLOTYPE can be manipulated to be in the appropriate form for an input data set for PROC HTSNP.

The following data set contains 150 individuals with genotypes at 13 SNPs that were simulated to mimic the frequencies of SNPs in the CASP8 gene (Johnson et al., 2001).

data casp8;
   input id (m1-m13) ($);
   datalines;
1 T/T T/T A/G G/G C/G A/G A/G G/C C/C G/G A/A A/G A/C
2 G/T T/T A/G T/G C/G G/G G/G C/C C/C G/G A/A A/G C/C
3 T/T C/T G/A G/G C/C G/A G/G C/G C/C G/G A/A A/A C/A
4 T/T T/C G/G G/G C/C G/G G/G C/C C/C G/G A/A A/A C/C

   ... more lines ...   

150 T/T T/T A/A G/G C/C A/A A/G G/G C/C G/G A/A A/A A/A
;

The following code can be used to first estimate haplotype frequencies by using the EM algorithm, and then to identify the haplotype tag SNPs.

ods output haplotypefreq=freqout(keep=haplotype freq);
proc haplotype data=casp8 genocol cutoff=0.0075;
   var m1-m13;
run;

data hapfreq;
   set freqout;
   array m{13} $ 1;
   do i = 1 to 13;
    m{i} = substr(haplotype, 2*i-1, 1);
   end;
   drop haplotype i;
run;

proc htsnp data=hapfreq size=4 method=sa best=5 cutoff=0.05
           seed=123 nosumm;
   var m1-m13;
   freq freq;
run;

The ODS statement is used to create a data set from the “Haplotype Frequencies” ODS table, which is displayed in its table form in Output 8.1.1.

With this table in the form of a SAS data set, the preceding DATA step code can be used to convert it to an input data set for PROC HTSNP, using the estimated frequencies from PROC HAPLOTYPE as the FREQ variable. In this example, the simulated annealing search method is specified for finding the best sets of size four. The “htSNP Evaluation” table that is created by PROC HTSNP is displayed in Output 8.1.2 to show the best five sets of SNPs that were selected.

Note that the last selection shown in Output 8.1.2 matches the set of htSNPs found by Johnson et al. (2001).