The SEVERITY Procedure

PROC SEVERITY enables you to specify that the response variable values are left-truncated or right-censored. The following DATA step expands the data set of the previous example to simulate a scenario that is typically encountered by an automobile insurance company. The values of the variable Y represent the loss values on claims that are reported to an auto insurance company. The variable THRESHOLD records the deductible on the insurance policy. If the actual value of Y is less than or equal to the deductible, then it is unobservable and does not get recorded. In other words, THRESHOLD specifies the left-truncation of Y. LIMIT records the policy limit. If the value of Y is equal to or greater than the recorded value, then the observation is right-censored.

 /*----- Lognormal Model with left-truncation and censoring -----*/
 data test_sev2(keep=y threshold limit
         label='A Lognormal Sample With Censoring and Truncation');
     set test_sev1;
     label y='Censored & Truncated Response';
     if _n_ = 1 then call streaminit(45679);

     /* make about 20% of the observations left-truncated */
     if (rand('UNIFORM') < 0.2) then
         threshold = y * (1 - rand('UNIFORM'));
     else
         threshold = .;
     /* make about 15% of the observations right-censored */
     iscens = (rand('UNIFORM') < 0.15);
     if (iscens) then
         limit = y;
     else
         limit = .;
 run;

The following statements use the AICC criterion to analyze which of the four predefined distributions (lognormal, Burr, gamma, and Weibull) has the best fit for the data:

 proc severity data=test_sev2 crit=aicc
         print=all plots(markcensored marktruncated)=pp;
     loss y / lt=threshold rc=limit;

     dist logn burr gamma weibull;
 run;

The LOSS statement specifies the left-truncation and right-censoring variables. Each candidate distribution needs to be specified by using a separate DIST statement. The PRINT= option in the PROC SEVERITY statement requests that all the displayed output be prepared. The PLOTS= option in the PROC SEVERITY statement requests that the P-P plots for each candidate distribution be prepared in addition to the default plots. It also instructs the procedure to mark the left-truncated and right-censored observations in the CDF plot.

Some of the key results prepared by PROC SEVERITY are shown in Figure 23.6 through Figure 23.11. The descriptive statistics of Y are shown in the second table of Figure 23.6. In addition to the estimates of the range, mean, and standard deviation of Y, the table also indicates the number of observations that are right-censored, left-truncated, and both right-censored and left-truncated. The "Model Selection Table" in Figure 23.6 shows that models with all the candidate distributions have converged and that the Logn (lognormal) model has the best fit for the data according to the AICC criterion.

PROC SEVERITY also prepares a table that shows all the fit statistics for all the candidate models. It is useful to see which model would be the best fit according to each of the criteria. The table prepared for this example is shown in Figure 23.7. It indicates that the lognormal model is chosen by all the criteria.

The plot that compares EDF and CDF estimates is shown in Figure 23.8. When left-truncation is specified, both the EDF and CDF estimates are conditional on the response variable being greater than the smallest left-truncation threshold in the sample. Notice the markers close to the X-axis of the plot. These indicate the values of Y that are left-truncated or right-censored.

Figure 23.8 EDF and CDF Estimates for the Truncated and Censored Data

In addition to the comparative plot, PROC SEVERITY produces a P-P plot for each of the models that has not failed to converge. It is a scatter plot of the EDF and the CDF estimates. The model for which the points are scattered closer to the unit-slope reference line is a better fit. The P-P plot for the lognormal distribution is shown in Figure 23.9. It indicates that the EDF and the CDF match very closely. In contrast, the P-P plot for the Weibull distribution, also shown in Figure 23.9, indicates a poor fit.

Figure 23.9 P-P Plots for Lognormal and Weibull Models Fitted to Truncated and Censored Data

 /*------ Specifying initial values using INIT= option -------*/
 proc severity data=test_sev2 crit=aicc print=all plots=none;
     loss y / lt=threshold rc=limit;

     dist burr(init=(theta=4.62348 alpha=1.15706 gamma=6.41227));
 run;