---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

The graphics output in the Results tab was produced using SAS® 9.2. Submitting the sample code with releases of SAS prior to SAS 9.2 might produce different results.

 /* Set the graphics environment */                                                                                                              
goptions reset=all border cback=white htitle=12pt; 
                                                                              
 /* Create the input data set A */                                                                                                          
data a;                                                                                                                                 
   input maxis1 $ 1-40 total;                                                                                                      
   datalines;                                                                                                                                  
Accuracy of the Order you Placed         95                                                                                             
Overall total of Orders for Breakfast    80                                                                                             
Overall total of Orders for Lunches      85                                                                                             
Temperature of all of the Food Ordered   78                                                                                             
Value for the Money                      87                                                                                                                
;  
run;                                                                                                                                     
                                                                                                                                 
 /* Create macro variables MAXIS2 and TOTAL. The    */                                                                                    
 /* TOTAL macro variable contains the total number  */                                                                                    
 /* of observations in the data set. The END=option */                                                                                    
 /* on the SET statement creates the varible EOF    */                                                                                    
 /* that signals the end-of file.                   */                                                                                    
                                                                                                                                         
data _null_;                                                                                                                            
   set a end=eof;                                                                                                                         
   call symput('maxis2' || left(_n_),"'" || trim(maxis1) || "'");                                                                         
   if eof then do;                                                                                                                        
      call symput('total',_n_);                                                                                                             
   end;                                                                                                                                   
run;                                                                                                                                    
                                                                                                                                        
 /* The MCDOLOOP macro is used to pass the long character    */                                                                           
 /* string to the VALUE= option in the AXIS statement in the */                                                                           
 /* PROC GCHART step.                                        */                                                                           
%macro mcdoloop;                                                                                                                        
   %do i=1 %to &total;                                                                                                                    
     &&maxis2&i                                                                                                                            
   %end;                                                                                                                                  
%mend mcdoloop;                                                                                                                         
                                                                                                                                        
 /* Create axis characteristics.  The values of the macro        */                                                                      
 /* variables generated by the %DO loop in MCDOLOOP macro change */                                                                      
 /* for each observation.                                        */                                                                      
                                                                                                                                        
axis1 value=(%mcdoloop) label=none;  
axis2 label=('Total'); 
                                                                                                                                        
 /* Add a title to the graph */                                                                                                                                       
title 'Survey Results';                                                                                                                 
                                                                                                                                        
 /* Produce the chart */                                                                                                                 
proc gchart data=a;                                                                                                                     
   hbar maxis1 / maxis=axis1 raxis=axis2 sumvar=total nostats;
run;                                                                                                                                    
quit;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information