This SAS Note provides a sample on how to use the PROC SGPLOT HBAR statement to add limits to a chart or the HBARPARM statement to add calculated limits to a horizontal bar chart. 

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/* Sample 1: Create a horiztonal bar chart with limits calculated within the SGPLOT procedure */
title "Mileage by Type";
proc sgplot data=sashelp.cars noautolegend;
  /* Generate a horizontal bar chart for average mileage in city driving 
     using the LIMITS= option to calculate and add lower and upper limits */
  hbar type / response=mpg_city stat=mean limits=both
              fillattrs=(color=cxa6bddb) limitattrs=(color=black);
  yaxis display=(nolabel) grid;
  xaxis display=(nolabel);
run;

/* Sample 2: Create a horiztonal bar chart with limits calculated prior to the SGPLOT procedure */
/* Use the MEANS procedure to calculate upper and lower limits */
proc means data=sashelp.cars alpha=.05 clm mean std noprint;
  class type;
  var mpg_city;
  output out=carsMean uclm=uclm lclm=lclm mean=mean;
run;

title 'Mileage by Type';
proc sgplot data=carsMean;
  /* Generate a horizontal bar chart for average mileage in city driving 
     using calculated limits */
  hbarparm category=type response=mean / 
	   fillattrs=(color=cxa6bddb)
     limitlower=lclm limitupper=uclm
     limitattrs=(color=black);
  yaxis display=(nolabel) grid;
  xaxis display=(nolabel);
run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information