INPUTC関数

実行時に文字の入力形式を指定できるようにします。

カテゴリ:

特殊

構文

構文

INPUTC(source, informat <, w>)

必須引数

source

入力形式を適用する文字定数、変数または式を指定します。

informat

sourceに適用する文字の入力形式が含まれる文字定数、変数または式です。

オプション引数

w

入力形式に適用する幅を指定する数値定数、変数または式です。

操作	ここで指定した幅は、入力形式での幅の指定より優先されます。

詳細

INPUTC関数が長さの割り当てられていない変数に値を返した場合、デフォルトでは変数の長さは最初の引数の長さによって決定されます。

比較

INPUTN関数は、実行時に数値の入力形式を指定できるようにします。INPUT関数はコンパイル時に入力形式を指定するため、INPUT関数を使用した方が高速です。

例

この例では、文字の入力形式を指定する方法を示します。この例のPROC FORMATステップでは、このステップで同時に作成する3つの入力形式のいずれかの名前で変数値1、2および3を書式化する、出力形式TYPEFMT.を作成します。これらの入力形式では、質問の種類に応じて、異なる単語として"positive"、"negative"および"neutral"の応答を格納します。PROC FORMATで出力形式と入力形式を作成した後に、DATAステップで質問と応答の種類を識別する番号で構成された生データを使用して、SASデータセットを作成します。レコードの読み取り後、DATAステップでTYPEの値を使用して、現在の質問の種類に適切な入力形式の値が含まれる変数RESPINFを作成します。また、応答に適切な単語の値が含まれる別の変数WORDもDATAステップで作成します。INPUTC関数は、質問の種類と適切な入力形式に基づいてWORDの値を割り当てます。

   proc format;
      value typefmt 1='$groupx' 
                    2='$groupy'
                    3='$groupz';
      invalue $groupx 'positive'='agree'
                      'negative'='disagree'
                      'neutral'='notsure';
      invalue $groupy 'positive'='accept'
                      'negative'='reject'
                      'neutral'='possible';
      invalue $groupz 'positive'='pass'
                      'negative'='fail'
                      'neutral'='retest';
   run;
   data answers;
      input type response $;
      respinformat=put(type, typefmt.);
      word=inputc(response, respinformat);
      datalines;
   1 positive
   1 negative
   1 neutral
   2 positive
   2 negative
   2 neutral
   3 positive
   3 negative
   3 neutral
   ;

開始オブザベーションのWORDの値はagreeです。最終オブザベーションのWORDの値はretestです。

INPUTC関数

構文

必須引数

source

informat

オプション引数

w

詳細

比較

例

関連項目: