Previous Page | Next Page

The LIFETEST Procedure

Example 49.2 Enhanced Survival Plot and Multiple-Comparison Adjustments

This example highlights some of the new features of PROC LIFETEST for SAS 9.2, especially the survival plot with number of subjects at risk and multiple comparisons of survival curves. In the following DATA step, data of 137 bone marrow transplant patients extracted from Klein and Moeschberger (1997) are saved in the data set BMT . At the time of transplant, each patient is classified into one of three risk categories: ALL (acute lymphoblastic leukemia), AML (acute myeloctic leukemia)-Low Risk, and AML-High Risk. The endpoint of interest is the disease-free survival time, which is the time to death or relapse or the end of the study in days. In this data set, the variable Group represents the patient’s risk category, the variable T represents the disease-free survival time, and the variable Status is the censoring indicator, with the value 1 indicating an event time and the value 0 a censored time.

   proc format;
      value risk 1='ALL' 2='AML-Low Risk' 3='AML-High Risk';
    
   data BMT;
      input Group T Status @@;
      format Group risk.;
      label T='Disease Free Time';
      datalines;
   1 2081 0 1 1602 0 1 1496 0 1 1462 0 1 1433 0
   1 1377 0 1 1330 0 1  996 0 1  226 0 1 1199 0
   1 1111 0 1  530 0 1 1182 0 1 1167 0 1  418 1
   1  383 1 1  276 1 1  104 1 1  609 1 1  172 1
   1  487 1 1  662 1 1  194 1 1  230 1 1  526 1
   1  122 1 1  129 1 1   74 1 1  122 1 1   86 1
   1  466 1 1  192 1 1  109 1 1   55 1 1    1 1
   1  107 1 1  110 1 1  332 1 2 2569 0 2 2506 0
   2 2409 0 2 2218 0 2 1857 0 2 1829 0 2 1562 0
   2 1470 0 2 1363 0 2 1030 0 2  860 0 2 1258 0
   2 2246 0 2 1870 0 2 1799 0 2 1709 0 2 1674 0
   2 1568 0 2 1527 0 2 1324 0 2  957 0 2  932 0
   2  847 0 2  848 0 2 1850 0 2 1843 0 2 1535 0
   2 1447 0 2 1384 0 2  414 1 2 2204 1 2 1063 1
   2  481 1 2  105 1 2  641 1 2  390 1 2  288 1
   2  421 1 2   79 1 2  748 1 2  486 1 2   48 1
   2  272 1 2 1074 1 2  381 1 2   10 1 2   53 1
   2   80 1 2   35 1 2  248 1 2  704 1 2  211 1
   2  219 1 2  606 1 3 2640 0 3 2430 0 3 2252 0
   3 2140 0 3 2133 0 3 1238 0 3 1631 0 3 2024 0
   3 1345 0 3 1136 0 3  845 0 3  422 1 3  162 1
   3   84 1 3  100 1 3    2 1 3   47 1 3  242 1
   3  456 1 3  268 1 3  318 1 3   32 1 3  467 1
   3   47 1 3  390 1 3  183 1 3  105 1 3  115 1
   3  164 1 3   93 1 3  120 1 3   80 1 3  677 1
   3   64 1 3  168 1 3   74 1 3   16 1 3  157 1
   3  625 1 3   48 1 3  273 1 3   63 1 3   76 1
   3  113 1 3  363 1
   ;

In the following statements, PROC LIFETEST is invoked to compute the product-limit estimate of the survivor function for each risk category. Using ODS Graphics, you can display the number of subjects at risk in the survival plot. The PLOTS= option requests that the survival curves be plotted, and the ATRISK= suboption specifies the time points at which the at-risk numbers are displayed. In the STRATA statement, the ADJUST=SIDAK option requests the idák multiple-comparison adjustment, and by default, all paired comparisons are carried out.

   ods graphics on;
    
   proc lifetest data=BMT plots=survival(atrisk=0 to 2500 by 500);
      time T * Status(0);
      strata Group / test=logrank adjust=sidak;
      run;

