The X12 Procedure

This example illustrates the use of MDLINFOIN= and MDLINFOOUT= data sets. Using the data set shown, PROC X12 step identifies the model with outliers as displayed in Output 38.7.1. Output 38.7.2 shows the data set that represents the chosen model.

data b1;
   input y @@; 
   datalines;
   112 118 132 129
   121 135 148 148
   136 119 104 118
   115 126 141 135
   125 149 270 170
   158 133 114 140
;

title 'Model Identification Output to MDLINFOOUT= Data Set';
proc x12 data=b1 start='1980q1' interval=qtr MdlInfoOut=mdl;
   automdl;
   outlier;
run ;

proc print data=mdl;
run;

Suppose that after examining the output from the preceding example, you decide that an Easter regressor should be added to the model. The following statements create a data set with the model identified above and adds a U.S. Census Bureau Predefined Easter(25) regressor. The new model data set to be used as input in the MDLINFOIN= option is displayed in the data set shown in Output 38.7.3.

data pluseaster;
   _NAME_ = 'y';
   _MODELTYPE_ = 'REG';
   _MODELPART_ = 'PREDEFINED';
   _COMPONENT_ = 'SCALE';
   _PARMTYPE_ = 'EASTER';
   _DSVAR_ = 'EASTER';
   _VALUE_ = 25;
run;

data mdlpluseaster;
   set mdl;
run;

proc append base=mdlpluseaster data=pluseaster force;
run;

proc print data=mdlpluseaster;
run;

The following statements estimate the regression and ARIMA parameters by using the model described in the new data set mdlpluseaster. The results of estimating the new model are shown in Output 38.7.4.

proc x12 data=b1 start='1980q1' interval=qtr
   MdlInfoIn=mdlpluseaster MdlInfoOut=mdl2;
   estimate;
run;

The new model estimation results are displayed in the data set mdl2 shown in Output 38.7.5.

proc print data=mdl2;
run;