• Previous Page
• |
• Next Page

Fitting the Correct Correlation Structures

In specifying the previous factor model by using COSAN, covariance structures rather than the correlation structures have been incorrectly assumed. That is, when fitting the correlation structures, the diagonal elements of must always be fixed ones. But these fixed ones have not been handled properly in the previous code, resulting in a specification of covariance structures rather than correlation structures. To fix the problem, additional model constraints on the diagonal elements of the correlation structures represented by are required. For example, it can be done by constraining the error variances

Other constraints could also serve the same purpose, but these are the most convenient and therefore are used subsequently. Without setting up these constraints, the previous PROC CALIS run is analyzing covariance structures. As pointed out in Browne (1982), fitting such covariance structures directly is not entirely appropriate for analyzing correlations. For the current data example, according to Browne (1982), the estimates obtained from fitting the wrong covariance structure model are still consistent (as if they were estimating the population parameters in the correlation structures). However, the chi-square test statistic as reported in the preceding section is not correct.

In addition, due to the fact that discrepancy functions used in PROC CALIS are derived for covariance matrices rather than correlation matrices, PROC CALIS is essentially set up for analyzing covariance structures (with or without mean structures), but not correlation structures. Hence, the statistical theory behind PROC CALIS applies to covariance structure analysis, but might not generalize to correlation structure analysis. Despite that, can PROC CALIS somehow fit the correct correlation structures to the current data without compromising the statistical theory? The answer is yes.

First, recall that the correlation structures are represented by:

As before, in the matrix, there are six linear constraints on the factor loadings. In addition, the diagonal elements of must be ones. To analyze the correlation structures by using PROC CALIS, a covariance structure model with such correlation structures embedded is now specified. That is, the covariance structure to be fitted by PROC CALIS is:

where is a diagonal matrix containing the population standard deviations for the manifest variables. This form of covariance structures implies the specification of the following COSAN model:

   proc calis data=Kinzer method=max nobs=326 nose;
      cosan D(6,DIA) * B(2,Gen) * I(2,Ide) + D(6,DIA) * PSI(6,DIA);                                   
      matrix B                                                     
             [ ,1]= b11 b21 b31 b41 b51 b61,                                        
             [ ,2]= b12 b22 b32 b42 b52 b62;
      matrix Psi                                       
             [1,1]= psi1-psi6;                                      
      matrix D                                       
             [1,1]= d1-d6 (6 * 1.);                                      
      parameters alpha (1.);
      /* SAS Programming Statements */
      /* 12 Constraints on Correlation structures */
      b12  = alpha - b11;
      b22  = alpha - b21;
      b32  = alpha - b31;
      b42  = alpha - b41;
      b52  = alpha - b51;
      b62  = alpha - b61;
      psi1 = 1. - b11 * b11 - b12 * b12;
      psi2 = 1. - b21 * b21 - b22 * b22;
      psi3 = 1. - b31 * b31 - b32 * b32;
      psi4 = 1. - b41 * b41 - b42 * b42;
      psi5 = 1. - b51 * b51 - b52 * b52;
      psi6 = 1. - b61 * b61 - b62 * b62;
      vnames D  var1-var6,
             B  Fact1 Fact2,
             I  Fact1 Fact2,
             Psi var1-var6;                             
   run;
   

In the COSAN statement, the covariance structures are described in the form of the generalized COSAN model. The most significant change is the inclusion of matrix for the population standard deviations. Accompanying this change is the addition of a MATRIX statement for defining the error variance parameters in matrix . Also, in this new specification, Psi1-Psi6 are defined as functions of the loading parameters:

This ensures that the correlation structures will have fixed ones for the diagonal elements.

Other constraints remain the same way as defined in the previous run. For example, the loadings on the second factor are functions of the loadings on the first factor:

The fit summary is presented in Output 25.4.4. The chi-square test statistic is 14.63 with =8 ( = 0.067). This shows that the previous chi-square test based on fitting a wrong covariance structure model is indeed questionable.

• Previous Page
• |
• Next Page
• |
• Top of Page