The following header might be produced if the ODS TEXT= or ODS PDF TEXT= statements are used to generate entire pages of output and the output crosses a page boundary:

Continuing contents of page NN, which would not fit on a single physical page

The NN value is the page number of the output.

Starting in SAS^® 9.2, the text from ODS TEXT= statement is seen as one entire cell. When it crosses a page boundary, the cell is "broken", resulting in the unwanted header message.

To circumvent the problem, do one of the following:

• Force a page break using a blank table.
• Edit the ExtendedPage style element to eliminate the unwanted header message.

The Full Code tab includes sample code that illustrates both workarounds. The first workaround uses a one-row PROC REPORT table that is not visible in the PDF output. The second workaround shows PROC TEMPLATE code that creates a style that effectively removes the unwanted header message.

Operating System and Release Information

The subsequent sections of code illustrate possible workarounds. The first inserts a "blank" PROC REPORT table in the PDF output to force a page break and eliminate the extraneous header. The second workaround eliminates the header message with PROC TEMPLATE.

title;
/* Set the orientation to portrait, suppress the date and page number, and suppress
   the warning that is generated when the macro variable exceeds a length of 256. */ 

options orientation=portrait nodate nonumber noquotelenmax;

ods escapechar="^";
ods pdf file="problem.pdf" notoc;

%let longtext=%sysfunc(repeat(Very long text string,200));

ods pdf text="^S={cellwidth=3.5in}&longtext";

ods pdf text="^S={cellwidth=4in}NEXT &longtext";
ods pdf close;


/* Illustrate the workarounds */
/* Workaround #1 */

ods pdf file="workaround1.pdf" notoc;
%let longtext=%sysfunc(repeat(Very long text string,200));

ods pdf text="^S={cellwidth=3.5in}&longtext";
   
/* Workaround code starts here */
ods pdf startpage=now;

proc report nowd data=sashelp.class(obs=1) 
     noheader style(report)={rules=none frame=void} 
     style(column)={foreground=white};
run;

ods pdf startpage=no;

ods pdf text="^S={cellwidth=4in}NEXT &longtext";

ods pdf close;

/* Workaround #2 */
proc template;
   define style styles.mystyle ;
   parent=styles.pearl; /* Use Styles.Printer in SAS 9.3 and earlier */
        class ExtendedPage /
        font = fonts("EmphasisFont")
        pretext=""
        posttext=""
        fillrulewidth=0pt
        borderwidth=0pt
        cellpadding=0pt
        textalign=r
        foreground=white;
   end;
run;

ods pdf file="workaround2.pdf" notoc style=styles.mystyle;
%let longtext=%sysfunc(repeat(Very long text string,200));

ods pdf text="^S={cellwidth=3.5in}&longtext";

ods pdf text="^S={cellwidth=4in}NEXT &longtext";

ods pdf close;

A fix for this issue for Base SAS 9.4_M2 is available at:

A fix for this issue for Base SAS 9.4_M1 is available at: