---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/* Set the graphics environment */                                                                                                      
goptions reset=all border cback=white htitle=12pt htext=10pt;                                                                           
                                                                                                                                        
/* Create data set Test */                                                                                                              
data test;                                                                                                                              
   set sashelp.shoes;                                                                                                                   
   where region in ("Asia", "Pacific") and product in ("Boot", "Sandal" "Slipper");                                                     
   new=trim(region)||product;                                                                                                           
run;                                                                                                                                    
                                                                                                                                        
/* Create an Annotate data set to label the Asia and Pacific groups */                                                                  
data anno;                                                                                                                              
   length function color $8 text $7;                                                                                                                      
   retain function 'label' xsys '2' ysys '3' color 'black' when 'a';                                                                    
   set test;                                                                                                                            
   midpoint=new;                                                                                                                        
   group=product;                                                                                                                       
   if substr(new,1,4)='Asia' then do;                                                                                                   
      y=7.5;                                                                                                                            
      text='Asia';                                                                                                                      
      output;                                                                                                                           
   end;                                                                                                                                 
   if substr(new,1,7)='Pacific' then do;                                                                                                
      y=7.5;                                                                                                                            
      text='Pacific';                                                                                                                   
      output;                                                                                                                           
   end;                                                                                                                                 
run;                                                                                                                                    
                                                                                                                                        
/* Define the title for the chart */                                                                                                    
title1 'Display Multiple Groups on the Midpoint Axis';                                                                                  
                                                                                                                                        
/* Specify a blank value for the axis label */                                                                                          
axis1 label=(h=1 ' ') value=none;                                                                                                       
                                                                                                                                        
/* Generate the bar chart */                                                                                                            
proc gchart data=test;                                                                                                                  
    vbar new / sumvar=sales group=product patternid=midpoint                                                                            
               maxis=axis1 nozero annotate=anno width=10;                                                                               
run;                                                                                                                                    
quit;    

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information