• Print |
• E-mail  |
• Bookmark

 
 /*+-------------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y                |
   |                                                             |
   |    NAME: GCTPATRN                                           |
   |   TITLE: GCTPATRN-Using Patterns and Joins in Contour Plots |
   | PRODUCT: GRAPH                                              |
   |  SYSTEM: ALL                                                |
   |    KEYS: GRAPHICS GCONTOUR AXIS LEGEND                      |
   |   PROCS: GCONTOUR                                           |
   |    DATA: INTERNAL                                           |
   |                                                             |
   | SUPPORT: GRAPHICS STAFF              UPDATE:                |
   |     REF: SAS/GRAPH REFERENCE GUIDE                          |
   +-------------------------------------------------------------+*/

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black blue green red cyan lipk lime)
         ftext=swissb htitle=5 htext=4;

   /* Create data set WORK.SWIRL */
data swirl;
   do x=-5 to 5 by 0.25;
      do y=-5 to 5 by 0.25;
         if x+y=0 then z=0;
         else z=(x*y)*((x*x-y*y)/(x*x+y*y));
         output;
      end;
   end;
run;

   /* Define title and footnote for first plot */
title1 'Simple Contour Plot';
footnote h=3 j=r 'GCTPATR1';

   /* Show the contour plot */
proc gcontour data=swirl;
   plot y*x=z;
run;

   /* Redefine title and footnote for second plot */
title1 'Representing Contour Levels with Patterns';
footnote h=3 j=r 'GCTPATR2';

   /* Show the contour plot */
proc gcontour data=swirl;
   plot y*x=z / pattern
                coutline=gray
                ctext=blue;
run;

   /* Redefine title and footnote for third plot */
title1 'Joining the Patterns in a Contour Plot';
footnote h=3 j=r 'GCTPATR3';

   /* Define axis and legend characteristics */
axis1 label=none value=('-5' ' ' '0' ' ' '5')
      color=red width=3;
axis2 label=none value=('-5' ' ' '0' ' ' '5')
      color=red width=3;

legend frame;

  /* Show the contour plot */
proc gcontour data=swirl;
   plot y*x=z / pattern
                join
                haxis=axis1
                vaxis=axis2
                legend=legend1;
run;
quit;

Operating System and Release Information