24666 - Simulating the LEAD function by comparing the value of a variable to its value in the next observation

Sample 24666: Simulating the LEAD function by comparing the value of a variable to its value in the next observation

/* Create sample data */

data one;
  input x y;
datalines;
5 1
5 2
10 1
2 1
2 2
19 1
;

/* Create TWO by merging ONE with itself.  Begin reading the second     */
/* reference to data set ONE with the second observation.  RENAME=      */
/* renames X so that the look-ahead value doesn't overwrite the current */
/* value of X in the program data vector.                               */

data two;
  merge one one(firstobs=2 rename=(x=nextx) keep=x);
  if x=nextx then match='YES';
  else match='NO';
run;

proc print data=TWO;
run;

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Obs     x    y    nextx    match

 1      5    1       5      YES
 2      5    2      10      NO
 3     10    1       2      NO
 4      2    1       2      YES
 5      2    2      19      NO
 6     19    1       .      NO

Type:	Sample
Topic:	SAS Reference ==> DATA Step SAS Reference ==> Functions ==> Special

Date Modified:	2011-12-06 13:17:45
Date Created:	2004-09-30 14:09:02

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	Base SAS	All	n/a	n/a

E-mail This Page

Knowledge Base

Sample 24666: Simulating the LEAD function by comparing the value of a variable to its value in the next observation

Operating System and Release Information

E-mail:
Password