Details and Examples: PARETO Procedure

Example 13.8 Creating Weighted Pareto Charts

[See PARETO12 in the SAS/QC Sample Library]In many applications, you can quantify the priority or severity of a problem with a measure such as the cost of repair or the loss to the customer expressed in man-hours. This example shows how to analyze such data with a weighted Pareto chart that incorporates the cost.

Suppose that the cost associated with each of the problems in data set Failure7 (see Example 13.6) has been determined and that the costs have been converted to a relative scale. The following statements add the cost information to the data set:

data Failure7;
   length Analysis $ 16;
   label Analysis = 'Basis for Analysis';
   set Failure7;
   Analysis = 'Cost';
      if      Cause = 'Contamination'  then Cost = 3.0;
      else if Cause = 'Metallization'  then Cost = 8.5;
      else if Cause = 'Oxide Defect'   then Cost = 9.5;
      else if Cause = 'Corrosion'      then Cost = 2.5;
      else if Cause = 'Doping'         then Cost = 3.6;
      else if Cause = 'Silicon Defect' then Cost = 3.4;
      else                                  Cost = 1.0;
      output;
   Analysis = 'Frequency';
      Cost = 1.0;
      output;
run;

The classification variable Analysis has two levels, 'Cost' and 'Frequency'. For Analysis='Cost', the value of Cost is the relative cost, and for Analysis='Frequency', the value of Cost is one.

The following statements create a one-way comparative Pareto chart with Analysis as the classification variable, in which the cells are weighted Pareto charts with Cost as the weight variable:

ods graphics off;
goptions vsize=4.25 in htext=2.8 pct htitle=3.2 pct;
title 'Pareto Analysis By Cost and Frequency';
proc pareto data=Failure7;
   vbar Cause / class      = ( Analysis )
                freq       = Counts
                weight     = Cost
                barlabel   = value
                out        = summary
                intertile  = 1.0;
run;

The display is shown in Output 13.8.1.

Output 13.8.1 Taking Cost into Account

Within each cell, the height of a bar is the frequency of the category multiplied by the value of Cost, expressed as a percent of the total across all categories. Thus, for the cell in which Analysis is equal to 'Frequency', the bars simply indicate the frequencies expressed in percent units. This display shows that the most commonly occurring problem (Contamination) is not the most expensive problem (Oxide Defect). The output data set summary is listed in Output 13.8.2.