Usage Note 67024: Using the ESTIMATE or CONTRAST statement or Margins macro to assess continuous variable effects in interactions and splines
 |  |  |  |
When a model contains interactions, it is often of interest to assess the effect of one of the interacting variables. When the variable of interest is categorical, and therefore is specified in the CLASS statement, this is most easily done using the LSMEANS, SLICE, or LSMESTIMATE statement. While it can also be done using the ESTIMATE or CONTRAST statement, these statements require you to properly determine the coefficients of the appropriate linear combination of model parameters. This requires care to define the hypothesis or quantity of interest in terms of the model. The advantage of the LSMEANS, SLICE, and LSMESTIMATE statements is that these coefficients are determined for you, removing the considerable chance of error present when using the ESTIMATE or CONTRAST statement. This note discusses and illustrates the use of all five statements in varying models and describes the process required to properly determine contrast coefficients.
Unfortunately, when the variable of interest is a continuous variable, rather than a categorical variable in the CLASS statement, the LSMEANS, SLICE, and LSMESTIMATE statements cannot be used. In the particular cases of binary response models, such as logistic or probit models, and the Cox survival model, there are statements that again provide an alternative to the more complex ESTIMATE and CONTRAST statements. For binary response models, the ODDSRATIO statement is available in the LOGISTIC procedure. Similarly, the HAZARDRATIO statement is available in the PHREG procedure. These statements estimate the change in odds or hazards for fixed amount(s) of change in the specified continuous predictor variable, optionally at specific values of the interacting variable(s).
But when using modeling procedures other than LOGISTIC or PHREG, such as when using the GLM, GENMOD, GLIMMIX, or other procedure to model a count or continuous response, nothing like the ODDSRATIO or HAZARDRATIO statement is available as an alternative to the ESTIMATE and CONTRAST statements for assessing a continuous variable involved in interactions.
Fortunately, it turns out that the HAZARDRATIO statement in PROC PHREG can still be useful because it can tell you what the needed contrast coefficients are when the E option is added. To make use of it, fit the desired model in PROC PHREG and include one or more HAZARDRATIO statements for the variable(s) to be assessed. Ignore all PHREG procedure output except the values labeled "Coefficient" in the Hazard Ratios table. Then fit the same model in your intended modeling procedure and add ESTIMATE or CONTRAST statements using those coefficients.
Note, however, that when the model is a generalized linear model that involves a link function other than the identity link, the above method is limited to testing the effect of the continuous variable using a CONTRAST statement or estimating the effect of the continuous variable on the link function, or linear predictor, using the ESTIMATE statement. If the primary interest is to estimate the difference in the response mean resulting from some amount of change in the continuous variable, then this must be done with the NLEstimate, NLMeans, or Margins macro when the link function is not the identity link. This is described in more detail with an example using a Poisson model below.
Simple example with continuous variables
Consider the surgery data modeled with PROC GENMOD in the Getting Started section of that procedure's documentation. The data are available in the SAS/STAT® Sample Library in example programs for the GENMOD procedure. The following statements model the response, Y, as a function of two variables, X3 and X4, and their interaction. The results (not shown) indicate that the interaction is significant.
proc glm data=surg;
model y = x3|x4;
run; quit;
Note that the syntax, x3|x4, is equivalent to specifying all main effects and interactions among variables X3 and X4. So, it is equivalent to this MODEL statement.
model y = x3 x4 x3*x4;
It is of interest to assess the effect on the response of increasing x4 by one unit when x3 is set at its mean. That can be done either with the Margins macro or with the HAZARDRATIO statement in PROC PHREG followed by the ESTIMATE statement in PROC GLM. Both are shown next.
Using the Margins macro
The Margins macro fits the specified model and computes the requested margins. For this example, the macro is used to estimate the predictive margins at two settings of x4 one unit apart with x3 set at its mean. The difference in these margins is also estimated.
The two settings of x4 to compare are specified in the two observations created in data set MDAT. In the following macro call, the above model is specified using data=, response=, and model=. The predictive margins for x4 at the mean of x3 are requested using margins= and mean=. The diff and cl options request the difference in the two predictive margins and its confidence interval. This is the marginal effect over these two specified levels of x4. The reverse option requests the (x4=3) - (x4=2) difference rather than the default which is in the opposite order.
data mdat;
do x4=2,3;
output;
end;
run;
%Margins(data=surg, response=y, model=x3|x4,
margins=x4, margindata=mdat, mean=x3,
options=diff reverse cl)
The results include the fitted model (not shown), the x3 mean value that was used, the response means at the two settings of x4, and their difference, 61.8.
|
Using the HAZARDRATIO and ESTIMATE statements
To determine the coefficients needed in an ESTIMATE statement, fit the model in PROC PHREG and include the HAZARDRATIO statement. Note that if the response contains any negative values, those observations are omitted by PROC PHREG. The same observations should be included in the PHREG analysis as when fitting the model using the intended modeling procedure. Since the determination of contrast coefficients does not depend on the actual response values, you can use any positive values. It is easiest to simply generate a variable of random values for any nonmissing values in the original response. In the DATA step that follows, a variable, RAND, is created that contains a random value between 0 and 1 for any nonmissing value of Y.
As mentioned above, you should ignore PROC PHREG output except the Hazard Ratios table. The ODS SELECT statement limits the displayed results to this one table. By default, the E option in the HAZARDRATIO statement adds to this table the contrast coefficients that estimate the effect of a one-unit increase in x4 at the mean of the interacting continuous variable, x3.
data surg;
set surg;
rand=y;
if y ne . then rand=ranuni(2342);
run;
proc phreg data=surg;
model rand = x3|x4;
hazardratio x4 / e;
ods select hazardratios;
run;
The contrast coefficients are shown in the Hazard Ratios table.
|
|||||||||||||||||||||
The effect of a unit increase in x4 with x3 fixed at its mean can now be assessed in the fit of the actual model using these coefficients in an ESTIMATE statement in the GLM procedure or other appropriate procedure. Note that effects with zero coefficient can be omitted. It is a good idea to include the E option in the ESTIMATE statement to verify that the coefficients are the same as provided by PROC PHREG. The fitted model is saved in an item store named RegMod for later use.
proc glm data=surg;
model y=x3|x4;
estimate 'x4+1 at mean(x3)' x4 1 x3*x4 77.111111 / e;
store SurgReg;
run; quit;
The ESTIMATE statement results show that the effect of increasing x4 by one unit with x3 at its mean is 61.8. The standard errors here and from the Margins macro differ slightly because different computational methods are used. The table of coefficients verifies that the coefficients were the same as shown earlier by PHREG.
|
||||||||||||||||||||||
The PLM procedure can use the saved model to produce plots and predicted values. The EFFECTPLOT statement below produces a plot of the predicted response against x4 with x3 fixed at its mean. To verify the estimate above, a data set, CHK, is created that contains two settings of x4 that are one unit apart and at the mean of x3. The SCORE statement produces predicted values for these two points. PROC MEANS displays the estimates at the two points and computes their difference.
data chk;
x3=77.111111;
do x4=2,3; output; end;
run;
proc plm restore=SurgReg;
effectplot fit(x=x4) / at(x3=77.111111);
score data=chk out=chkout predicted=pred;
run;
proc means data=chkout min max range;
var pred;
run;
The effect plot gives a visual verification of the estimate. Further, the difference between the estimated response values at the two points is the same as the above estimate.
|
|||||||||
To estimate the effect of changing the variable of interest by more or less than one unit, specify the desired unit or units of change in the UNITS= option in the HAZARDRATIO statement. Also, to estimate the effect of the change at specific values of the interacting variable(s), specify the AT option. For example, to estimate the effect of changing x4 by 1.5 and 2 units at several settings of x3 (50, 75, and 100), the following HAZARDRATIO statement provides the coefficients for use in subsequent ESTIMATE or CONTRAST statements.
hazardratio x4 / units=1.5 2 at (x3=50 75 100) e;
Continuous-categorical interaction in a log-linked model
When the interacting variable is categorical rather than continuous, it is the effect of changing the continuous variable at each level of the categorical variable that is of interest. This is what the HAZARDRATIO statement provides by default for a unit increase in the continuous variable. Again, the amount(s) of change in the continuous variable can be specified using the UNITS= option. Also, the levels of the categorical variable at which the effect is estimated can be specified with the AT option.
This example fits a Poisson model to data from Long (1997) that models the numbers of articles published by scientists (ART) as a function of various predictors. In this model, the predictors are the prestige of the scientists' PhD program (PHD) and the number of young children they have (KID5). Of interest is estimating the effect of an increase in program prestige on the number of published articles. The data are available in the SAS/ETS® Sample Library in example programs for the COUNTREG procedure.
Two estimates of the effect of prestige can be obtained. Since the model involves the log link function, the ESTIMATE statement can give the multiplicative effect, as measured by the ratio of the response means, when comparing two populations that differ by a fixed number of units of prestige. The Margins macro can estimate the additive effect by estimating the difference in response means for the same two populations. Additionally, the NLEstimate macro can provide either of these two effect measures. The CONTRAST statement can be used for the purpose of testing, rather than estimating, the effect of a change in prestige. The HAZARDRATIO statement in PROC PHREG can be used to provide the coefficients for the ESTIMATE and CONTRAST statements.
Estimating the ratio of response means
The following statements use the HAZARDRATIO statement to produce the contrast coefficients to estimate the effects of changing the program prestige by 2 and 3 units when the scientist has no or two young children. Since the response is a count, it contains no negative values and can be used as is in PROC PHREG. Note that the PARAM=GLM option is specified in the CLASS statement to use the conventional 0/1 coding of dummy variables which will also be used when fitting the Poisson model in PROC GENMOD. The parameterization of CLASS variables used in PROC PHREG should match the parameterization used when fitting the model and estimating effects.
proc phreg data=long97data;
class kid5 / param=glm;
model art = phd|kid5;
hazardratio phd / units=2 3 at (kid5='0' '2') e;
ods select hazardratios;
run;
The HAZARDRATIO statement produces the following table.
|
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
The coefficients can then be used in ESTIMATE or CONTRAST statements when fitting the model in PROC GENMOD. Note that the same CLASS parameterization and model are specified. The STORE statement is added to save the fitted model for later use to score observations and plot the fitted model.
proc genmod data=long97data;
class kid5 / param=glm;
model art = phd|kid5 / dist=poisson link=log;
estimate 'PHD+2 0 kids' phd 2 phd*kid5 2 / e;
contrast 'PHD+2 0 kids' phd 2 phd*kid5 2 / wald e;
estimate 'PHD+3 0 kids' phd 3 phd*kid5 3 / e;
estimate 'PHD+2 2 kids' phd 2 phd*kid5 0 0 2 / e;
estimate 'PHD+3 2 kids' phd 3 phd*kid5 0 0 3 / e;
store PhdMod;
run;
Among the tables produced by PROC GENMOD are tables (not shown) that verify the same coefficients were used and show the desired estimates from increasing the program prestige with no or two children.
The following table from the CONTRAST statement provides a test of the specified increase in prestige with no children. The effect on the response is significant (p<0.0001) and applies to both the multiplicative (mean ratio) and additive (mean difference) change.
|
|||||||||||||||
The Mean Estimate column in the following table of ESTIMATE statement results provides the estimated multiplicative increase in the mean number of published articles for each increase in prestige with either no or two children. Since the model uses the log link, the coefficients produced by the HAZARDRATIO statement define the difference on the log scale between prestige at one level and at a level 2 or 3 units higher with no or two children. The first ESTIMATE statement above for the case of a two-unit increase in prestige with no children estimates log(μp+2)-log(μp) = log[μp+2/μp], where μp is the mean number of articles at prestige level p and μp+2 is the mean at prestige p+2. The estimate of this difference in log response means is given in the L'Beta column and is 0.2408. The ESTIMATE statement automatically applies the inverse of the link function, exponentiation in this case, to this estimate yielding the ratio of response means: exp(log[μp+2/μp]) = μp+2/μp = 1.2723. The mean number of articles increases by a factor of 1.2723 for each two-unit increase in prestige.
|
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
Estimating the difference in response means
Note that the difference in response means for a fixed change in prestige is not provided by the ESTIMATE statement. That is generally the case when the model uses a non-identity link function. For a model with link function g, its inverse g-1, and ESTIMATE statement coefficients that define a difference in two populations as above, the L'Beta value from the ESTIMATE statement is an estimate of g(μ1)-g(μ2) and the Mean Estimate value is an estimate of g-1[g(μ1)-g(μ2)]. In the case of the identity link, the L'Beta and Mean Estimate values are both estimates of the difference in response means, μ1-μ2. In the case of the log link, they are estimates of the log mean ratio and mean ratio as shown above.
The difference in response means is generally a nonlinear combination of model parameters in generalized linear models. It can be estimated by directly expressing the difference in terms of the model in the NLEstimate macro. Unlike the ESTIMATE and CONTRAST statements, the NLEstimate macro can estimate nonlinear combinations of model parameters. The parameter estimates from the model are shown below.
|
|||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
With the model parameter estimates represented, in order, by the names b_p1, b_p2, and so on, the f= expression in the following macro call specifies the mean difference for an increase in prestige from 2 to 4 with no children. The model saved by the STORE statement is specified in instore=.
%NLEst( instore=PhdMod, label=4PHD-2PHD @ 0kids mean diff,
f=exp(b_p1 + 4*b_p2 + b_p3 + 4*b_p7) -
exp(b_p1 + 2*b_p2 + b_p3 + 2*b_p7) )
The estimated difference in mean number of articles for a two-unit increase in prestige is 0.4063.
|
The ratio of means can also be estimated using the macro.
%NLEst( instore=phdmod, label=4PHD/2PHD @ 0kids mean ratio,
f=exp(b_p1 + 4*b_p2 + b_p3 + 4*b_p7) /
exp(b_p1 + 2*b_p2 + b_p3 + 2*b_p7) )
Note that the estimated mean ratio, 1.2723, is the same as provided above as the Mean Estimate from the ESTIMATE statement. The confidence limits differ slightly due to a different, but asymptotically equivalent, method for computing the limits. Also, the standard error of the ratio is provided rather than the standard error for the difference in log means provided by the ESTIMATE statement.
|
The NLMeans macro can also estimate both the ratio or difference in means. To use this macro, two ESTIMATE statements must be added in the GENMOD step to estimate the means of the two populations. The NLMeans macro can then be called to provide the difference or ratio of means. For details and examples of using the NLMeans macro, see its documentation.
The difference in means can also be considered a marginal effect. As such, it can be estimated using the Margins macro, which can fit the model as well as estimate the means in the populations and their difference. Neither PROC GENMOD nor PROC PHREG is needed for this approach. The two prestige levels to estimate and compare are specified in the two observations specified in data set MDAT. The means are estimated and compared for the case of no children as indicated by the one observation in data set ADAT. The same model as above is specified in the Margins macro using data=, class=, response=, model=, and dist=. The predictive margins for prestige in the two populations are requested using margins=, margindata=, at=, and atdata=. The diff and cl options request the difference in the two predictive margins and its confidence interval. This is the marginal effect over these two specified levels of prestige. The reverse option requests the (PHD=4) - (PHD=2) difference rather than the default which is in the opposite order.
data mdat;
do phd=2,4;
output;
end;
run;
data adat;
kid5=0;
run;
%Margins(data=long97data, class=kid5, response=art, model=phd|kid5, dist=poisson,
margins=phd, margindata=mdat, at=kid5, atdata=adat, options=diff reverse cl)
Note that the same estimated difference and confidence limits are obtained as from the NLEstimate macro above. The Margins macro additionally provides the estimated means at each level of prestige.
|
As done in the previous example, confirmation of all of these estimates can be obtained using the EFFECTPLOT and SCORE statements in PROC PLM, followed by PROC MEANS to compute the difference. Data set CHK is created that contains the two settings of prestige that are two units apart and with no children. The ILINK option is specified in the EFFECTPLOT statement to plot the predicted mean response on the vertical axis rather than the default log of the response mean (the linear predictor). The ILINK option is also used in the SCORE statement to obtain predicted mean article counts.
data chk;
kid5=0;
do phd=2,4;
output;
end;
run;
proc plm restore=PhdMod;
effectplot fit(x=phd) / at(kid5='0') ilink;
score data=chk out=chkout predicted=pred / ilink;
run;
proc means data=chkout min max range;
var pred;
run;
The resulting plot and range value from PROC MEANS confirm that the difference in response mean for an increase in two units of prestige with no children is 0.4063. Note also that the ratio of means is 1.898 / 1.492 = 1.272 as produced by the ESTIMATE statement and NLEstimate macro.
|
|||||||||
Model with multiple interactions
The HAZARDRATIO statement in PROC PHREG can be used in the same way in more complex models. Consider the automobile fuel efficiency data (Asuncion and Newman, UCI Machine Learning Repository, 2007) modeled with PROC ADAPTIVEREG in the Getting Started section of that procedure's documentation. The data are available in the SAS/STAT® Sample Library in example programs for the ADAPTIVEREG procedure.
Suppose that the model involves four variables and all possible interactions among three of them. Of particular interest is to estimate the effect of advancing model years on the mileage of domestic cars (ORIGIN=1). Other predictors in the model are the horsepower rating and number of cylinders. Notice that model year is involved in one two-way interaction with a categorical variable, in another two-way interaction with a continuous variable, and finally in a three-way interaction with both.
Using the Margins macro
As with the first example, the Margins macro can estimate the change in mileage for increasing model year. The MDAT data set specifies three model years, 70, 71, and 75, for comparison. The change from a one-year increase can be determined by comparing years 70 and 71, and the change for a five-year increase from comparing years 70 and 75. These comparisons will be done for domestic cars (ORIGIN=1) and at 100 horsepower as specified in data set ADAT. In the Margins macro, the model is specified in response=, class=, and model=. The means for the model years at the origin and horsepower setting are requested in margins=, margindata=, at=, and atdata=. The comparison among the years, with confidence intervals, is requested with the diff, reverse, and cl options.
data mdat;
do year=70,71,75;
output;
end;
run;
data adat;
origin=1;
horsepower=100;
run;
%Margins(data=autompg, response=mpg, class=cylinders origin,
model=cylinders year|horsepower|origin,
margins=year, margindata=mdat,
at=horsepower origin, atdata=adat, options=diff reverse cl)
The estimated margins for each year and their differences are given in the Predictive Margins table and Differences of Margins tables. For domestic, 100-horsepower cars, a one model year increase results in an increase of 0.612 miles per gallon. Over five years, the increase is 21.645 miles per gallon.
horsepower=100 origin=1
horsepower=100 origin=1
|
Using the HAZARDRATIO and ESTIMATE statements
These statements produce the coefficients needed to assess the effect of increasing model year by 1 and 5 years on domestic cars at a horsepower rating of 100. Since MPG is a nonnegative variable, the variable can be used directly in PROC PHREG.
proc phreg data=autompg;
class cylinders origin / param=glm;
model mpg = cylinders year|horsepower|origin;
hazardratio year / units=1 5 at (origin='1' horsepower=100) e;
ods select hazardratios;
run;
The contrast coefficients appear in the Hazard Ratios table.
|
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
Those coefficients are then used in PROC ORTHOREG to fit the model and produce the estimates. Note that the same could be done in other procedures that can model a normally distributed response such as GLM, GLIMMIX, and GENMOD. The EFFECTPLOT statement requests a plot of the effect of model year.
proc orthoreg data=autompg;
class cylinders origin;
model mpg = cylinders year|horsepower|origin;
estimate 'year+1 US HP=100' year 1 year*horsepower 100 year*origin 1 year*horsepower*origin 100 / cl e;
estimate 'year+5 US HP=100' year 5 year*horsepower 500 year*origin 5 year*horsepower*origin 500 / cl e;
effectplot slicefit(x=year sliceby=cylinders) / at (origin='1' horsepower=100);
run;
The results from ORTHOREG include tables (from the E option, not shown) that verify that the coefficients from PHREG were properly used and tables of estimates. All of the procedures mentioned above produce estimates similar to the following from ORTHOREG. Since no link function is involved in this model, the estimates for one- and five-year increases match those from the Margins macro. As noted in the first example, the standard errors here and from the Margins macro differ slightly because different computational methods are used. The plot shows the effect of model year on MPG for domestic cars with 100 horsepower with each number of cylinders and is consistent with the estimated one- and five-year effects.
 |
