The RELIABILITY Procedure

The Weibull distribution is used in a wide variety of reliability analysis applications. This example illustrates the use of the Weibull distribution to model product life data from a single population. The following statements create a SAS data set containing observed and right-censored lifetimes of 70 diesel engine fans (Nelson 1982, p. 318):

data fan;                                                                         
   input Lifetime censor @@;                    
   Lifetime = Lifetime/1000;                    
   label lifetime='Fan Life (1000s of Hours)';  
   datalines;                                 
 450 0    460 1   1150 0   1150 0   1560 1 
1600 0   1660 1   1850 1   1850 1   1850 1 
1850 1   1850 1   2030 1   2030 1   2030 1 
2070 0   2070 0   2080 0   2200 1   3000 1 
3000 1   3000 1   3000 1   3100 0   3200 1 
3450 0   3750 1   3750 1   4150 1   4150 1 
4150 1   4150 1   4300 1   4300 1   4300 1 
4300 1   4600 0   4850 1   4850 1   4850 1 
4850 1   5000 1   5000 1   5000 1   6100 1 
6100 0   6100 1   6100 1   6300 1   6450 1 
6450 1   6700 1   7450 1   7800 1   7800 1 
8100 1   8100 1   8200 1   8500 1   8500 1 
8500 1   8750 1   8750 0   8750 1   9400 1 
9900 1  10100 1  10100 1  10100 1  11500 1 
;                                          

Some of the fans had not failed at the time the data were collected, and the unfailed units have right-censored lifetimes. The variable Lifetime represents either a failure time or a censoring time in thousands of hours. The variable Censor is equal to 0 if the value of Lifetime is a failure time, and it is equal to 1 if the value is a censoring time.

If ODS Graphics is disabled, graphical output is created using traditional graphics; otherwise, ODS Graphics is used. The following statements use the RELIABILITY procedure to produce the traditional graphical output shown in Figure 17.1:

ODS Graphics OFF;
proc reliability data=fan;
   distribution Weibull;
   pplot lifetime*censor( 1 ) /  covb ;
run;
ODS Graphics ON;

The DISTRIBUTION statement specifies the Weibull distribution for probability plotting and maximum likelihood (ML) parameter estimation. The PROBPLOT statement produces a probability plot for the variable Lifetime and specifies that the value of 1 for the variable Censor denotes censored observations. You can specify any value, or group of values, for the censor-variable (in this case, Censor) to indicate censoring times. The option COVB requests the ML parameter estimate covariance matrix.

The graphical output, displayed in Figure 17.1, consists of a probability plot of the data, an ML fitted distribution line, and confidence intervals for the percentile (lifetime) values. An inset box containing summary statistics, Weibull scale and shape estimates, and other information is displayed on the plot by default. The locations of the right-censored data values are plotted as plus signs in an area at the top of the plot.

Figure 17.1: Weibull Probability Plot for Engine Fan Data (Traditional Graphics)

If ODS Graphics is enabled, you can create the probability plot by using ODS Graphics . The following SAS statements use ODS Graphics to create the probability plot shown in Figure 17.1:

proc reliability data=fan;
   distribution Weibull;
   pplot lifetime*censor( 1 ) /  covb;
run;

The plot is shown in Figure 17.2.

Figure 17.2: Weibull Probability Plot for Engine Fan Data (ODS Graphics)

The tabular output produced by the preceding SAS statements is shown in Figure 17.3 and Figure 17.4. This consists of summary data, fit information, parameter estimates, distribution percentile estimates, standard errors, and confidence intervals for all estimated quantities.