A Combined Measurement-Structural Model with Reciprocal Influence and Correlated Residuals

To illustrate a more complex model, this example uses some well-known data from Haller and Butterworth (1960). Various models and analyses of these data are given by Duncan, Haller, and Portes (1968), Jöreskog and Sörbom (1988), and Loehlin (1987).

The study is concerned with the career aspirations of high school students and how these aspirations are affected by close friends. The data are collected from 442 seventeen-year-old boys in Michigan. There are 329 boys in the sample who named another boy in the sample as a best friend. The observations to be analyzed consist of the data from these 329 boys paired with the data from their best friends.

The method of data collection introduces two statistical problems. First, restricting the analysis to boys whose best friends are in the original sample causes the reduced sample to be biased. Second, since the data from a given boy might appear in two or more observations, the observations are not independent. Therefore, any statistical conclusions should be considered tentative. It is difficult to accurately assess the effects of the dependence of the observations on the analysis, but it could be argued on intuitive grounds that since each observation has data from two boys and since it seems likely that many of the boys will appear in the data set at least twice, the effective sample size might be as small as half of the reported 329 observations.

The correlation matrix, taken from Jöreskog and Sörbom (1988), is shown in the following DATA step:

   title 'Peer Influences on Aspiration: Haller & Butterworth (1960)';
   data aspire(type=corr);
      _type_='corr';
      input _name_ $ riq rpa rses roa rea fiq fpa fses foa fea;
      label riq='Respondent: Intelligence'
            rpa='Respondent: Parental Aspiration'
            rses='Respondent: Family SES'
            roa='Respondent: Occupational Aspiration'
            rea='Respondent: Educational Aspiration'
            fiq='Friend: Intelligence'
            fpa='Friend: Parental Aspiration'
            fses='Friend: Family SES'
            foa='Friend: Occupational Aspiration'
            fea='Friend: Educational Aspiration';
      datalines;
   riq   1.      .      .      .      .      .       .      .      .      .
   rpa   .1839  1.      .      .      .      .       .      .      .      .
   rses  .2220  .0489  1.      .      .      .       .      .      .      .
   roa   .4105  .2137  .3240  1.      .      .       .      .      .      .
   rea   .4043  .2742  .4047  .6247  1.      .       .      .      .      .
   fiq   .3355  .0782  .2302  .2995  .2863  1.       .      .      .      .
   fpa   .1021  .1147  .0931  .0760  .0702  .2087   1.      .      .      .
   fses  .1861  .0186  .2707  .2930  .2407  .2950  -.0438  1.      .      .
   foa   .2598  .0839  .2786  .4216  .3275  .5007   .1988  .3607  1.      .
   fea   .2903  .1124  .3054  .3269  .3669  .5191   .2784  .4105  .6404  1.
   ;

The model analyzed by Jöreskog and Sörbom (1988) is displayed in the path diagram in Figure 17.17.

Figure 17.17 Path Diagram: Career Aspiration – Jöreskog and Sörbom (1988)

Two latent variables, f_ramb and f_famb, represent the respondent’s level of ambition and his best friend’s level of ambition, respectively. The model states that the respondent’s ambition is determined by his intelligence (riq) and socioeconomic status (rses), his perception of his parents’ aspiration for him (rpa), and his friend’s socioeconomic status (fses) and ambition (f_famb). It is assumed that his friend’s intelligence (fiq) and parental aspiration (fpa) affect the respondent’s ambition only indirectly through the friend’s ambition (f_famb). Ambition is indexed by the manifest variables of occupational (roa) and educational aspiration (rea), which are assumed to have uncorrelated residuals. The path coefficient from ambition to occupational aspiration is set to 1.0 to determine the scale of the ambition latent variable.

