In a SAS^® session with the double-byte character set (DBCS) option set, if the DEFAULT style or a style with DEFAULT as its parent is applied to output created by the EXCELXP tagset, an XLS/XML file is created without any errors generated in the SAS Log. However, when the file is opened in Microsoft Excel, the following dialog box is generated:

Problems came up in the following areas during load:

Style

The problem is with the fonts definition in the style DEFAULT, which combines MS UI Gothic and Sans-serif. Alternative PROC TEMPLATE code is included in the Full Code tab showing a style template that removes the Sans-serif font.

This problem can also be encountered in a single-byte character set environment (NODBCS) if a fonts list includes a font name with more than one space and the Sans-serif specification. The workaround is the same as that shown in the Full Code tab, which illustrates the removal of the Sans-serif font in the list.

Operating System and Release Information

proc template;
   define style Styles.problem;
    parent=styles.default;
      replace fonts
         "Fonts used in the default style" /
         'TitleFont2' = ("'MS UI Gothic', Helvetica, sans-serif",4,Bold Italic)
         'TitleFont' = ("'MS UI Gothic', Helvetica, sans-serif",5,Bold Italic)
         'StrongFont' = ("'MS UI Gothic', Helvetica, sans-serif",4,Bold)
         'EmphasisFont' = ("'MS UI Gothic', Helvetica, sans-serif",3,Italic)
         'FixedEmphasisFont' = ("Courier New, Courier, monospace",2,Italic)
         'FixedStrongFont' = ("Courier New, Courier, monospace",2,Bold)
         'FixedHeadingFont' = ("Courier New, Courier, monospace",2)
         'BatchFixedFont' = ("SAS Monospace, Courier New, Courier, monospace",2)
         'FixedFont' = ("Courier",2)
         'headingEmphasisFont' = ("'MS UI Gothic', Helvetica, sans-serif",4,Bold Italic)
         'headingFont' = ("'MS UI Gothic', Helvetica, sans-serif",4,Bold)
         'docFont' = ("'MS UI Gothic', Helvetica, sans-serif",3);
      end;
run;

ods tagsets.excelxp file="problem.xml" style=styles.problem;

proc print data=sashelp.class; 
run;

ods _all_ close;

/* WORKAROUND */
proc template;
   define style Styles.Workaround;
    parent=styles.default;
      replace fonts
         "Fonts used in the default style" /
         'TitleFont2' = ("'MS UI Gothic', Helvetica ",4,Bold Italic)
         'TitleFont' = ("'MS UI Gothic', Helvetica ",5,Bold Italic)
         'StrongFont' = ("'MS UI Gothic', Helvetica ",4,Bold)
         'EmphasisFont' = ("'MS UI Gothic', Helvetica ",3,Italic)
         'FixedEmphasisFont' = ("Courier New, Courier, monospace",2,Italic)
         'FixedStrongFont' = ("Courier New, Courier, monospace",2,Bold)
         'FixedHeadingFont' = ("Courier New, Courier, monospace",2)
         'BatchFixedFont' = ("SAS Monospace, Courier New, Courier, monospace",2)
         'FixedFont' = ("Courier",2)
         'headingEmphasisFont' = ("'MS UI Gothic', Helvetica ",4,Bold Italic)
         'headingFont' = ("'MS UI Gothic', Helvetica ",4,Bold)
         'docFont' = ("'MS UI Gothic', Helvetica ",3);
      end;
run;

ods tagsets.excelxp file="workaround.xml" style=styles.workaround;

proc print data=sashelp.class; 
run;

ods _all_ close;