The following demonstrates how results from PROC GLM are read into PROC MIANALYZE. The data from the example titled "PROC GLM for Unbalanced ANOVA" in the Getting Started section of the GLM documentation is used below and missing values are introduced into the data for the purposes of illustrating the use of the MI and MIANALYZE procedures.

      data exp;
         input A $ B $ Y @@;
         datalines;
      A1 B1 12 A1 B1 .     A1 B2 11 A1 B2 9
      A2 B1 20 A2 B1 18    A2 B2 .
      ;

To impute the missing values in the response variable, the monotone regression method is employed by PROC MI in the statements below. Five imputations, which is the default, are done. This code results in a WARNING message regarding the imputation method for variables A and B that can be ignored because neither is being imputed.

      proc mi data=exp nimpute=5 seed=10 out=exp_imp;
         class a b;
         monotone regression;
         var a b y;
         run;

Suppose there are CLASS variables in the model and you want to combine the parameter estimates from multiple imputations. For example, the following PROC GLM step fits a 2x2 factorial model and saves the Parameter Estimates table to a data set.

      proc glm data=exp_imp;
         by _imputation_;
         class A B;
         model Y = A B A*B / solution;
         ods output ParameterEstimates=parms_glm;
         run;

The following statements display the Parameter Estimates table from the first imputation. Note that it does not match any of the formats required by the CLASSVAR= option in PROC MIANALYZE. See "Input Data Sets" in the Details section of the MIANALYZE documentation. Specifically, the PARAMETER variable records each parameter as its effect name (A, B, or A*B) followed by its associated variable level(s) separated by spaces.

      proc print data=parms_glm noobs;
         where _imputation_=1;
         var _imputation_ parameter estimate stderr;
         run;

In order for PROC MIANALYZE to use this table it is necessary to modify the PARAMETER variable such that its value in each row is a valid SAS name. The following DATA step uses the SCAN function to pick out the first level (second word) in the PARAMETER variable. The INDEXW function then finds the position of the first level. The SUBSTR function selects from that position to the end which is the list of levels. This effectively removes the effect name from the beginning of PARAMETER. Finally, the COMPRESS function removes blanks from the levels list and prepends 'p' to ensure that the final value in PARAMETER is a valid SAS name when levels are numeric.

      data parms_glm;                                                                                                                              
         set parms_glm;
         if  parameter ne 'Intercept' then do;
             FirstLevel = scan(parameter,2,' ');
             LevelsPos  = indexw(parameter,FirstLevel);
             LevelsList = substr(parameter,LevelsPos);
             parameter = 'p'||compress(LevelsList); 
         end; 
         run;     
      
      proc print data=parms_glm noobs;
         where _imputation_=1;
         var _imputation_ parameter estimate stderr;
         run;

Now that values of the PARAMETER variable are SAS names, you can list these names in the MODELEFFECTS statement in PROC MIANALYZE. The CLASS statement is not needed since the parameters are individually named. Also, because of the full-rank parameterization that the CLASS statement in GLM uses, it is necessary to leave the parameters that have been set to zero out of the list specified in the MODELEFFECTS statement. Further, note that because neither the TEST statement nor the MULT option is specified in MIANALYZE it is not necessary to specify the COVB= data set as long as the PARMS= data set contains the estimates and standard errors.

      proc mianalyze parms=parms_glm;
         modeleffects intercept pa1 pb1 pa1b1;
         ods select ParameterEstimates;
         run;

Only the parameter estimates from MIANALYZE are shown below.

It is also possible to combine the results from ESTIMATE statements. This is illustrated by adding two ESTIMATE statements to the example above. The ODS OUTPUT statement saves the results of the ESTIMATE statements in a data set.

      proc glm data=exp_imp;
         by _imputation_;
         class A B;
         model Y=A B A*B/solution;
         estimate 'A1 vs A2 in B1' a 1 -1 a*b 1 0 -1 0;
         estimate 'A1 vs A2 in B2' a 1 -1 a*b 0 1 0 -1;
         ods output estimates=est_ds; 
         run;

In order to properly combine the results from the ESTIMATE statements, it is necessary to sort the EST_DS data set by the PARAMETER variable as well as by _IMPUTATION_.

      proc sort data=est_ds;
         by parameter _imputation_;
         run;

To get the two combined estimates, a BY statement is needed in MIANALYZE. Because GLM uses the variable PARAMETER to identify the different ESTIMATE statements it is necessary to use the the DATA= option rather than the PARMS= option to input the data into MIANALYZE.

      proc mianalyze data=est_ds;
         by parameter;
         modeleffects estimate;
         stderr stderr;
         ods select ParameterEstimates;
         run;

Operating System and Release Information