This is a continuation of SAS Note  #017438 .

An example of filling the holes with zero uptime values is shown below:

    %let FILL_AVAILABILITY_WITH = ZERO;
    %CPSLMETL(slmpath=c:\itslm21\pgmlib,
              environmentDBPath=e:\slm\environment,
              contractID=1,
              action=SYNC,  /* Could also be ACTION=ETL */
              _rc=myRC);
    %put Return code from ETL is &myRC;

Before deciding how to fill the holes, you may want to know how
pervasive, if at all, the problem is in your contract databases.
Any holes in this data really are symptoms of operational problems with
SLM contract database because the source data that is used by ITSLM
never arrived into ITRM.

Prior to upgrading your contract database, you can discover how many
availability holes exist in your contract database by submitting the
following SAS code. This code will also display what the holes are.
You might find that prior to filling the holes, you actually want to
track down the real data and process it through ITRM and ITSLM, and fill
the holes with actual values. This code does not require HF21LM01 to be
installed.

/* Customize the following lines as indicated by the comments */

/* Assign the DETAIL libref to the DETAIL library of your  */
  /* contract database.  Write access is not required.       */
  libname detail 'E:\slm\contractdb\detail' access=readonly;

  /* Assign the SLM libref to your ITSLM Environment Database. */
  /* Write access is not required.                             */
  libname slm 'E:\slm\environment' access=readonly;

  /* No further customization is required beyond this point */
  proc sql noprint;
     create table work.AvailabilityTables as
       select memname as table
       from   dictionary.members
      where  libname eq 'DETAIL'
        and  memname eqt 'A'
        and  memtype eq  'VIEW';
  quit;

    data work.holes;
       length table $8;
       attrib holeStartDatetime format=datetime21.2;
       attrib holeEndDatetime format=datetime21.2;
       stop;
    run;

    %macro _findHoles(table);
      data work.appendMe(keep=table holeStartDateTime holeEndDateTime);
         set detail.&table.D(keep=datetime);
         by datetime;
         format previousdatetime datetime21.2;
         format holestartdatetime datetime21.2;
         format holeenddatetime datetime21.2;
         length table $8;
         table = "&table";
         if first.datetime then do;
            previousDatetime = lag(datetime);
            if round(datetime - previousDatetime,1) gt 300 then do;
               holeStartDatetime = previousDatetime+300;
               holeEndDatetime   = datetime;
               output work.appendMe;
            end;
         end;
      run;
      proc append base=work.holes data=work.appendme; run;
    %mend _findHoles;

    filename code catalog 'work.code.sanity.source';
    data _null_;
      file code;
      set work.availabilityTables;
      put '%_findHoles(' table ');';
    run;
    %inc code;

    proc sql noprint;
         create table work.namedHoles as
         select slm.name !!' '!!substr(holes.table,2,6)
                as ComponentNameAndID,
                holes.HoleEndDatetime format=datetime21.2,
                holes.HoleStartDatetime format=datetime21.2
           from slm.component as slm,
                work.holes as holes
           where slm.id eq input(substr(holes.table,2,6),6.)
           order by ComponentNameAndID,HoleStartDatetime;
    quit;

title1 "What is the distribution of data holes for the Availability
tables?";
    title2 "Listed by Component Name and ID";
    title3 ;
    proc freq data=work.NamedHoles;
       table ComponentNameAndID;
    run;

    title1 "What are the Availability Holes for each Component?";
    title2;
    title3;
    proc print data=work.namedHoles noobs n;

Operating System and Release Information