Previous Page

|

Next Page

The CALIS Procedure

Example 25.1 Path Analysis: Stability of Alienation

The following covariance matrix from Wheaton et al. (1977) has served to illustrate the performance of several implementations for the analysis of structural equation models. Two different models have been analyzed by an early implementation of LISREL and are mentioned in Jöreskog (1978). You can also find a more detailed discussion of these models in the LISREL VI manual (Jöreskog and Sörbom 1985).

A slightly modified model for this covariance matrix is included in the EQS 2.0 manual (Bentler 1985, p. 28). The path diagram of this model is displayed in Figure 25.1. The same model is reanalyzed here by PROC CALIS. However, for the analysis with the EQS implementation, the last variable (V6) is rescaled by a factor of 0.1 to make the matrix less ill-conditioned. Since the Levenberg-Marquardt or Newton-Raphson optimization technique is used with PROC CALIS, rescaling the data matrix is not necessary and, therefore, is not done here. The results reported here reflect the estimates based on the original covariance matrix.

The DATA step and the CALIS model specification are shown as follows:

   data Wheaton(TYPE=COV);                                             
   title "Stability of Alienation";                                    
   title2 "Data Matrix of WHEATON, MUTHEN, ALWIN & SUMMERS (1977)";    
      _type_ = 'cov'; input _name_ $ v1-v6;                            
      label v1='Anomie (1967)' v2='Anomie (1971)' v3='Education'       
            v4='Powerlessness (1967)' v5='Powerlessness (1971)'        
            v6='Occupational Status Index';                            
      datalines;                                                       
   v1   11.834     .        .        .       .        .                
   v2    6.947    9.364     .        .       .        .                
   v3    6.819    5.091   12.532     .       .        .                
   v4    4.783    5.028    7.495    9.986    .        .                
   v5   -3.839   -3.889   -3.841   -3.625   9.610     .                
   v6  -21.899  -18.831  -21.748  -18.775  35.522  450.288             
   ;                                                                   

   
   ods graphics on;
   
   proc calis cov data=Wheaton tech=nr edf=931 pall plots=residuals;
      lineqs
         v1 =         f1                  + e1,
         v2 =    .833 f1                  + e2,
         v3 =         f2                  + e3,
         v4 =    .833 f2                  + e4,
         v5 =         f3                  + e5,
         v6 = Lamb (.5) f3                + e6,
         f1 = Gam1(-.5) f3                + d1,
         f2 = Beta (.5) f1 + Gam2(-.5) f3 + d2;
      std 
         e1-e6 = The1-The2 The1-The4 (6 * 3.),
         d1-d2 = Psi1-Psi2 (2 * 4.),
         f3    = Phi (6.) ;
      cov
         e1 e3 = The5 (.2),
         e4 e2 = The5 (.2);
   run;
   
   ods graphics off;
   

The COV option in the PROC CALIS statement requests the analysis of the covariance matrix. Without the COV option, the correlation matrix would be computed and analyzed. Since no METHOD= option has been used, maximum likelihood estimates are computed by default. The TECH=NR option requests the Newton-Raphson optimization method. The PALL option produces the almost complete set of displayed output, as displayed in Output 25.1.1 through Output 25.1.23. Note that, when you specify the PALL option, you can produce large amounts of output. The PALL option is used in this example to show how you can get a wide spectrum of useful information from PROC CALIS.

PROC CALIS can produce a high-quality residual histogram that is useful for showing the distribution of residuals. To request the residual histogram, you must first enable ODS Graphics by specifying the ods graphics on statement, as shown in the preceding code before the PROC CALIS statement. Then, the residual histogram is requested by the plots=residuals option in the PROC CALIS statement.

Output 25.1.1 displays the model specification in matrix terms, followed by the lists of endogenous and exogenous variables. Output 25.1.2 displays equations and initial parameter estimates. You can use these output to ensure that the desired model is being analyzed.

Output 25.1.1 Model and Variables

Stability of Alienation

Data Matrix of WHEATON, MUTHEN, ALWIN & SUMMERS (1977)

The CALIS Procedure

Covariance Structure Analysis: Pattern and Initial Values

LINEQS Model Statement
		Matrix	Rows	Columns	Matrix Type
Term 1	1	_SEL_	6	17	SELECTION
	2	_BETA_	17	17	EQSBETA	IMINUSINV
	3	_GAMMA_	17	9	EQSGAMMA
	4	_PHI_	9	9	SYMMETRIC