||||||||||||||||||||||||||||||||||||||||||||||||||||||
Models involving constructed effects such as splines
The HAZARDRATIO statement is particularly useful in complex models such as those that involve constructed effects. Several types of constructed effects are available with the EFFECT statement that can be used in many modeling procedures. Splines are one type of constructed effect commonly used when the association of a continuous predictor on the response is complex and unknown. The spline is a very flexible function that can accommodate complex relationships between predictor and response.
The following example uses the diabetes data in the Getting Started section of the GAM procedure's documentation. The data are available in the SAS/STAT® Sample Library in example programs for the GAM procedure. The model assesses the association of subject age (AGE) and a measure of acidity (BaseDeficit) on the log of the serum C-peptide level (logCP). A natural cubic spline is applied to BaseDeficit to allow for a complex association of that variable with the response. Both linear and quadratic effects of AGE are included in the model and the BaseDeficit spline is allowed to interact with both AGE effects. The EFFECT and MODEL statements below specify this model.
Note that the Margins macro cannot be used since the macro does not support models that involve constructed effects such as splines. The method using the HAZARDRATIO and ESTIMATE statements is shown.
After fitting the model, it is of interest to estimate the effect of increasing BaseDeficit by one unit, from -10 to -9, when AGE is fixed at 10. The following statements define the model and include a HAZARDRATIO statement to produce the coefficients needed to estimate this effect.
proc phreg data=diabetes;
effect s = spline(BaseDeficit / naturalcubic);
model logCP = s|age|age;
hazardratio BaseDeficit / at (BaseDeficit=-10 age=10) e;
ods select hazardratios;
run;
Following are the coefficients produced by the HAZARDRATIO statement.
|
|||||||||||||||||||||||||||||||||||||||||||||
The model can now be fit using PROC ORTHOREG and the effect estimated using the coefficients provided by the HAZARDRATIO statement. The EFFECTPLOT statement below is included to visualize the effect of interest. It requests a plot of the predicted response against BaseDeficit when AGE is fixed at 10. The fitted model is also saved by the STORE statement in an item store named RegMod.
proc orthoreg data=diabetes;
effect s = spline(BaseDeficit / naturalcubic);
model logCP = s|age|age;
estimate 'BD+1 @BD=-10,age=10'
s 0 1 20.663889 s*age 0 10 206.638889
s*age*age 0 100 2066.388889 / cl e;
effectplot fit(x=BaseDeficit) / at (age=10);
store RegMod;
run;
The results from the ESTIMATE and EFFECTPLOT statements are shown below. The estimated effect of increasing BaseDeficit by one unit at -10 when AGE=10 is about 0.009. The effect of larger changes could be obtained by including the UNITS= option in the HAZARDRATIO statement.
 |