Output 49.2.1 displays the estimated disease free survival for the three leukemia groups with the number of subjects at risk at 0, 500, 1000, 1500, 2000, and 2500 days. Patients in the AML-Low Risk group experience disease free longer than those in the ALL group, who in turn fare better than those in the AML-High Risk group.

Output 49.2.1 Estimated Disease-Free Survival for 137 Bone Marrow Transplant Patients
Estimated Disease-Free Survival for 137 Bone Marrow Transplant Patients

The log-rank test (Output 49.2.2) shows that the disease-free survival times for these three risk groups are significantly different (p=0.001).

Output 49.2.2 Log-Rank Test of Disease Group Homogeneity
Test of Equality over Strata
Test Chi-Square DF Pr >
Chi-Square
Log-Rank 13.8037 2 0.0010

The idák multiple-comparison results are shown in Output 49.2.3. There is no significant difference in disease-free survivor functions between the ALL and AML-High Risk groups (p=0.2779). The difference between the ALL and AML-Low Risk groups is marginal (p=0.0685), but the AML-Low Risk and AML-High Risk groups have significantly different disease-free survivor functions (p=0.0006).

Output 49.2.3 All Paired Comparsions
Adjustment for Multiple Comparisons for the Logrank Test
Strata Comparison Chi-Square p-Values
Group Group Raw Sidak
ALL AML-High Risk 2.6610 0.1028 0.2779
ALL AML-Low Risk 5.1400 0.0234 0.0685
AML-High Risk AML-Low Risk 13.8011 0.0002 0.0006

Suppose you consider the AML-Low Risk group as the reference group. You can use the DIFF= option in the STRATA statement to designate this risk group as the control and apply a multiple-comparison adjustment to the p-values for the paired comparison between the AML-Low Risk group with each of the other groups. Consider the idák correction again. You specify the ADJUST= and DIFF= options as in the following statements.

   proc lifetest data=BMT notable plots=none;
      time T * Status(0);
      strata Group / test=logrank adjust=sidak diff=control('AML-Low Risk');
      run;

Output 49.2.4 shows that although both the ALL and AML-High Risk groups differ from the AML-Low Risk group at the 0.05 level, the difference between the AML-High Risk and the AML-Low Risk group is highly significant (p=0.0004).

Output 49.2.4 Comparisons with the Reference Group
The LIFETEST Procedure

Adjustment for Multiple Comparisons for the Logrank Test
Strata Comparison Chi-Square p-Values
Group Group Raw Sidak
ALL AML-Low Risk 5.1400 0.0234 0.0462
AML-High Risk AML-Low Risk 13.8011 0.0002 0.0004

Klein and Moeschberger (1997, Section 4.4) describe in detail how to compute the Hall-Wellner (HW) and equal-precision (EP) confidence bands for the survivor function. You can output these simultaneous confidence intervals to a SAS data set by using the CONFBAND= and OUTSURV= options in the PROC LIFETEST statement. You can display survival curves with pointwise and simultaneous confidence limits through ODS Graphics. When the survival data are stratified, displaying all the survival curves and their confidence limits in the same plot can make the plot appear cluttered. In the following statements, the PLOTS= specification requests that the survivor functions be displayed along with their pointwise confidence limits (CL) and Hall-Wellner confidence bands (CB=HW). The STRATA=PANEL specification requests that the survival curves be displayed in a panel of three plots, one for each risk group.

   proc lifetest data=BMT plots=survival(cl cb=hw strata=panel);
      time T * Status(0);
      strata Group;
      run;
    
   ods graphics off;

The panel plot is shown in Output 49.2.5.

Output 49.2.5 Estimated Disease-Free Survivor Functions with Confidence Limits
Estimated Disease-Free Survivor Functions with Confidence Limits

Previous Page | Next Page | Top of Page