The 8 Endogenous Variables
Manifest	v1 v2 v3 v4 v5 v6
Latent	f1 f2

The 9 Exogenous Variables
Manifest
Latent	f3
Error	e1 e2 e3 e4 e5 e6 d1 d2

General modeling information, descriptive statistics, and the input covariance matrix are displayed in Output 25.1.3. Because the input data set contains only the covariance matrix, the means of the manifest variables are assumed to be zero. Note that this has no impact on the estimation, unless a mean structure model is being analyzed.

The 12 parameter estimates in the model and their respective locations in the parameter matrices are displayed in Output 25.1.4. Each of the parameters, The1, The2, and The5, is specified for two elements in the parameter matrix _PHI_.

PROC CALIS examines whether each element in the moment matrix is modeled by the parameters defined in the model. If an element is not structured by the model parameters, it is predetermined by its observed value. This occurs, for example, when there are exogenous manifest variables in the model. If present, the predetermined values of the elements are displayed. In the current example, the ‘.’ displayed for all elements in the predicted moment matrix (Output 25.1.5) indicates that there are no predetermined elements in the model.

Output 25.1.6 displays the optimization information. You can check this table to determine whether the convergence criterion is satisfied. PROC CALIS displays an error message when problematic solutions are encountered.

Next, the predicted model matrix is displayed in the Output 25.1.7, followed by a list of model test statistics or fit indices (Output 25.1.8). Depending on your modeling philosophy, some indices might be preferred to others. In this example, all indices and test statistics point to a good fit of the model.

PROC CALIS can perform a detailed residual analysis. Large residuals might indicate misspecification of the model. In Output 25.1.9, raw residuals are reported and ranked. Because of the differential scaling of the variables, it is usually more useful to examine the standardized residuals instead. In Output 25.1.10, for example, the table for the 10 largest asymptotically standardized residuals is displayed. The model performs the poorest concerning the variable v5 and its covariance with v2, v1, and v3. This might suggest a misspecification of the model equation for v5. However, because the model fit is quite good, such a possible misspecification is not a serious concern in the analysis.

The histogram of the asymptotically standardized residuals is displayed in Output 25.1.11, which also shows the normal and kernel approximations. The residual distribution looks quite symmetrical. It shows a small to medium departure from the normal distribution, as evidenced by the discrepancies between the kernel and the normal distribution curves.

Output 25.1.11 Distribution of Asymptotically Standardized Residuals

Output 25.1.12 displays the equations and parameter estimates. Each parameter estimate is displayed with its standard error and the corresponding t ratio. As a general rule, a t ratio larger than 2 represents a statistically significant departure from 0. From these results, it is observed that both f1 (Alienation 1967) and f2 (Alienation 1971) are regressed negatively on f3 (Socioeconomic Status), and f1 has a positive effect on f2. The estimates and significance tests for the variance and covariance of the exogenous variables are also displayed.

The measurement scale of variables is often arbitrary. Therefore, it can be useful to look at the standardized equations produced by PROC CALIS. Output 25.1.13 displays the standardized equations and predicted moments. From the standardized structural equations for f1 and f2, you can conclude that SES (f3) has a larger impact on earlier Alienation (f1) than on later Alienation (f3). The squared multiple correlation for each equation is also shown in Output 25.1.13. These correlations indicate the proportion of systematic variance in the equations. Finally, correlations among the exogenous variables are shown.

The predicted covariances among the latent variables and between the observed and the latent variables are displayed in Output 25.1.14.

For interpreting the model, these predicted moments are not as useful as the main results shown previously. However, these predicted moments can be useful for further analysis. For example, they can be useful in constructing bootstrap "populations" for resampling. Another use of these moments is to compute the latent variable score regression coefficients. PROC CALIS computes these coefficients automatically, as shown in Output 25.1.15.

In Output 25.1.15, each latent variable is expressed as a linear combination of the observed variables. By computing these linear combinations for each individual, you can estimate the latent variable scores. See Chapter 76, The SCORE Procedure, for more information about the creation of latent variable scores.

The total effects and indirect effects of the exogenous variables are displayed in Output 25.1.16. These results supplement to those shown in the linear equations in Output 25.1.12, which shows only the direct effects of predictor variables on outcome variables. Total, direct, and indirect effects have the following simple relationship:

