Example 88.4 Confirmatory Factor Analysis: Cognitive Abilities

In this example, cognitive abilities of 64 students from a middle school were measured. The fictitious data contain nine cognitive test scores. Three of the scores were for reading skills, three others were for math skills, and the remaining three were for writing skills. The covariance matrix for the nine variables was obtained. A confirmatory factor analysis with three factors was conducted. The following is the input data set and the PROC TCALIS specification for the analysis:

   title "Confirmatory Factor Analysis Using the FACTOR Modeling Language";
   title2 "Cognitive Data";    
   data cognitive1(type=cov);
      _type_='cov';
      input _name_ $ reading1 reading2 reading3 math1 math2 math3 
            writing1 writing2 writing3;
      datalines;
   reading1 83.024    .      .      .      .      .      .      .      .   
   reading2 50.924 108.243   .      .      .      .      .      .      .   
   reading3 62.205  72.050 99.341   .      .      .      .      .      .   
   math1    22.522  22.474 25.731 82.214   .      .      .      .      .   
   math2    14.157  22.487 18.334 64.423 96.125   .      .      .      .   
   math3    22.252  20.645 23.214 49.287 58.177 88.625   .      .      .   
   writing1 33.433  42.474 41.731 25.318 14.254 27.370 90.734   .      .   
   writing2 24.147  20.487 18.034 22.106 26.105 22.346 53.891 96.543   .   
   writing3 13.340  20.645 23.314 19.387 28.177 38.635 55.347 52.999 98.445  
   ;

   proc tcalis data=cognitive1 nobs=64 modification;
      factor
         Read_Factor   -> reading1-reading3  = load1-load3,
         Math_Factor   -> math1-math3        = load4-load6,
         Write_Factor  -> writing1-writing3  = load7-load9;
      pvar
         Read_Factor Math_Factor Write_Factor = 3 * 1.,
         reading1-reading3 math1-math3 writing1-writing3 = errvar1-errvar9;
   run;

In the PROC TCALIS statement, the number of observations is specified with the NOBS= option. The MODIFICATION option in the same statement requests model modification indices be computed.

The FACTOR modeling language is the most handy tool for specifying confirmatory factor models. The FACTOR statement is used to invoke this modeling language. Entries in the FACTOR statement are for specifying factor-variables relationships and are separated by commas. In each entry, you first specify a latent factor, followed by the right arrow sign –>. Then you specify the observed variables that have nonzero loadings on the factor. Next, an equal sign is used to signify the specification of the loading parameters that follow. The loading parameters can be names (parameters without initial estimates), numbers (fixed values), or names followed by parenthesized numbers (parameter with initial values). In this example, there are three factors: Read_Factor, Math_Factor, and Write_Factor. These factors have simple cluster structures with the nine observed variables. Each observed variable has only one loading on exactly one factor, yielding a total of nine loading parameters named load1–load9. No initial estimates are specified for them. They are computed by PROC TCALIS.

In the PVAR statement, you specify the variances of the factors and the error variances for the observed variables. The factor variances in this model are fixed at ones for identification purposes. The error variances for the observed variables are free parameters without initial estimates, named errvar1–errvar9, respectively.

The covariances of the factors are not specified in the model, meaning that the factors are uncorrelated by default. Certainly, this might not be reasonable. But for illustration purposes, this uncorrelated factor model is fitted. With the MODIFICATION option in the PROC TCALIS statement, LM (Lagrange Multiplier) tests are conducted. The results of LM tests can suggest the inclusion of additional parameters for a better model fit. If the uncorrelated factor model is indeed unreasonable, it is shown in the results of the LM tests.

In Output 88.4.1, the initial model specification is echoed in matrix form. The observed variables and factors are also displayed.

In the table for initial factor loading matrix, the nine loading parameters are shown to have simple cluster relations with the factors. In the table for initial factor covariance matrix, the diagonal matrix shows that the factors are not correlated. The diagonal elements are fixed at ones so that this matrix is also a correlation matrix for the factors. In the table for initial error variances, the nine variance parameters are shown. No initial estimates were specified, as indicated by the missing values '.'.

In Output 88.4.2, initial estimates are generated by the instrumental variable method and the McDonald method.

These initial estimates turn out to be pretty good, in the sense that only three more iterations are needed to converge to the maximum likelihood estimates and the final function value does not change much from the initial function value , as shown in Output 88.4.3.

The fit summary is shown in Output 88.4.4.