This model can be analyzed with PROC TCALIS by using the PATH modeling language, as shown in the following statements:

   proc tcalis corr data=aspire nobs=329;
      path
         /* measurement model for aspiration */
         rea <-  f_ramb    lambda2,
         roa <-  f_ramb    1.,
         foa <-  f_famb    1.,
         fea <-  f_famb    lambda3,
         /* structural model of influences */
         f_ramb <- rpa     gam1,
         f_ramb <- riq     gam2,
         f_ramb <- rses    gam3, 
         f_ramb <- fses    gam4,
         f_famb <- rses    gam5,
         f_famb <- fses    gam6, 
         f_famb <- fiq     gam7,
         f_famb <- fpa     gam8,
         f_ramb <- f_famb  beta1,
         f_famb <- f_ramb  beta2;
      pvar
         f_ramb = psi11,
         f_famb = psi22,
         rpa riq rses fpa fiq fses = v1-v6,
         rea roa fea foa = theta1-theta4;
      pcov
         f_ramb f_famb = psi12,
         rpa riq rses fpa fiq fses = 15 * cov__;
   run;

In this specification, the names of the parameters correspond to those used by Jöreskog and Sörbom (1988). Since this TYPE=CORR data set does not contain an observation with _TYPE_=’N’ giving the sample size, it is necessary to specify the NOBS= option in the PROC TCALIS statement.

Specifying a name followed by double underscores is a quick way to generate unique parameter names. The double underscores are replaced with a unique number each time a new parameter name is generated. For example, in the COV statement, the specification

   rpa riq rses fpa fiq fses = 15 * cov__;

is equivalent to

   rpa riq rses fpa fiq fses = cov01-cov15;

In the PROC TCALIS statement, the CORR option is used to indicate that the correlation matrix is fitted by the model. Fitting correlation matrices by covariance structure modeling method is plagued with some statistical issues. For example, the chi-square statistic might not follow the theoretical distribution well, and the estimates of standard errors might not be accurate. Nonetheless, the correlation matrix is fitted here for illustration and comparison purposes.

The results from this analysis are displayed in Figure 17.18.

Jöreskog and Sörbom (1988) present more detailed results from a second analysis in which two constraints are imposed:

• The coefficients connecting the latent ambition variables are equal (that is, beta1 beta2).

• The covariance of the disturbances of the ambition variables is zero (that is, psi12 ).

This analysis can be performed by changing the names beta1 and beta2 to beta and omitting the line from the COV statement for psi12, as shown in the following statements:

   proc tcalis corr data=aspire nobs=329;
      path
         /* measurement model for aspiration */
         rea <-  f_ramb    lambda2,
         roa <-  f_ramb    1.,
         foa <-  f_famb    1.,
         fea <-  f_famb    lambda3,
         /* structural model of influences */
         f_ramb <- rpa     gam1,
         f_ramb <- riq     gam2,
         f_ramb <- rses    gam3, 
         f_ramb <- fses    gam4,
         f_famb <- rses    gam5,
         f_famb <- fses    gam6, 
         f_famb <- fiq     gam7,
         f_famb <- fpa     gam8,
         f_ramb <- f_famb  beta,
         f_famb <- f_ramb  beta;
      pvar
         f_ramb = psi11,
         f_famb = psi22,
         rpa riq rses fpa fiq fses = v1-v6,
         rea roa fea foa = theta1-theta4;
      pcov
         rpa riq rses fpa fiq fses = 15 * cov__;
    run;

The fit summary is displayed in Figure 17.19, and the estimation results are displayed in Figure 17.20.

The difference between the chi-square values for the two preceding models is with degrees of freedom, which is far from significant. This indicates that the restricted model (analysis 2) fits as well as the unrestricted model (analysis 1). However, the chi-square test of the restricted model against the alternative of a completely unrestricted covariance matrix yields a p-value of 0.0596, which indicates that the model might not be entirely satisfactory (p-values from these data are probably too small because of the dependence of the observations).

Loehlin (1987) points out that the models considered are unrealistic in at least two respects. First, the variables of parental aspiration, intelligence, and socioeconomic status are assumed to be measured without error. Loehlin adds uncorrelated measurement errors to the model and assumes, for illustrative purposes, that the reliabilities of these variables are known to be 0.7, 0.8, and 0.9, respectively. In practice, these reliabilities would need to be obtained from a separate study of the same or a very similar population. If these constraints are omitted, the model is not identified. However, constraining parameters to a constant in an analysis of a correlation matrix might make the chi-square goodness-of-fit test inaccurate, so there is more reason to be skeptical of the p-values. Second, the error terms for the respondent’s aspiration are assumed to be uncorrelated with the corresponding terms for his friend. Loehlin introduces a correlation between the two educational aspiration error terms and between the two occupational aspiration error terms. These additions produce the path diagram for Loehlin’s model 1 shown in Figure 17.21.

