The MIXED Procedure

In this example from Snedecor and Cochran (1980, p. 256), a one-way classification model with heterogeneous variances is fit. The data, shown in the following DATA step, represent amounts of different types of fat absorbed by batches of doughnuts during cooking, measured in grams.

data absorb;
   input FatType Absorbed @@;
   datalines;
 1 164  1 172  1 168  1 177  1 156  1 195
 2 178  2 191  2 197  2 182  2 185  2 177
 3 175  3 193  3 178  3 171  3 163  3 176
 4 155  4 166  4 149  4 164  4 170  4 168
;

The statistical model for these data can be written as

where is the amount of fat absorbed by the jth batch of the ith fat type, and denotes the fat-type effects. A quick glance at the data suggests that observations 6, 9, 14, and 21 might be influential on the analysis, because these are extreme observations for the respective fat types.

The following SAS statements fit this model and request influence diagnostics for the fixed effects and covariance parameters. ODS Graphics is used to create plots of the influence diagnostics in addition to the tabular output. The ESTIMATES suboption requests plots of “leave-one-out” estimates for the fixed effects and group variances.

ods graphics on;

proc mixed data=absorb asycov;
   class FatType;
   model Absorbed = FatType / s
                    influence(iter=10 estimates);
   repeated / group=FatType;
   ods output Influence=inf;
run;

ods graphics off;

The “Influence” table is output to the SAS data set inf so that parameter estimates can be printed subsequently. Results from this analysis are shown in Output 59.7.1.

The fixed-effects solutions correspond to estimates of the following parameters:

You can easily verify that these estimates are simple functions of the arithmetic means in the groups. For example, , , and so forth. The covariance parameter estimates are the sample variances in the groups and are uncorrelated.

The variances in the four groups are shown in the “Covariance Parameter Estimates” table (Output 59.7.1). The estimated variance in the first group is two to three times larger than the variance in the other groups.

In groups where the residual variance estimate is large, the precision of the estimate is also small (Output 59.7.2).

The following statements print the “leave-one-out” estimates for fixed effects and covariance parameters that were written to the inf data set with the ESTIMATES suboption (Output 59.7.3):

proc print data=inf label;
   var parm1-parm5 covp1-covp4;
run;

The graphical displays in Output 59.7.4 and Output 59.7.5 are created when ODS Graphics is enabled. For general information about ODS Graphics, see Chapter 21: Statistical Graphics Using ODS. For specific information about the graphics available in the MIXED procedure, see the section ODS Graphics.

The estimate of the intercept is affected only when observations from the last group are removed. The estimate of the “FatType 1” effect reacts to removal of observations in the first and last group (Output 59.7.4).

While observations can affect one or more fixed-effects solutions in this model, they can affect only one covariance parameter, the variance in their group (Output 59.7.5). Observations 6, 9, 14, and 21, which are extreme in their group, reduce the group variance considerably.

Diagnostics related to residuals and predicted values are printed with the following statements:

proc print data=inf label;
   var observed predicted residual pressres
       student Rstudent;
run;

Observations 6, 9, 14, and 21 have large studentized residuals (Output 59.7.6). That the externally studentized residuals are much larger than the internally studentized residuals for these observations indicates that the variance estimate in the group shrinks when the observation is removed. Also important to note is that comparisons based on raw residuals in models with heterogeneous variance can be misleading. Observation 5, for example, has a larger residual but a smaller studentized residual than observation 21. The variance for the first fat type is much larger than the variance in the fourth group. A “large” residual is more “surprising” in the groups with small variance.

A measure of the overall influence on the analysis is the (restricted) likelihood distance, shown in Output 59.7.7. Observations 6, 9, 14, and 21 clearly displace the REML solution more than any other observations.

The following statements list the restricted likelihood distance and various diagnostics related to the fixed-effects estimates (Output 59.7.8):

proc print data=inf label;
   var leverage observed CookD DFFITS CovRatio RLD;
run;

In this example, observations with large likelihood distances also have large values for Cook’s D and values of CovRatio far less than one (Output 59.7.8). The latter indicates that the fixed effects are estimated more precisely when these observations are removed from the analysis.

The following statements print the values of the D statistic and the CovRatio for the covariance parameters:

proc print data=inf label;
   var iter CookDCP CovRatioCP;
run;

The same conclusions as for the fixed-effects estimates hold for the covariance parameter estimates. Observations 6, 9, 14, and 21 change the estimates and their precision considerably (Output 59.7.9, Output 59.7.10). All iterative updates converged within at most four iterations.

Output 59.7.10 displays the standard panel of influence diagnostics that is obtained when influence analysis is iterative. The Cook’s D and CovRatio statistics are displayed for each deletion set for both fixed-effects and covariance parameter estimates. This provides a convenient summary of the impact on the analysis for each deletion set, since Cook’s D statistic measures impact on the estimates and the CovRatio statistic measures impact on the precision of the estimates.

Observations 6, 9, 14, and 21 have considerable impact on estimates and precision of fixed effects and covariance parameters. This is not necessarily the case. Observations can be influential on only some aspects of the analysis, as shown in the next example.