Using the chi-square model test criterion, the uncorrelated factor model should be rejected at . The RMSEA estimate is , which is not indicative of a good fit according to Browne and Cudeck (1993). Other indices might suggest only a marginal good fit. For example, Bentler’s comparative fit index and Bollen non-normed index delta2 are both above 0.90. However, many other do not attain this 0.90 level. For example, adjusted GFI is only . It is thus safe to conclude that there could be some improvements on the model fit.

The MODIFICATION option in the PROC TCALIS statement has been used to request for computing the LM test indices for model modifications. The results are shown in Output 88.4.5.

Three different tables for ranking the LM test results are shown. In the first table, the new loading parameters that would improve the model fit the most are shown first. For example, in the first row a new factor loading of writing1 on the Read_Factor is suggested to improve the model fit the most. The LM Stat value is . This is an approximation of the chi-square drop if this parameter was included in the model. The Pr > ChiSq value of indicates a significant improvement of model fit at . Nine more new loading parameters are suggested in the table, with less and less statistical significance in the change of model fit chi-square. Note that these approximate chi-squares are one-at-a-time chi-square changes. That means that the overall chi-square drop is not a simple sum of individual chi-square changes when you include two or more new parameters in the modified model.

The other two tables in Output 88.4.5 shows the new parameters in factor covariances, error variances, or error covariances that would result in a better model fit. The table for the new parameters of the factor covariance matrix indicates that adding each of the covariances among factors might lead to a statistically significant improvement in model fit. This confirms with the initial argument that uncorrelated factors might not reasonable in this case—it fails to explain the covariances among observed variables through the correlations among latent factors. The largest LM Stat value in this table is , which is smaller than that of the largest LM Stat for the factor loading parameters. Despite this, it is more reasonable to add the covariance parameters among factors first to determine whether that improves the model fit. To do this, you need to add the COV statement for specifying the covariances among factors to the original code. The following statements are used to specify the modified factor model with covariances among factors:

   proc tcalis data=cognitive1 nobs=64;
      factor
         Read_Factor   -> reading1-reading3  = load1-load3,
         Math_Factor   -> math1-math3        = load4-load6,
         Write_Factor  -> writing1-writing3  = load7-load9;
      pvar
         Read_Factor Math_Factor Write_Factor = 3 * 1.,
         reading1-reading3 math1-math3 writing1-writing3 = errvar1-errvar9;
      cov Read_Factor Math_Factor Write_Factor = fcov1-fcov3;
   run;

The fit summary is shown in Output 88.4.6.

The model fit chi-square value is , which is about less than the model with uncorrelated factors. The -value is , indicating a fairly satisfactory model fit. The RMSEA value is , which is close to , a value recommended as an indication of good model fit by Browne and Cudeck (1993). More fit indices that do not attain the level with the uncorrelated factor model now have values close to or above . These include the goodness-of-fit index (GFI), McDonald centrality, Bentler-Bonnet NFI, and Bentler-Bonnet non-normed index. By all counts, the correlated factor model is a much better fit than the uncorrelated factor model.

In Output 88.4.7, the estimation results for factor loadings are shown. All these loadings are statistically significant, indicating non-chance relationships with the factors.

In Output 88.4.8, the factor covariance matrix is shown. Because the diagonal elements are all ones, the off-diagonal elements are correlations among factors. The correlations range from –. These factors are moderately correlated.

In Output 88.4.9, the error variances for variables are shown.

All values except the one for reading3 are bigger than , a value close to a critical -value at . This means that the error variance for reading3 could have been zero in the population, or it could have been nonzero but the current sample just has this nonsignificant value by chance (that is, a Type 2 error). Further research is needed to confirm either way.

In addition to the parameter estimation results, PROC TCALIS also outputs supplementary results that could be useful for interpretations. In Output 88.4.10, the squared multiple correlations and the factor scores regression coefficients are shown.

The percentages of variance for the observed variables that can be explained by the factors are shown in the R-Square column of the table for squared multiple correlations (R-squares). These R-squares can be interpreted meaningfully because there is no reciprocal relationships among variables or correlated errors in the model. All estimates of R-squares are bounded between and .

In the table for factor scores regression coefficients, entries are coefficients for the variables you can use to create the factor scores. The larger the coefficient, the more influence of the corresponding variable for creating the factor scores. It makes intuitive sense to see the cluster pattern of these coefficients—the reading measures are more important to create the latent variable scores of Read_Factor and so on.