Figure 17.21 Path Diagram: Career Aspiration – Loehlin (1987)

In Figure 17.21, the observed variables rpa, riq, rses, fses, fiq, and fpa are all treated as measurements with errors. Their purified counterparts f_rpa, f_riq, f_rses, f_fses, f_fiq, and f_fpa are latent variables created in the model to represent measurements without errors. Path coefficients from these latent variables to the observed variables are fixed coefficients, indicating the square roots of the theoretical reliabilities in the model. These latent variables, rather than the observed counterparts, serve as predictors of the ambition variables f_ramb and f_famb. Correlated errors for the occupational aspiration variables and the educational aspiration variables are also shown in Figure 17.21. The error covariance for the educational aspiration variables rea and fea is indicated by the parameter covea, and the error covariance for the occupational aspiration variables roa and foa is indicated by the parameter covoa.

The statements for fitting this model by using the PATH modeling language are as follows:

   proc tcalis corr data=aspire nobs=329;
      path
         /* measurement model for aspiration */
         rea  <-  f_ramb    lambda2,
         roa  <-  f_ramb    1.,
         foa  <-  f_famb    1.,
         fea  <-  f_famb    lambda3,
   
         /* measurement model for intelligence and environment */
         rpa  <-  f_rpa     0.837,
         riq  <-  f_riq     0.894,
         rses <-  f_rses    0.949,
         fses <-  f_fses    0.949,
         fiq  <-  f_fiq     0.894,
         fpa  <-  f_fpa     0.837,
   
         /* structural model of influences */
         f_ramb <- f_rpa     gam1,
         f_ramb <- f_riq     gam2,
         f_ramb <- f_rses    gam3, 
         f_ramb <- f_fses    gam4,
         f_famb <- f_rses    gam5,
         f_famb <- f_fses    gam6, 
         f_famb <- f_fiq     gam7,
         f_famb <- f_fpa     gam8,
         f_ramb <- f_famb    beta1,
         f_famb <- f_ramb    beta2;
      pvar
         f_ramb = psi11,
         f_famb = psi22,
         f_rpa f_riq f_rses f_fses f_fiq f_fpa = 6 * 1.0,
         rea roa fea foa                       = theta1-theta4,
         rpa riq rses fpa fiq fses             = err1-err6;
      pcov
         f_ramb f_famb   = psi12,
         rea  fea        = covea,
         roa  foa        = covoa,
         f_rpa f_riq f_rses f_fses f_fiq f_fpa = 15 * cov__;
   run;

The fit summary is displayed in Figure 17.22, and the estimation results are displayed in Figure 17.23.

Since the p-value for the chi-square test is , this model clearly cannot be rejected. However, Schwarz’s Bayesian criterion for this model (SBC ) is somewhat larger than for Jöreskog and Sörbom’s (1988) analysis 2 (SBC ), suggesting that a more parsimonious model would be desirable.

