Adding a Header and Positioning the Inset on an ANOM Chart
/***********************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: ANMIN3 */
/* TITLE: Adding a Header and Positioning the Inset on an ANOM Chart */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: ANOM Charts, Mean Charts, Inset, Header, Positioning */
/* PROCS: ANOM */
/* DATA: */
/* */
/* SUPPORT: saswgr */
/* REF: PROC ANOM, INSET Statement Getting Started 3 */
/* */
/***********************************************************************/
data LabelDeviations;
input Position @;
do i = 1 to 5;
input Deviation @;
output;
end;
drop i;
datalines;
1 -0.02386 -0.02853 -0.03001 -0.00428 -0.03623
1 -0.04222 -0.00144 -0.06466 0.00944 -0.00163
2 -0.02014 -0.02725 0.02268 -0.03323 0.03661
2 0.04378 0.05562 0.00977 0.05641 0.01816
3 -0.00728 0.02849 -0.04404 -0.02214 -0.01394
3 0.04855 0.03566 0.02345 0.01339 -0.00203
4 0.06694 0.10729 0.05974 0.06089 0.07551
4 0.03620 0.05614 0.08985 0.04175 0.05298
5 0.03677 0.00361 0.03736 0.01164 -0.00741
5 0.02495 -0.00803 0.03021 -0.00149 -0.04640
6 0.00493 -0.03839 -0.02037 -0.00487 -0.01202
6 0.00710 -0.03075 0.00167 -0.02845 -0.00697
;
data Location;
length _LABEL_ $ 10 _VALUE_ $ 12;
input _LABEL_ _VALUE_ &;
datalines;
Plant Lexington
Line 1
Shift 2
;
ods graphics on;
title 'Mean Chart for Diameters';
proc anom data=LabelDeviations;
xchart Deviation*Position / odstitle=title;
inset data=Location mse nout /
format = 8.5
position = rm
cshadow = black
height = 3
header = 'Summary';
run;