Sample 50993: Use hardware font symbols as plotting symbols with PROC GPLOT
You can use hardware font symbols as plotting symbols with the GPLOT procedure. To use a hardware font symbol, the font name is specified with the FONT= option in the SYMBOL statement. The VALUE= option in the SYMBOL statement is used to specify the hexadecimal value that represents the symbol.
See the sample code on the Full Code tab for an illustration.
To view tables containing the symbols that are available with the Symbol, Wingdings, and Arial fonts, see
SAS Note 47789, "Use the SAS/GRAPH® Annotate facility to create a symbol table containing all the special symbols that are available with a particular font". In the tables on the Output tab, the hexadecimal value for each symbol is displayed above the symbol.
These sample files and code examples are provided by SAS Institute
Inc. "as is" without warranty of any kind, either express or implied, including
but not limited to the implied warranties of merchantability and fitness for a
particular purpose. Recipients acknowledge and agree that SAS Institute shall
not be liable for any damages whatsoever arising out of their use of this material.
In addition, SAS Institute will provide no support for the materials contained herein.
The sample code below illustrates how to use hardware font symbols as plotting symbols with the GPLOT procedure. To use a hardware font symbol, the font name is specified with the FONT= option in the SYMBOL statement. The VALUE= option in the SYMBOL statement is used to specify the hexadecimal value that represents the symbol.
/* Set the graphics environment */
goptions reset=all cback=white border htext=10pt htitle=12pt;
data exchange;
input YearQuarter mmddyy10. Euro Pound Yen;
datalines;
1/1/2008 0.00 0.00 0.00
4/1/2008 -4.25 0.30 -0.90
7/1/2008 -0.50 4.48 2.18
10/1/2008 13.69 26.04 -8.68
1/1/2009 14.53 37.62 -11.30
4/1/2009 9.97 28.04 -7.53
7/1/2009 4.76 20.51 -11.13
10/1/2009 1.36 21.17 -14.80
1/1/2010 8.09 26.80 -13.92
4/1/2010 17.51 32.66 -12.57
7/1/2010 16.06 27.66 -18.51
10/1/2010 10.09 25.06 -21.67
1/1/2011 9.54 23.56 -21.98
4/1/2011 4.04 21.24 -22.57
7/1/2011 5.76 22.75 -26.19
10/1/2011 10.98 25.77 -26.64
1/1/2012 14.20 25.93 -24.79
4/1/2012 16.53 24.94 -23.97
7/1/2012 19.66 25.23 -25.37
10/1/2012 15.41 23.17 -23.00
1/1/2013 13.35 27.40 -12.51
;
run;
/* Define the titles */
title1 "Currency Percent Change Against the U.S. Dollar";
title2 "Quarterly Data - Baseline 1/1/2008";
/* Define the axis characteristics */
axis1 label=none order=('01Jan2008'd to '01Jan2013'd by year) offset=(1,1)pct;
axis2 label=(angle=90 "Percent Change") minor=(n=1);
/* Define the symbol characteristics */
symbol1 interpol=join color=vibg height=14pt font='Arial' value='80'x; /* Euro */
symbol2 interpol=join color=mob height=14pt font='Arial' value='A3'x; /* Pound */
symbol3 interpol=join color=depk height=14pt font='Arial' value='A5'x; /* Yen */
/* Define the legend */
legend1 repeat=1 shape=symbol(5,2.5) label=none frame;
/* Create the graph */
proc gplot data=exchange;
plot (Euro Pound Yen)*YearQuarter / overlay legend=legend1
haxis=axis1 vaxis=axis2;
format YearQuarter year4.;
run;
quit;
These sample files and code examples are provided by SAS Institute
Inc. "as is" without warranty of any kind, either express or implied, including
but not limited to the implied warranties of merchantability and fitness for a
particular purpose. Recipients acknowledge and agree that SAS Institute shall
not be liable for any damages whatsoever arising out of their use of this material.
In addition, SAS Institute will provide no support for the materials contained herein.
This sample illustrates how to use hardware font symbols as plotting symbols with the GPLOT procedure.
| Type: | Sample |
| Topic: | SAS Reference ==> Procedures ==> GPLOT
Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Types ==> Plots ==> Line
Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Elements ==> Symbols/Interpolation
|
| Date Modified: | 2013-09-12 14:12:53 |
| Date Created: | 2013-09-05 16:48:20 |
Operating System and Release Information
| SAS System | SAS/GRAPH | z/OS | 9.2 TS1M0 | |
| Microsoft® Windows® for 64-Bit Itanium-based Systems | 9.2 TS1M0 | |
| Microsoft Windows Server 2003 Datacenter 64-bit Edition | 9.2 TS1M0 | |
| Microsoft Windows Server 2003 Enterprise 64-bit Edition | 9.2 TS1M0 | |
| Microsoft Windows XP 64-bit Edition | 9.2 TS1M0 | |
| Microsoft® Windows® for x64 | 9.2 TS1M0 | |
| Microsoft Windows Server 2003 Datacenter Edition | 9.2 TS1M0 | |
| Microsoft Windows Server 2003 Enterprise Edition | 9.2 TS1M0 | |
| Microsoft Windows Server 2003 Standard Edition | 9.2 TS1M0 | |
| Microsoft Windows XP Professional | 9.2 TS1M0 | |
| Windows Vista | 9.2 TS1M0 | |
| Windows Vista for x64 | 9.2 TS1M0 | |
| 64-bit Enabled AIX | 9.2 TS1M0 | |
| 64-bit Enabled HP-UX | 9.2 TS1M0 | |
| 64-bit Enabled Solaris | 9.2 TS1M0 | |
| HP-UX IPF | 9.2 TS1M0 | |
| Linux | 9.2 TS1M0 | |
| Linux for x64 | 9.2 TS1M0 | |
| OpenVMS on HP Integrity | 9.2 TS1M0 | |
| Solaris for x64 | 9.2 TS1M0 | |
