The AUTOREG Procedure

One of the key assumptions of the ordinary regression model is that the errors have the same variance throughout the sample. This is also called the homoscedasticity model. If the error variance is not constant, the data are said to be heteroscedastic.

Since ordinary least squares regression assumes constant error variance, heteroscedasticity causes the OLS estimates to be inefficient. Models that take into account the changing variance can make more efficient use of the data. Also, heteroscedasticity can make the OLS forecast error variance inaccurate because the predicted forecast variance is based on the average variance instead of on the variability at the end of the series.

To illustrate heteroscedastic time series, the following statements create the simulated series Y. The variable Y has an error variance that changes from 1 to 4 in the middle part of the series.

data a;
   do time = -10 to 120;
      s = 1 + (time >= 60 & time < 90);
      u = s*rannor(12346);
      y = 10 + .5 * time + u;
      if time > 0 then output;
      end;
run;

title 'Heteroscedastic Time Series';
proc sgplot data=a noautolegend;
   series x=time y=y / markers;
   reg x=time y=y / lineattrs=(color=black);
run;

The simulated series is plotted in Figure 9.10.

Figure 9.10: Heteroscedastic and Autocorrelated Series

To test for heteroscedasticity with PROC AUTOREG, specify the ARCHTEST option. The following statements regress Y on TIME and use the ARCHTEST= option to test for heteroscedastic OLS residuals:

/*-- test for heteroscedastic OLS residuals --*/
proc autoreg data=a;
   model y = time / archtest;
   output out=r r=yresid;
run;

The PROC AUTOREG output is shown in Figure 9.11. The Q statistics test for changes in variance across time by using lag windows that range from 1 through 12. (See the section Testing for Nonlinear Dependence: Heteroscedasticity Tests for details.) The p-values for the test statistics strongly indicate heteroscedasticity, with p < 0.0001 for all lag windows.

The Lagrange multiplier (LM) tests also indicate heteroscedasticity. These tests can also help determine the order of the ARCH model that is appropriate for modeling the heteroscedasticity, assuming that the changing variance follows an autoregressive conditional heteroscedasticity model.

The tests of Lee and King (1993) and Wong and Li (1995) can also be applied to check the absence of ARCH effects. The following example shows that Wong and Li’s test is robust to detect the presence of ARCH effects with the existence of outliers.

/*-- data with outliers at observation 10 --*/
data b;
   do time = -10 to 120;
      s = 1 + (time >= 60 & time < 90);
      u = s*rannor(12346);
      y = 10 + .5 * time + u;
      if time = 10 then
         do; y = 200; end;
      if time > 0 then output;
   end;
run;
/*-- test for heteroscedastic OLS residuals --*/
proc autoreg data=b;
   model y = time / archtest=(qlm) ;
   model y = time / archtest=(lk,wl) ;
run;

As shown in Figure 9.12, the p-values of Q or LM statistics for all lag windows are above 90%, which fails to reject the null hypothesis of the absence of ARCH effects. Lee and King’s test, which rejects the null hypothesis for lags more than 8 at 10% significance level, works better. Wong and Li’s test works best, rejecting the null hypothesis and detecting the presence of ARCH effects for all lag windows.