Example 95.1 Theoretical Semivariogram Model Fitting

This example continues the introduction study presented in the section Getting Started: VARIOGRAM Procedure by fitting a theoretical semivariogram model to the estimated classical sample semivariogram in Figure 95.8. You will use PROC NLIN to perform the model fit and to compare two different approaches: the ordinary least squares (OLS) and the weighted least squares (WLS) fitting methods.

A review of the coal seam thickness empirical semivariogram in Figure 95.8 shows first a slow, then rapid rise from the origin, suggesting a Gaussian-type form:

as shown in the section Theoretical Semivariogram Models.

By experimentation, you find that a sill of and a range of feet (effective range feet) provide a reasonable fit of the preceding semivariogram model. You can use these values as initial guesses in the least squares fitting process. For the fitting you need the output data set that is produced by the parameters used in the section Theoretical Semivariogram Models. The following statements skip the autocorrelation statistics and the creation of plots, and produce the required output data for the semivariogram table. Note that for the fitting process you need information about the semivariance variance, which you obtain by specifying the CL option in the COMPUTE statement.

   title 'Theoretical Semivariogram Model Fitting Example';
   ods graphics on;

   proc variogram data=thick outv=outv plots=none;
      compute lagd=7 maxlag=10 robust cl;
      coordinates xc=East yc=North;
      ods output SemivariogramTable=sv;
      var Thick;
   run;

Since MAXLAG=10, you computed the empirical semivariogram at 11 points (see also Figure 95.8). You would like to obtain a smooth theoretical semivariogram plot, so you need to estimate the theoretical model at more points on the horizontal (distance) axis. The following statements create a sequence of such distance points from 0 to 70,000 feet and space them 500 feet apart:

   data pv;
      do Distance = 0 to 70 by 0.5;
         Semivariance = .;
         output;
      end;
   run;

   data sv; set sv pv; by Distance;
   run;

PROC NLIN performs its own analysis based on the Gaussian model you provided as input. By invoking the NLIN procedure twice, as shown in the following statements, you obtain the estimates for the theoretical model parameters for the OLS and WLS fitting methods. Notice in the WLS case that the weights are defined as the inverse of the computed semivariance variance.

   proc nlin data=sv; 
      parms Range=30
            Sill=7.5;
      model Semivariance = 
            Sill*(1-exp(-Distance*Distance/(Range*Range)));
      output out=OLS p=OLS;
   run;

   proc nlin data=sv; 
      parms Range=30
            Sill=7.5;
      model Semivariance = 
            Sill*(1-exp(-Distance*Distance/(Range*Range)));
      _weight_ = 1/SemivarianceStdErr/SemivarianceStdErr; 
      output out=WLS p=WLS;
   run;

Output 95.1.1 shows part of the NLIN procedure output that displays the model parameters statistics for the OLS methods.