The sample code on the Full Code tab uses a spline interpolation method in the GRID statement of PROC G3GRID to output data that generates a smoother surface plot with PROC G3D.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

 /* Set the graphics environment */
goptions reset=all border cback=white htitle=12pt; 

 /* Create data set WORK.NUMS using  */
 /* a set of randomly sampled points */
data nums;
   keep x y z;
   do i=1 to 30;
      x=10*ranuni(33)-5;
      y=10*ranuni(35)-5;
      z=sin(sqrt(x*x+y*y));
      output;
   end;
run;

 /* Define a title for the graph */
title1 'Surface Plot After Spline Interpolation';

 /* Process points with PROC G3GRID */
proc g3grid data=nums out=spline;
   grid y*x=z / spline
                axis1=-5 to 5 by .5
                axis2=-5 to 5 by .5;
run;

 /* Generate a surface plot */
proc g3d data=spline;
   plot y*x=z;  
run;

 /* Define a title for the second graph */
title1 'Surface Plot After Smoothed Spline Interpolation';

 /* Process points with PROC G3GRID */
proc g3grid data=nums out=smoothed;
   grid y*x=z / spline
                smooth=.05
                axis1=-5 to 5 by .5
                axis2=-5 to 5 by .5;
run;

 /* Generate a surface plot */
proc g3d data=smoothed;
   plot y*x=z;
run;
quit;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information