Since it is assumed that the same model applies to all the boys in the sample, the path diagram should be symmetric with respect to the respondent and his friend. In particular, the corresponding coefficients should be equal. By imposing equality constraints on the pairs of corresponding coefficients, this example obtains Loehlin’s (1987) model 2. The PATH model is as follows, where an OUTMODEL= data set is created to facilitate subsequent hypothesis tests:

   proc tcalis corr data=aspire nobs=329 outmodel=model2;
      path
         /* measurement model for aspiration */
         rea  <-  f_ramb    lambda,              /* 1 ec! */
         roa  <-  f_ramb    1.,
         foa  <-  f_famb    1.,
         fea  <-  f_famb    lambda,
   
         /* measurement model for intelligence and environment */
         rpa  <-  f_rpa     0.837,
         riq  <-  f_riq     0.894,
         rses <-  f_rses    0.949,
         fses <-  f_fses    0.949,
         fiq  <-  f_fiq     0.894,
         fpa  <-  f_fpa     0.837,
   
         /* structural model of influences */
         f_ramb <- f_rpa     gam1,               /* 5 ec! */
         f_ramb <- f_riq     gam2,
         f_ramb <- f_rses    gam3, 
         f_ramb <- f_fses    gam4,
         f_famb <- f_rses    gam4,
         f_famb <- f_fses    gam3, 
         f_famb <- f_fiq     gam2,
         f_famb <- f_fpa     gam1,
         f_ramb <- f_famb    beta,
         f_famb <- f_ramb    beta;
      pvar
         f_ramb = psi,                           /* 1 ec! */
         f_famb = psi,
         f_rpa f_riq f_rses f_fpa f_fiq f_fses = 6 * 1.0,
         rea fea                 = 2 * thetaea,  /* 2 ec! */
         roa foa                 = 2 * thetaoa,
         rpa fpa                 = errpa1 errpa2,
         riq fiq                 = erriq1 erriq2,
         rses fses               = errses1 errses2;
      pcov
         f_ramb f_famb           = psi12,
         rea  fea                = covea,
         roa  foa                = covoa,
         f_rpa f_riq f_rses      = cov1-cov3,          /* 3 ec! */
         f_fpa f_fiq f_fses      = cov1-cov3,
         f_rpa f_riq f_rses * f_fpa f_fiq f_fses =     /* 3 ec! */
             cov4 cov5 cov6
             cov5 cov7 cov8
             cov6 cov8 cov9;
   run;

The fit summary is displayed in Figure 17.24, and the estimation results are displayed in Figure 17.25.

The test of Loehlin’s (1987) model 2 against model 1 yields a chi-square of with degrees of freedom, which is clearly not significant. This indicates the restricted model 2 fits at least as well as model 1. Schwarz’s Bayesian criterion (SBC) is also much lower for model 2 () than for model 1 (). Hence, model 2 seems preferable on both substantive and statistical grounds.

A question of substantive interest is whether the friend’s socioeconomic status (SES) has a significant direct influence on a boy’s ambition. This can be addressed by omitting the paths from f_fses to f_ramb and from f_rses to f_famb designated by the parameter name gam4, yielding Loehlin’s (1987) model 3:

   title2 'Loehlin (1987) analysis: Model 3';
   data model3(type=calismdl);
      set model2;
      if _name_='gam4' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc tcalis corr data=aspire nobs=329 inmodel=model3;
   run;

The fit summary is displayed in Figure 17.26.

The chi-square value for testing model 3 versus model 2 is with degree of freedom and a p-value of . Although the parameter is of marginal significance, the estimate in model 2 () is small compared to the other coefficients, and SBC indicates that model 3 is preferable to model 2.

Another important question is whether the reciprocal influences between the respondent’s and friend’s ambitions are needed in the model. To test whether these paths are zero, set the parameter beta for the paths linking f_ramb and f_famb to zero to obtain Loehlin’s (1987) model 4:

   title2 'Loehlin (1987) analysis: Model 4';
   data model4(type=calismdl);
      set model2;
      if _name_='beta' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc tcalis corr data=aspire nobs=329 inmodel=model4;
   run;

The fit summary is displayed in Figure 17.27, and the estimation results are displayed in Figure 17.28.

The chi-square value for testing model 4 versus model 2 is with degree of freedom and a p-value of . Hence, there is little evidence of reciprocal influence.

Loehlin’s (1987) model 2 has not only the direct paths connecting the latent ambition variables f_ramb and f_famb but also a covariance between the disturbance terms d_ramb and d_famb to allow for other variables omitted from the model that might jointly influence the respondent and his friend. To test the hypothesis that this covariance is zero, set the parameter psi12 to zero, yielding Loehlin’s (1987) model 5:

   title2 'Loehlin (1987) analysis: Model 5';
   data model5(type=calismdl);
      set model2;
      if _name_='psi12' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc tcalis corr data=aspire nobs=329 inmodel=model5;
   run;

The fit summary is displayed in Figure 17.29, and the estimation results are displayed in Figure 17.30.

