The RELIABILITY Procedure

Doganaksoy, Hahn, and Meeker (2002) analyzed failure data for the dielectric insulation of generator armature bars. A sample of 58 segments of bars were subjected to a high voltage stress test. Based on examination of the sample after the test, failures were attributed to one of two modes:

The following SAS statements create a SAS data set that contains the failure data:

data Voltage;
   input Hours Mode$ @@;
   if Mode = 'Cen' then Status = 1;
   else Status = 0;
   datalines;
2   E   3   E   5   E   8   E   13  Cen 21  E
28  E   31  E   31  Cen 52  Cen 53  Cen 64  E
67  Cen 69  E   76  E   78  Cen 104 E   113 Cen
119 E   135 Cen 144 E   157 Cen 160 E   168 D
179 Cen 191 D   203 D   211 D   221 E   226 D
236 E   241 Cen 257 Cen 261 D   264 D   278 D
282 E   284 D   286 D   298 D   303 E   314 D
317 D   318 D   320 D   327 D   328 D   328 D
348 D   348 Cen 350 D   360 D   369 D   377 D
387 D   392 D   412 D   446 D
;

The variable Hours represents the number of hours until a failure, or the number of hours on test if the sample unit did not fail. The variable Mode represents the failure mode: D for degradation failure, E for early failures, or Cen if the unit did not fail (i.e., is right-censored). The computed variable Status is a numeric indicator for censored observations.

The following statements fit a Weibull distribution to the individual failure modes (D and E), and compute the failure distribution with both modes acting:

proc reliability data=Voltage;
   distribution Weibull;
   pplot Hours*Status(1) / pref(intersect) = 10
                           preflabel = ('10th Percentile')
                           survtime = 100 200 300 400 500 1000
                           lupper = 500;
   fmode combine = Mode( 'D' 'E' );
run;

Figure 17.27 contains estimates of the combined failure mode survival function at the times specified with the SURVTIME = option in the PPLOT statement.

Figure 17.28 shows Weibull parameter estimates for the two individual failure modes.

Figure 17.29 is a Weibull probability plot of the failure probability distribution with the two failure modes combined, along with approximate pointwise 95% confidence limits. A reference line at the 10% point on the probability axis intersecting the distribution curve shows the tenth percentile of lifetimes when both modes act to be about 34 hours.

Figure 17.29: Weibull Plot for Failure Modes D and E

The following SAS statements create the Weibull probability plot in Figure 17.30:

proc reliability data=Voltage;
   distribution Weibull;
   pplot Hours*Status(1) / pref(intersect) = 10
                           preflabel = ('10th Percentile')
                           survtime = 100 200 300 400 500 1000
                           noconf
                           lupper = 500;
   fmode combine = Mode( 'D' 'E' ) / plotmodes;
run;

The PLOTMODES option in the FMODE statement cause the Weibull fits for the individual failure modes to be included on the probability plot. The combined failure mode curve is almost the same as the fit curve for mode E for lifetimes less than 100 hours, and slightly greater than the fit curve for mode D for lifetimes greater than 100 hours.

Figure 17.30: Weibull Plot for Failure Modes D and E with Individual Modes