Documentation Example 4 for PROC SURVEYREG
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: SVREX4 */
/* TITLE: Documentation Example 4 for PROC SURVEYREG */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: regression, survey sampling */
/* KEYS: regression estimator */
/* KEYS: unequal weighting, linear model */
/* PROCS: SURVEYREG */
/* DATA: */
/* */
/* SUPPORT: Tony An */
/* REF: PROC SURVEYREG, Example 4 */
/* */
/* MISC: Stratified Sampling */
/* */
/****************************************************************/
data Farms;
input State $ Region FarmArea CornYield Weight;
datalines;
Iowa 1 100 54 33.333
Iowa 1 83 25 33.333
Iowa 1 25 10 33.333
Iowa 2 120 83 10.000
Iowa 2 50 35 10.000
Iowa 2 110 65 10.000
Iowa 2 60 35 10.000
Iowa 2 45 20 10.000
Iowa 3 23 5 5.000
Iowa 3 10 8 5.000
Iowa 3 350 125 5.000
Nebraska 1 130 20 5.000
Nebraska 1 245 25 5.000
Nebraska 1 150 33 5.000
Nebraska 1 263 50 5.000
Nebraska 1 320 47 5.000
Nebraska 1 204 25 5.000
Nebraska 2 80 11 20.000
Nebraska 2 48 8 20.000
;
data StratumTotals;
input State $ Region _TOTAL_;
datalines;
Iowa 1 100
Iowa 2 50
Iowa 3 15
Nebraska 1 30
Nebraska 2 40
;
ods graphics on;
title1 'Analysis of Farm Area and Corn Yield';
title2 'Model I: Same Intercept and Slope';
proc surveyreg data=Farms total=StratumTotals;
strata State Region / list;
model CornYield = FarmArea / covB;
weight Weight;
run;
ods graphics off;
data FarmsByState;
set Farms;
if State='Iowa' then do;
FarmAreaIA=FarmArea;
FarmAreaNE=0;
end;
else do;
FarmAreaIA=0;
FarmAreaNE=FarmArea;
end;
run;
title1 'Analysis of Farm Area and Corn Yield';
title2 'Model II: Same Intercept, Different Slopes';
proc surveyreg data=FarmsByState total=StratumTotals;
strata State Region;
model CornYield = FarmAreaIA FarmAreaNE / covB;
weight Weight;
run;
title1 'Analysis of Farm Area and Corn Yield';
title2 'Model III: Different Intercepts and Slopes';
proc surveyreg data=FarmsByState total=StratumTotals;
strata State Region;
class State;
model CornYield = State FarmAreaIA FarmAreaNE / noint covB solution;
weight Weight;
run;