To illustrate, consider the relationships between latent factor f3 and variables v1–v4. In the linear equations shown in Output 25.1.12, latent factor f3 does not have direct effects on variables v1–v4. This does not mean that f3 has no effects on these variables at all. As shown in the first table of Output 25.1.16, latent factor f3 indeed has nonzero total effects on all variables, including variables v1–v4. In the next table that shows indirect effects, latent factor f3, again, has nonzero indirect effects on variables v1–v4, and these effects are identical to the total effects. Because the sum of direct and indirect effects is the total effect, this means that the effects of f3 on v1–v4 are all indirect. Similar decomposition of effects can be made for other relationships. For example, while f1 has a total effect of on v1, it has no indirect effect on v1. This means that all the effect of f1 on v1 is direct, which is also shown in an equation in Output 25.1.12. Finally, consider the effects of f3 on f2. In Output 25.1.16, latent factor f3 has nonzero total effect () and indirect effect () on f2, and these two effects are not identical. The difference of these two effects is the direct effect , as shown in an equation in Output 25.1.12.

PROC CALIS can display Lagrange multiplier and Wald statistics for model modifications. Modification indices are displayed for each parameter matrix, as shown in Output 25.1.17 through Output 25.1.22. Only the Lagrange multiplier statistics have significance levels and approximate changes of values displayed. The significance level of the Wald statistic for a given parameter is the same as that shown in the equation output. An insignificant p-value for a Wald statistic means that the corresponding parameter can be dropped from the model without significantly worsening the fit of the model.

A significant p-value for a Lagrange multiplier test indicates that the model would achieve a better fit if the corresponding parameter were free. To aid in determining significant results, PROC CALIS displays the rank order of the 10 largest Lagrange multiplier statistics. For example, [E5:E2] in the _PHI_ matrix is associated with the largest Lagrange multiplier statistic; the associated p-value is . This means that adding a parameter for the covariance between E5 and E2 will lead to a significantly better fit of the model. However, adding parameters indiscriminately can result in specification errors. An overfitted model might not perform well with future samples. As always, the decision to add parameters should be accompanied by consideration and knowledge of the application area.

When you specify equality constraints, PROC CALIS displays Lagrange multiplier tests for releasing the constraints, as shown in Output 25.1.23. In the current example, none of the three constraints achieve a p-value smaller than . This means that releasing the constraints might not lead to a significantly better fit of the model. Therefore, all constraints are retained in the model.

The current model is specified using the LINEQS, STD, and COV statements. As discussed in the section Getting Started: CALIS Procedure, you can also specify the same model by using other specification methods. In the following statements, equivalent COSAN and RAM specifications of the current model are shown. These two specifications would give essentially the same estimation results for the model specified using the LINEQS model statements.

   proc calis cov data=Wheaton tech=nr edf=931;                
      Cosan J(9, Ide) * A(9, Gen, Imi) * P(9, Sym);              
      Matrix A                                                   
              [ ,7] = 1. .833  5 * 0. Beta (.5) ,              
              [ ,8] = 2 * 0.  1.  .833 ,                       
              [ ,9] = 4 * 0.  1.  Lamb Gam1-Gam2 (.5 2 * -.5); 
      Matrix P                                                   
              [1,1] = The1-The2 The1-The4 (6 * 3.) ,           
              [7,7] = Psi1-Psi2 Phi (2 * 4. 6.) ,              
              [3,1] = The5 (.2) ,                              
              [4,2] = The5 (.2) ;                              
      Vnames J V1-V6 F1-F3 ,                                     
             A = J ,                                             
             P E1-E6 D1-D3 ;                                     
   run;                                                        

   proc calis cov data=Wheaton tech=nr edf=931;                
      Ram                                                        
         1   1  7  1.       ,                                  
         1   2  7  .833     ,                                  
         1   3  8  1.       ,                                  
         1   4  8  .833     ,                                  
         1   5  9  1.       ,                                  
         1   6  9  .5    Lamb ,                                
         1   7  9  -.5   Gam1 ,                                
         1   8  7  .5    Beta ,                                
         1   8  9  -.5   Gam2 ,                                
         2   1  1  3.    The1 ,                                
         2   2  2  3.    The2 ,                                
         2   3  3  3.    The1 ,                                
         2   4  4  3.    The2 ,                                
         2   5  5  3.    The3 ,                                
         2   6  6  3.    The4 ,                                
         2   1  3  .2    The5 ,                                
         2   2  4  .2    The5 ,                                
         2   7  7  4.    Psi1 ,                                
         2   8  8  4.    Psi2 ,                                
         2   9  9  6.    Phi ;                                 
      Vnames 1 F1-F3,                                            
             2 E1-E6 D1-D3;                                      
   run;                                                        

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.