The MIXED Procedure

The data for this example are from Hemmerle and Hartley (1973) and are also used for an example in the VARCOMP procedure. The response variable consists of measurements from an oven experiment, and the model contains a fixed effect A and random effects B and A*B.

The SAS statements are as follows:

data hh;
   input a b y @@;
   datalines;
1 1 237   1 1 254    1 1 246
1 2 178   1 2 179
2 1 208   2 1 178    2 1 187
2 2 146   2 2 145    2 2 141
3 1 186   3 1 183
3 2 142   3 2 125    3 2 136
;

ods output ParmSearch=parms;
proc mixed data=hh asycov mmeq mmeqsol covtest;
   class a b;
   model y = a / outp=predicted;
   random b a*b;
   lsmeans a;
   parms (17 to 20 by .1) (.3 to .4 by .005) (1.0);
run;
proc print data=predicted;
run;

The ASYCOV option in the PROC MIXED statement requests the asymptotic variance matrix of the covariance parameter estimates. This matrix is the observed inverse Fisher information matrix, which equals , where is the Hessian matrix of the objective function evaluated at the final covariance parameter estimates. The MMEQ and MMEQSOL options in the PROC MIXED statement request that the mixed model equations and their solution be displayed.

The OUTP= option in the MODEL statement produces the data set predicted, containing the predicted values. Least squares means (LSMEANS) are requested for A. The PARMS and ODS statements are used to construct a data set containing the likelihood surface.

The results from this analysis are shown in Output 59.3.1–Output 59.3.13.

The “Model Information” table in Output 59.3.1 lists details about this variance components model.

The “Class Level Information” table in Output 59.3.2 lists the levels for A and B.

The “Dimensions” table in Output 59.3.3 reveals that is and is . Since there are no SUBJECT= effects, PROC MIXED considers the data to be effectively from one subject with 16 observations.

Only a portion of the “Parameter Search” table is shown in Output 59.3.4 because the full listing has 651 rows.

As Output 59.3.5 shows, convergence occurs quickly because PROC MIXED starts from the best value from the grid search.

The “Covariance Parameter Estimates” table in Output 59.3.6 lists the variance components estimates. Note that B is much more variable than A*B.

The asymptotic covariance matrix in Output 59.3.7 also reflects the large variability of B relative to A*B.

As Output 59.3.8 shows, the PARMS likelihood ratio test (LRT) compares the best model from the grid search with the final fitted model. Since these models are nearly the same, the LRT is not significant.

The mixed model equations are analogous to the normal equations in the standard linear model. As Output 59.3.9 shows, for this example, rows 1–4 correspond to the fixed effects, rows 5–12 correspond to the random effects, and Col13 corresponds to the dependent variable.

The solution matrix in Output 59.3.10 results from sweeping all but the last row of the mixed model equations matrix. The final column contains a solution vector for the fixed and random effects. The first four rows correspond to fixed effects and the last eight correspond to random effects.

The A factor is significant at the 5% level (Output 59.3.11).

Output 59.3.12 shows that the significance of A appears to be from the difference between its first level and its other two levels.

Output 59.3.13 lists the predicted values from the model. These values are the sum of the fixed-effects estimates and the empirical best linear unbiased predictors (EBLUPs) of the random effects.

To plot the likelihood surface by using ODS Graphics, use the following statements:

proc template;
   define statgraph surface;
      begingraph;
         layout overlay3d;
            surfaceplotparm x=CovP1 y=CovP2 z=ResLogLike;
         endlayout;
      endgraph;
   end;
run;
proc sgrender data=parms template=surface;
run;

The results from this plot are shown in Output 59.3.14. The peak of the surface is the REML estimates for the B and A*B variance components.