Providing software solutions since 1976

• Log in
• Create profile
• Welcome
  [Log out]
• Edit profile

• Print  |
• Feedback  |
• Share

  • E-mail

  
  
  

  E-mail This Page

  Your Name:*
  Your E-mail:*
  Recipient E-mail:*
  Send a copy to me
  Personal Message:
  
  

  * indicates a required field

The concept of a LEAD function infers the ability to look ahead to a subsequent observation in a data set. This functionality can be obtained by using the SET statement's POINT=variable option.

By assigning an observation number to the numeric variable specified with the option, and then using the option on a second SET statement, a subsequent observation can be accessed (read into the Program Data Vector) in addition to the current observation.

Since a variable name can only exist once in the Program Data Vector, the second SET statement would ordinarily result in the value of the variables from the first SET statement being over-written. To avoid this behavior, the KEEP= and RENAME= data set options should be used with the second SET statement to read in only the pertinent variables and to give them a new name.

When the POINT= option is used with the SET and that specific SET statement is the only statement which reads an observation from a data set, then a STOP statement is required so that SAS knows when to terminate the DATA step. In this sample, the initial SET statement (without the POINT= option) reads every observation sequentially. As such, SAS will terminate the DATA step when all the observations have been read via that SET statement.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/*Sample data set*/
data one;
  input var1 $ var2;
datalines;
A 10
B 22
C 5
D 41
E 33
;
run;

data two;
/*Add the END= option to facilitate checking for last observation.*/
  set one end=finished;
/*Look ahead only if not on last observation.*/
  if not finished then do;
/*Define or calculate the observation number to be read. In this example,*/
/*simply add one to the _N_ variable to read the very next observation.*/
  pt = _N_ + 1;
/*Be sure to keep only pertinent variables and rename them.*/
  set one (keep= var2 rename= (var2 = next_var2)) point=pt;
/*Subtract next value of var2 from current value of var2.*/
  diff = var2 - next_var2;
  end;
  else next_var2 = .;
run;

proc print; run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

                       next_
Obs    var1    var2     var2    diff

 1      A       10       22      -12
 2      B       22        5       17
 3      C        5       41      -36
 4      D       41       33        8
 5      E       33        .        .

Operating System and Release Information