The chi-square value for testing model 5 versus model 2 is with degree of freedom. This test statistic is insignificant. Omitting the covariance between the disturbance terms, therefore, causes hardly any deterioration in the fit of the model.

These data fail to provide evidence of direct reciprocal influence between the respondent’s and friend’s ambitions or of a covariance between the disturbance terms when these hypotheses are considered separately. Notice, however, that the covariance psi12 between the disturbance terms increases from for model 2 to for model 4. Before you conclude that all of these paths can be omitted from the model, it is important to test both hypotheses together by setting both beta and psi12 to zero as in Loehlin’s (1987) model 7:

   title2 'Loehlin (1987) analysis: Model 7';
   data model7(type=calismdl);
      set model2;
      if _name_='psi12'|_name_='beta' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc tcalis corr data=aspire nobs=329 inmodel=model7;
   run;

The fit summary is displayed in Figure 17.31, and the estimation results are displayed in Figure 17.32.

When model 7 is tested against models 2, 4, and 5, the p-values are respectively 0.0433, 0.0370, and 0.0123, indicating that the combined effect of the reciprocal influence and the covariance of the disturbance terms is statistically significant. Thus, the hypothesis tests indicate that it is acceptable to omit either the reciprocal influences or the covariance of the disturbances, but not both.

It is also of interest to test the covariances between the error terms for educational (covea) and occupational aspiration (covoa), since these terms are omitted from Jöreskog and Sörbom’s (1988) models. Constraining covea and covoa to zero produces Loehlin’s (1987) model 6:

   title2 'Loehlin (1987) analysis: Model 6';
   data model6(type=calismdl);
      set model2;
      if _name_='covea'|_name_='covoa' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc tcalis corr data=aspire nobs=329 inmodel=model6;
   run;

The fit summary is displayed in Figure 17.33.

The chi-square value for testing model 6 versus model 2 is with degrees of freedom and a p-value of , indicating that there is considerable evidence of correlation between the error terms.

The following table summarizes the results from Loehlin’s (1987) seven models.

For comparing models, you can use a DATA step to compute the differences of the chi-square statistics and p-values:

   data _null_;
      array achisq[7] _temporary_
         (12.0132 19.0697 23.0365 20.9981 19.0745 33.4475 25.3466);
      array adf[7] _temporary_
         (13 28 29 29 29 30 30);
      retain indent 16;
      file print;
      input ho ha @@;
      chisq = achisq[ho] - achisq[ha];
      df = adf[ho] - adf[ha];
      p = 1 - probchi( chisq, df);
      if _n_ = 1 then put
         / +indent 'model comparison   chi**2   df  p-value'
         / +indent '---------------------------------------';
      put +indent +3 ho ' versus ' ha @18 +indent chisq 8.4 df 5. p 9.4;
   datalines;
   2 1    3 2    4 2    5 2    7 2    7 4    7 5    6 2
   ;

The DATA step displays the table in Figure 17.34.

                model comparison   chi**2   df  p-value                         
                ---------------------------------------                         
                   2  versus 1     7.0565   15   0.9561                         
                   3  versus 2     3.9668    1   0.0464                         
                   4  versus 2     1.9284    1   0.1649                         
                   5  versus 2     0.0048    1   0.9448                         
                   7  versus 2     6.2769    2   0.0433                         
                   7  versus 4     4.3485    1   0.0370                         
                   7  versus 5     6.2721    1   0.0123                         
                   6  versus 2    14.3778    2   0.0008                         

Although none of the seven models can be rejected when tested against the alternative of an unrestricted covariance matrix, the model comparisons make it clear that there are important differences among the models. Schwarz’s Bayesian criterion indicates model 5 as the model of choice. The constraints added to model 5 in model 7 can be rejected (p=0.0123), while model 5 cannot be rejected when tested against the less constrained model 2 (p=0.9448). Hence, among the small number of models considered, model 5 has strong statistical support. However, as Loehlin (1987, p. 106) points out, many other models for these data could be constructed. Further analysis should consider, in addition to simple modifications of the models, the possibility that more than one friend could influence a boy’s aspirations, and that a boy’s ambition might have some effect on his choice of friends. Pursuing such theories would be statistically challenging.