This SAS Note provides a sample on how to use the SGPANEL procedure to create panels of box plots with marker symbols using the JITTER option. 

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/* Create a subset of the SASHELP.HEART data set for subjects over 55. 
   Create a grouping variable for systolic and diastolic for paneled output */
data heart;
  set sashelp.heart(where=(ageatstart > 56)keep=ageatstart sex systolic diastolic);
  length group $9;
  group="Systolic";
  value=systolic; 
  output;
  group="Diastolic";
  value=diastolic;
  output;
  drop ageatstart systolic diastolic;
run;

title "Distribution of Blood Pressure by Sex for Age > 55";
proc sgpanel data=heart noautolegend;
  /* Use the SORT= option to order the panels */
  panelby group / novarname rows=1 columns=2 sort=descending;

  /* Add the JITTER option to separate points at the same location */
  /* Use filled outlined symbols */
  scatter x=sex y=value / jitter filledoutlinedmarkers
      markerattrs=(symbol=circlefilled size=11) 
      markerfillattrs=(color=cxfdae6b)
      markeroutlineattrs=(color=black)
      transparency=0.5;
  vbox value / category=sex nofill 
      lineattrs=(color=black thickness=2)
      whiskerattrs=(color=black thickness=2)
      medianattrs=(color=black thickness=2)
      displaystats=(std mean n);
  rowaxis grid display=(nolabel);
  colaxis display=(nolabel);
run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information