• Print |
• E-mail  |
• Bookmark

/* Set graphics options */

goptions reset=all htext=3 pct colors=(black) border ctext=black ftext=swiss;

/* Create the data set, SWEST. Subset states in western region and assign */
/* counties to regions.                                                   */

data swest;
   set maps.county;
   if state in(4,8,35,49);
   if state=4 then do;                     /* Arizona */
      if county in(1,5,15,17)
      then region='Flagstaff';
         else region='Phoenix';
      end;
   if state=8 then do;                    /* Colorado */
      if county in(33,67,83,85,91,111,113)
      then region='Flagstaff';
         else region='Denver';
      end;
   if state=35 then do;                 /* New Mexico */
      if county in(17,23,29)
      then region='Phoenix';
         else if county in(31,45)
         then region='Flagstaff';
            else region='Santa Fe';
      end;
   if state=49 then do;                       /* Utah */
      if county in(9,47)
      then region='Denver';
         else if county in(25,37,53)
         then region='Flagstaff';
            else region='Provo';
      end;
run;

/* Project the map of western states. */

proc gproject data=swest out=swest;
   id state county;
run;

/* Create a data set with only state borders. */

proc gremove data=swest out=stborder;
   by state;
   id county;
run;

/* Sort by region and create a data set with only  */
/* region borders.                                 */

proc sort data=swest out=swest2;
   by region;
run;

proc gremove data=swest2 out=regbordr;
   by region;
   id county;
run;

/* Create an Annotate data set, ANNOST to draw  */
/* state borders.                               */

data annost;
   set stborder;
   by state segment;
   retain
      size 4         /* line thickness                */
      color 'yellow' /* yellow border                 */
      xsys '2'       /* Use the map coordinate system.*/
      ysys '2'
      when 'a' ;   /* Annotate after the map is drawn.*/

      /* For the first point in each polygon or the   */
      /* first point of the interior polygon, set     */
      /* FUNCTION to 'POLY'.                          */
   if first.segment or (lag(x)=. and lag(y)=.)
      then function='POLY    ';

      /* For other points, set FUNCTION to 'POLYCONT'. */
   else function='POLYCONT';

      /* Don't output points with missing values. */
   if x and y then output;
run;

/* Create an Annotate data set, ANNOREG to draw the borders */
/* for the regions.                                         */

data annoreg;
   set regbordr;
   by region segment;
   retain
      size 4         /* line thickness                 */
      color 'black'  /* black border                   */
      xsys '2'       /* Use the map coordinate system. */
      ysys '2'
      when 'a';    /* Annotate after the map is drawn. */

      /* For first point in each polygon or first */
      /* point of interior polygon, set FUNCTION  */
      /* to 'POLY'.                               */
   if first.segment or (lag(x)=. and lag(y)=.)
      then function='POLY    ';

      /* For other points, set FUNCTION to 'POLYCONT'. */
   else function='POLYCONT';

     /* Don't output points with missing values. */
   if x and y then output;
run;

   /* Combine the two Annotate data sets. */

data annoboth;
   set annost annoreg;
run;

/* Add the title */

title h=8 pct 'Western Conservation Regions';

/* Create the map, using the Annotate facility to  */
/* draw state and region outlines.                 */

proc gmap map=swest data=swest anno=annoboth;
   id state county;
   choro region / coutline=white  legend=legend1;
   legend1 shape=bar(4,3) pct  across=5 frame
           cshadow=black label=none;

/* Define patterns for the map */

   pattern1 v=s c=green;
   pattern2 v=s c=blue;
   pattern3 v=s c=red;
   pattern4 v=s c=magenta;
   pattern5 v=s c=cyan;
run;
quit;

Operating System and Release Information