options nodate pageno=1 pagesize=60 linesize=72;
title "Leading Grain Producers";

proc template;
   define table shared.cellstyle;

   translate _val_=. into "No data";

   notes "NMVAR defines symbols that will be used to determine the colors
 of the cells.";

  nmvar low "Use default style."
        medium "Use yellow foreground color and bold font weight"
        high "Use red foreground color and a bold, italic font.";

   classlevels=on;

   define column char_var;
      generic=on;
      blank_dups=on;
   end;

   define column num_var;
      generic=on;

      justify=on;

%let low=10000;
%let medium=50000;
%let high=100000;

      cellstyle _val_ <= &low as data,
                _val_ <= &medium as data
                         {color=green fontstyle=italic},
                _val_ <= &high as data
                         {color=yellow fontweight=bold},
                    1 as data
                         {color=red fontstyle=italic
                          fontweight=bold};
   end;
      

   end;
run;

data _null_;
   set grain_production;

   file print ods=(
        template="shared.cellstyle"

        columns=(
           char_var=year(generic=on)
           char_var=country(generic=on format=$cntry.)
           char_var=type(generic=on)
           num_var=kilotons(generic=on format=comma12.)
           )
        );

   put _ods_;
run;

proc template;
    delete shared.cellstyle;
run;

Program Description