|||||||||||||||||||||||||||
To check the effect estimated by the ESTIMATE statement, the following statements evaluate the fitted model at two BaseDeficit settings, -10 and -9, with AGE fixed at 10. The two settings are created in data CHK and predicted values are computed for each using the SCORE statement in PROC PLM. PROC MEANS displays the estimates at the two points and computes their difference.
data chk;
age=10;
do BaseDeficit=-10, -9;
output;
end;
run;
proc plm restore=RegMod;
score data=chk out=chkout predicted=pred;
run;
proc means data=chkout min max range;
var pred;
run;
The predicted values are shown below. The difference (Range) is equal to the 0.009 estimate produced by the ESTIMATE statement.
|
|||||||||
___________
References
Long, J. S. (1997). Regression Models for Categorical and Limited Dependent Variables. Thousand Oaks, CA: Sage Publications.
Operating System and Release Information
| Product Family | Product | System | SAS Release | |
| Reported | Fixed* | |||
| SAS System | SAS/STAT | z/OS | ||
| z/OS 64-bit | ||||
| OpenVMS VAX | ||||
| Microsoft® Windows® for 64-Bit Itanium-based Systems | ||||
| Microsoft Windows Server 2003 Datacenter 64-bit Edition | ||||
| Microsoft Windows Server 2003 Enterprise 64-bit Edition | ||||
| Microsoft Windows XP 64-bit Edition | ||||
| Microsoft® Windows® for x64 | ||||
| OS/2 | ||||
| Microsoft Windows 8 Enterprise 32-bit | ||||
| Microsoft Windows 8 Enterprise x64 | ||||
| Microsoft Windows 8 Pro 32-bit | ||||
| Microsoft Windows 8 Pro x64 | ||||
| Microsoft Windows 8.1 Enterprise 32-bit | ||||
| Microsoft Windows 8.1 Enterprise x64 | ||||
| Microsoft Windows 8.1 Pro 32-bit | ||||
| Microsoft Windows 8.1 Pro x64 | ||||
| Microsoft Windows 10 | ||||
| Microsoft Windows 95/98 | ||||
| Microsoft Windows 2000 Advanced Server | ||||
| Microsoft Windows 2000 Datacenter Server | ||||
| Microsoft Windows 2000 Server | ||||
| Microsoft Windows 2000 Professional | ||||
| Microsoft Windows NT Workstation | ||||
| Microsoft Windows Server 2003 Datacenter Edition | ||||
| Microsoft Windows Server 2003 Enterprise Edition | ||||
| Microsoft Windows Server 2003 Standard Edition | ||||
| Microsoft Windows Server 2003 for x64 | ||||
| Microsoft Windows Server 2008 | ||||
| Microsoft Windows Server 2008 R2 | ||||
| Microsoft Windows Server 2008 for x64 | ||||
| Microsoft Windows Server 2012 Datacenter | ||||
| Microsoft Windows Server 2012 R2 Datacenter | ||||
| Microsoft Windows Server 2012 R2 Std | ||||
| Microsoft Windows Server 2012 Std | ||||
| Microsoft Windows Server 2016 | ||||
| Microsoft Windows Server 2019 | ||||
| Microsoft Windows XP Professional | ||||
| Windows 7 Enterprise 32 bit | ||||
| Windows 7 Enterprise x64 | ||||
| Windows 7 Home Premium 32 bit | ||||
| Windows 7 Home Premium x64 | ||||
| Windows 7 Professional 32 bit | ||||
| Windows 7 Professional x64 | ||||
| Windows 7 Ultimate 32 bit | ||||
| Windows 7 Ultimate x64 | ||||
| Windows Millennium Edition (Me) | ||||
| Windows Vista | ||||
| Windows Vista for x64 | ||||
| 64-bit Enabled AIX | ||||
| 64-bit Enabled HP-UX | ||||
| 64-bit Enabled Solaris | ||||
| ABI+ for Intel Architecture | ||||
| AIX | ||||
| HP-UX | ||||
| HP-UX IPF | ||||
| IRIX | ||||
| Linux | ||||
| Linux for x64 | ||||
| Linux on Itanium | ||||
| OpenVMS Alpha | ||||
| OpenVMS on HP Integrity | ||||
| Solaris | ||||
| Solaris for x64 | ||||
| Tru64 UNIX | ||||
| Type: | Usage Note |
| Priority: | |
| Topic: | Analytics ==> Regression SAS Reference ==> Procedures ==> PHREG SAS Reference ==> Macro |
| Date Modified: | 2021-01-08 11:24:24 |
| Date Created: | 2020-12-02 15:49:08 |