The sample code on the Full Code tab illustrates the use of the COLAXISTABLE statement in PROC SGPANEL to display a table of data values with the graph. The COLAXISTABLE statement requires the third maintenance release of SAS^® 9.4 (TS1M3).

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

proc sql; 
   create table minmax as
   select country, prodtype, min(actual) as min, max(actual) as max, count(actual) as num
   from sashelp.prdsale 
   group by country, prodtype;
quit;

data prdsale;
   set sashelp.prdsale minmax;
run;

title1 h=1.5 'Sales by Country';
ods graphics / reset outputfmt=png height=400px width=600px border;

proc sgpanel data=prdsale;
   styleattrs datacolors=(tan cxbdbdbd) 
              datacontrastcolors=(black black);
   panelby country / novarname columns=3 headerattrs=(size=12)
                     headerbackcolor=grayf5;
   vbox actual / category=prodtype group=prodtype capshape=line
                 dataskin=pressed meanattrs=(symbol=diamondfilled);
   colaxis display=(nolabel noticks novalues);
   rowaxis valueattrs=(size=10) labelattrs=(size=12);
   format min max dollar12.;
   colaxistable num / label='Num' position=bottom separator 
                      valueattrs=(size=10) labelattrs=(size=10);
   colaxistable min / label='Min' position=bottom separator 
                      valueattrs=(size=10) labelattrs=(size=10);
   colaxistable max / label='Max' position=bottom separator 
                      valueattrs=(size=10) labelattrs=(size=10);
   keylegend / title='' valueattrs=(size=12) autoitemsize;
run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information