SUPPORT

Select Your Region

Visit the Cary, NC, US corporate headquarters site

Americas

Europe

Middle East & Africa

Asia Pacific

View our worldwide contacts list for help finding your region

Americas

Europe

Middle East & Africa

Asia Pacific

Sign In

Get access to My SAS, trials, communities and more.

Sign Out

Get access to My SAS, trials, communities and more.

SAS Sites

sas.com
Support
Blogs
Communities
Developer
Curiosity
Videos

Documentation

Learn
Brand
PartnerNet
Merchandise
SUPPORT / SAMPLES & SAS NOTES
 

Support

Sample 26151: Using user-defined functions in statistical procedures in SAS® 9.1.3

DetailsCodeOutputAboutRate It

This example demonstrates usage of the FCMP procedure. A new function is defined, stored, and tested and then used by another procedure.

In the first section of code, the function is defined: 

proc fcmp outlib = sasuser.FCMP_Cat.fcns; 
  function ln(x);
    y = log(x);
    return(y);
  endsub;
quit;

The new function, "LN," is simply the "LOG" function in SAS, which is the natural logarithm. While this new function definition is simple, the ability to define your own function is powerful. You are no longer limited to functions that are predefined within SAS.

The newly-defined "LN" function is then stored in the "fcns" package of the "FCMP_Cat" catalog in the "sasuser" library. Additional details on syntax of the FCMP procedure are available in the FCMP Procedure documentation.

The CMPLIB= system option is then used to let SAS know that the this catalog contains functions that need to be compiled during the program compilation: 

options cmplib=(sasuser.FCMP_Cat);

A test call to the function demonstrates that it is available in the function package and that it performs the computation as expected: 

proc fcmp;
  out = ln(10);
  put "Testing Function Call";
  put "LN(10) returns:" out;
quit;

The output from that test call is displayed on Page 1 of the output listing. See the Output tab for this result.

Data that follows the model specification

    y = log(a*x) + z
is then generated for use in the MODEL procedure, where z is a standard normal random variable, a is the population parameter, x is the independent variable, and y is the dependent variable. 

data logdata;
  a = 0.5;
  do x=1 to 10000;
    z = rannor(123);
    y = log(a*x) + z;
    output;
  end;
run;

Finally, the parameter a is estimated using the MODEL procedure, based on the data that was just generated: 

proc model data = logdata;
  parameters a;
  y = ln(a*x);
  fit y;
run;
quit;

Notice that the "LN" function that was defined in the code above is available to and successfully utilized by the MODEL procedure. This simple example demonstrates the power of the FCMP procedure, and the concepts here may be extended to define multiple complex functions to be used by other SAS procedures alongside predefined SAS functions.

The output generated by the MODEL procedure is available on the Output tab, Pages 2-4. See the Full Code tab for a full set of standalone code for this example.

Additional Notes and Updates

  • In SAS 9.1.3, user-defined FCMP functions and subroutines cannot be called from the DATA step (see SAS Note 41809). Functions and subroutines are stored in SAS catalogs. See The FCMP Procedure (SAS 9.1).
  • In SAS 9.2 and later, user-defined FCMP functions and subroutines can be called from the DATA step. Functions and subroutines are stored in SAS data sets. See The FCMP Procedure (SAS 9.2).


These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.